Add ALSA-based volume control and test logic

CMakeLists.txt

@@ -34,6 +34,7 @@ if (BRICKMAN_TEST)
         test/FakeBluez5.vala
         test/FakeConnman.vala
         test/controller/FakeAboutController.vala
+        test/controller/FakeAudioController.vala
         test/controller/FakeBatteryController.vala
         test/controller/FakeBluetoothController.vala
         test/controller/FakeDeviceBrowserController.vala
@@ -52,12 +53,14 @@ else (BRICKMAN_TEST)
         lib/connman/Service.vala
         lib/connman/Technology.vala
         src/controller/AboutController.vala
+        src/controller/AudioController.vala
         src/controller/BatteryController.vala
         src/controller/BluetoothController.vala
         src/controller/DeviceBrowserController.vala
         src/controller/FileBrowserController.vala
         src/controller/NetworkController.vala
         src/controller/OpenRobertaController.vala
+        src/AlsaBackedMixerElement.vala
         src/GlobalManager.vala
         src/main.vala
     )
@@ -71,6 +74,7 @@ set (BRICKMAN_COMMON_SOURCE_FILES
     lib/systemd/Systemd.vala
     lib/systemd/logind-interfaces.vala
     lib/systemd/systemd-interfaces.vala
+    src/AlsaInterface.vala
     src/controller/IBrickManagerModule.vala
     src/dbus/Bluez5Agent.vala
     src/dbus/ConnmanAgent.vala
@@ -86,6 +90,8 @@ set (BRICKMAN_COMMON_SOURCE_FILES
     src/view/DeviceBrowserWindow.vala
     src/view/FileBrowserWindow.vala
     src/view/HomeWindow.vala
+    src/view/MixerElementSelectorWindow.vala
+    src/view/MixerElementVolumeWindow.vala
     src/view/MotorBrowserWindow.vala
     src/view/MotorInfoWindow.vala
     src/view/MotorValueDialog.vala
@@ -118,6 +124,7 @@ set (BRICKMAN_COMMON_SOURCE_FILES
 
 find_package(PkgConfig REQUIRED)
 pkg_check_modules(DEPS REQUIRED
+    alsa
     ev3devkit-0.4
     glib-2.0
     gobject-2.0
@@ -174,6 +181,7 @@ PACKAGES
     curses
     posix
     linux
+    alsa
     ${BRICKMAN_TEST_PACKAGES}
 CUSTOM_VAPIS
     bindings/*.vapi

README.md

@@ -49,7 +49,7 @@ not in brickstrap shell:
 
         mkdir -p <some-build-dir>
         cd <some-build-dir>
-        cmake <path-to-brickdm-source> -DCMAKE_BUILD_TYPE=string:Debug -DBRICKMAN_TEST=bool:Yes
+        cmake <path-to-brickman-source> -DCMAKE_BUILD_TYPE=string:Debug -DBRICKMAN_TEST=bool:Yes
         make
         make run
 

debian/control

@@ -4,7 +4,8 @@ Priority: standard
 Maintainer: David Lechner <david@lechnology.com>
 Build-Depends: debhelper (>= 9), dh-systemd, cmake, valac (>= 0.24),
                libgirepository1.0-dev, libgudev-1.0-dev,
-               libncurses5-dev, libev3devkit-dev, netpbm
+               libncurses5-dev, libev3devkit-dev, netpbm,
+               libasound2-dev
 Standards-Version: 3.9.5
 Homepage: https://www.ev3dev.org
 Vcs-Git: git://github.com/ev3dev/brickman.git

src/AlsaBackedMixerElement.vala

@@ -0,0 +1,105 @@
+/*
+ * brickman -- Brick Manager for LEGO MINDSTORMS EV3/ev3dev
+ *
+ * Copyright (C) 2016 Kaelin Laundry <wasabifan@outlook.com>
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; either version 2 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
+ * MA 02110-1301, USA.
+ */
+
+/* AlsaBackedMixerElement.vala - Implementation of IMixerElementViewModel using ALSA API */
+
+using Alsa;
+
+namespace BrickManager {
+    public class AlsaBackedMixerElement: IMixerElementViewModel, Object {
+        private const SimpleChannelId primary_channel_id = SimpleChannelId.MONO;
+
+        private unowned MixerElement alsa_element;
+        private SimpleElementId alsa_id;
+
+        public AlsaBackedMixerElement(MixerElement element) {
+            this.alsa_element = element;
+            SimpleElementId.alloc(out alsa_id);
+            element.get_id(alsa_id);
+        }
+
+        public string name {
+            get {
+                return alsa_id.get_name();
+            }
+        }
+
+        public uint index {
+            get {
+                return alsa_id.get_index();
+            }
+        }
+
+        public int volume {
+            get {
+                long volume = 0;
+                alsa_element.get_playback_volume(primary_channel_id, out volume);
+
+                long min_volume, max_volume;
+                alsa_element.get_playback_volume_range(out min_volume, out max_volume);
+
+                // Prevent division by zero
+                if(max_volume == min_volume)
+                    return 0;
+
+                // Do calculations as floats so avoid odd-looking increments from truncation
+                return (int)Math.round((volume - min_volume) * 100 / (float)(max_volume - min_volume));
+            }
+            set {
+                long min_volume, max_volume;
+                alsa_element.get_playback_volume_range(out min_volume, out max_volume);
+
+                int constrained_volume = int.min(100, int.max(0, value));
+                float scaled_volume = constrained_volume * (max_volume - min_volume) / 100f + min_volume;
+                long rounded_volume = (long)Math.round(scaled_volume);
+
+                alsa_element.set_playback_volume_all(rounded_volume);
+
+                bool should_mute = rounded_volume <= min_volume;
+                if(is_muted != should_mute)
+                    set_is_muted(should_mute);
+            }
+        }
+
+        public bool can_mute {
+            get {
+                return alsa_element.has_playback_switch();
+            }
+        }
+
+        public bool is_muted {
+            get {
+                if(!can_mute)
+                    return false;
+
+                int mute_switch = 0;
+                alsa_element.get_playback_switch(primary_channel_id, out mute_switch);
+
+                return mute_switch == 0;
+            }
+        }
+
+        protected void set_is_muted(bool is_muted) {
+            if(can_mute)
+                alsa_element.set_playback_switch_all(is_muted ? 0 : 1);
+        }
+    }
+}

src/AlsaInterface.vala

@@ -0,0 +1,110 @@
+/*
+ * brickman -- Brick Manager for LEGO MINDSTORMS EV3/ev3dev
+ *
+ * Copyright (C) 2016 Kaelin Laundry <wasabifan@outlook.com>
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; either version 2 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
+ * MA 02110-1301, USA.
+ */
+
+/* AlsaInterface.vala - Definitions for interfacing with ALSA */
+
+using Alsa;
+
+namespace BrickManager {
+    public interface IMixerElementViewModel : Object {
+        public const int MIN_VOLUME = 0;
+        public const int MAX_VOLUME = 100;
+        public const int HALF_VOLUME = (MAX_VOLUME + MIN_VOLUME) / 2;
+
+        public abstract string name { get; }
+        public abstract uint index { get; }
+        public abstract int volume { get; set; }
+        public abstract bool can_mute { get; }
+        public abstract bool is_muted { get; }
+    }
+
+    public class FakeMixerElement: IMixerElementViewModel, Object {
+        private string _name;
+        private uint _index;
+        private int _volume;
+        private bool _can_mute;
+        private bool _is_muted;
+
+        public string name {
+            get {
+                return _name;
+            }
+        }
+
+        public uint index {
+            get {
+                return _index;
+            }
+        }
+
+        public FakeMixerElement(string name, uint index, int volume, bool can_mute) {
+            set_name(name);
+            set_index(index);
+            this.volume = volume;
+
+            set_can_mute(can_mute);
+        }
+
+        public int volume {
+            get {
+                return _volume;
+            }
+            set {
+                _volume = int.min(100, int.max(0, value));
+
+                bool should_mute = _volume <= 0;
+                if(_is_muted != should_mute)
+                    set_is_muted(should_mute);
+            }
+        }
+
+        public bool can_mute {
+            get {
+                return _can_mute;
+            }
+        }
+        public bool is_muted {
+            get {
+                return _is_muted;
+            }
+        }
+
+        public void set_name(string new_name) {
+            this._name = new_name;
+            notify_property("name");
+        }
+
+        public void set_index(uint new_index) {
+            this._index = new_index;
+            notify_property("index");
+        }
+
+        public void set_can_mute(bool can_mute) {
+            this._can_mute = can_mute;
+            notify_property("can_mute");
+        }
+
+        public void set_is_muted(bool is_muted) {
+            this._is_muted = is_muted;
+            notify_property("is_muted");
+        }
+    }
+}

src/controller/AudioController.vala

@@ -0,0 +1,99 @@
+/*
+ * brickman -- Brick Manager for LEGO MINDSTORMS EV3/ev3dev
+ *
+ * Copyright 2014-2015 David Lechner <david@lechnology.com>
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; either version 2 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
+ * MA 02110-1301, USA.
+ */
+
+/* BatteryController.vala - Controller for monitoring battery */
+
+using Ev3devKit.Devices;
+using Ev3devKit.Ui;
+using Alsa;
+
+namespace BrickManager {
+    public class AudioController : Object, IBrickManagerModule {
+        private const int VOLUME_STEP = 10;
+
+        Mixer mixer;
+        MixerElementSelectorWindow mixer_select_window;
+        MixerElementVolumeWindow volume_window;
+
+        public string display_name { get { return "Sound"; } }
+
+        protected void initialize_mixer() {
+            mixer = null;
+            Mixer.open(out mixer);
+            mixer.attach();
+            mixer.register();
+            mixer.load();
+        }
+
+        void create_main_window () {
+            mixer_select_window = new MixerElementSelectorWindow ();
+
+            mixer_select_window.mixer_elem_selected.connect ((selected_element) => {
+                if(volume_window == null)
+                    create_volume_window();
+
+                volume_window.current_element = selected_element;
+                volume_window.show_element_details = true;
+                volume_window.show();
+            });
+        }
+
+        void create_volume_window() {
+            volume_window = new MixerElementVolumeWindow();
+
+            // Wire up handlers for volume window signals
+            volume_window.volume_up.connect(() =>
+                volume_window.current_element.volume += VOLUME_STEP);
+
+            volume_window.volume_down.connect(() =>
+                volume_window.current_element.volume -= VOLUME_STEP);
+
+            volume_window.volume_min.connect(() =>
+                volume_window.current_element.volume = IMixerElementViewModel.MIN_VOLUME);
+        }
+
+        public void show_main_window () {
+            if (mixer_select_window == null) {
+                create_main_window ();
+            }
+
+            // Whenever the audio item is launched from the main menu,
+            // repopulate the mixer list
+            mixer_select_window.clear_elements();
+            // Re-initializing will return updated data, including volume
+            initialize_mixer();
+            for(MixerElement element = mixer.first_elem(); element != null; element = element.next()) {
+                mixer_select_window.add_element(new AlsaBackedMixerElement(element));
+            }
+
+            if(mixer_select_window.has_single_element) {
+                if(volume_window == null)
+                    create_volume_window();
+
+                volume_window.current_element = mixer_select_window.first_element;
+                volume_window.show_element_details = false;
+                volume_window.show();
+            }
+            else
+                mixer_select_window.show ();
+        }
+    }
+}