Tc 60

src/_variables.tf

@@ -39,6 +39,13 @@ variable "global_settings" {
   }
 }
 
+variable "application_gateways" {
+  type        = any
+  description = "Map of Application Gateways to deploy"
+  default     = {}
+}
+
+
 variable "landingzone" {
   description = "Landing zone metadata and tfstate dependencies"
   type = object({

src/modules/_networking/application_gateway/_locals.tf

@@ -0,0 +1,20 @@
+locals {
+  lz_key = try(var.settings.lz_key, var.client_config.landingzone_key)
+
+  resource_group = var.resources[local.lz_key].resource_groups[var.settings.resource_group_ref]
+
+  resource_group_name = local.resource_group.name
+  location            = local.resource_group.location
+
+  public_ip = var.resources[local.lz_key].public_ips[var.settings.public_ip]
+
+  subnet = var.resources[local.lz_key].virtual_networks[var.settings.virtual_network].subnets[
+    split("/", var.settings.subnet_ref)[1]
+  ]
+
+  tags = merge(
+    var.global_settings.tags,
+    var.global_settings.inherit_resource_group_tags ? local.resource_group.tags : {},
+    try(var.settings.tags, {})
+  )
+}

src/modules/_networking/application_gateway/main.tf

@@ -0,0 +1,80 @@
+resource "azurerm_application_gateway" "main" {
+  name                = var.settings.name
+  location            = local.location
+  resource_group_name = local.resource_group_name
+  tags                = local.tags
+
+  sku {
+    name     = var.settings.sku.name
+    tier     = var.settings.sku.tier
+    capacity = var.settings.sku.capacity
+  }
+
+  gateway_ip_configuration {
+    name      = var.settings.gateway_ip_configuration.name
+    subnet_id = local.subnet.id
+  }
+
+  frontend_ip_configuration {
+    name                 = var.settings.frontend_ip_configuration.name
+    public_ip_address_id = local.public_ip.id
+  }
+
+  dynamic "frontend_port" {
+    for_each = try(var.settings.frontend_ports, [])
+    content {
+      name = frontend_port.value.name
+      port = frontend_port.value.port
+    }
+  }
+
+  dynamic "backend_address_pool" {
+    for_each = try(var.settings.backend_address_pools, [])
+    content {
+      name         = backend_address_pool.value.name
+      ip_addresses = try(backend_address_pool.value.ip_addresses, [])
+    }
+  }
+
+  dynamic "backend_http_settings" {
+    for_each = try(var.settings.backend_http_settings_list, [])
+    content {
+      name                  = backend_http_settings.value.name
+      port                  = backend_http_settings.value.port
+      protocol              = backend_http_settings.value.protocol
+      cookie_based_affinity = try(backend_http_settings.value.cookie_based_affinity, "Disabled")
+      request_timeout       = try(backend_http_settings.value.request_timeout, 20)
+    }
+  }
+
+  dynamic "http_listener" {
+    for_each = try(var.settings.http_listeners, [])
+    content {
+      name                           = http_listener.value.name
+      frontend_ip_configuration_name = http_listener.value.frontend_ip_configuration_name
+      frontend_port_name             = http_listener.value.frontend_port_name
+      protocol                       = http_listener.value.protocol
+      host_name                      = try(http_listener.value.host_name, null)
+    }
+  }
+
+  dynamic "request_routing_rule" {
+    for_each = try(var.settings.request_routing_rules, [])
+    content {
+      name                       = request_routing_rule.value.name
+      rule_type                  = request_routing_rule.value.rule_type
+      http_listener_name         = request_routing_rule.value.http_listener_name
+      backend_address_pool_name  = request_routing_rule.value.backend_address_pool_name
+      backend_http_settings_name = request_routing_rule.value.backend_http_settings_name
+    }
+  }
+
+  dynamic "timeouts" {
+    for_each = can(var.settings.timeouts) ? [1] : []
+    content {
+      create = try(var.settings.timeouts.create, null)
+      update = try(var.settings.timeouts.update, null)
+      delete = try(var.settings.timeouts.delete, null)
+    }
+  }
+}

src/modules/_networking/application_gateway/outputs.tf

@@ -0,0 +1,7 @@
+output "name" {
+  value = azurerm_application_gateway.main.name
+}
+
+output "id" {
+  value = azurerm_application_gateway.main.id
+}

src/modules/_networking/application_gateway/variables.tf

@@ -0,0 +1,19 @@
+variable "settings" {
+  type = any
+}
+
+variable "resources" {
+  type        = any
+  description = "Resources provided by other modules"
+  default     = {}
+}
+
+variable "global_settings" {
+  type        = any
+  description = "Global settings shared across modules"
+}
+
+variable "client_config" {
+  type        = any
+  description = "Client config object (landingzone key, etc.)"
+}

src/networking.tf

@@ -73,6 +73,31 @@ module "virtual_network_gateways" {
     landingzone_key = var.landingzone.key
   }
 }
+module "application_gateways" {
+  source   = "./modules/_networking/application_gateway"
+  for_each = var.application_gateways
+
+  settings        = each.value
+  global_settings = local.global_settings
+
+  resources = merge(
+    {
+      (var.landingzone.key) = {
+        resource_groups  = module.resource_groups
+        virtual_networks = module.virtual_networks
+        public_ips       = module.public_ips
+      }
+    },
+    {
+      for k, v in module.remote_states : k => v.outputs
+    }
+  )
+
+  client_config = {
+    landingzone_key = var.landingzone.key
+  }
+}
+
 
 module "public_ips" {
   source   = "./modules/_networking/public_ip"