[Mob456] 石像ボスを作成

Asset/data/asset/functions/mob/0456.gargo_ex_machina/_index.d.mcfunction

@@ -0,0 +1,139 @@
+#> asset:mob/0456.gargo_ex_machina/_index.d
+# @private
+
+#> tag
+# @within function asset:mob/0456.gargo_ex_machina/**
+    # - 共通
+    #declare tag CO.EntityRoot 自分自身
+    #declare tag CO.ModelRoot AJモデルのRootEntity
+    #declare tag CO.Hitbox 当たり判定
+    #declare tag CO.CenterPosition 中心点
+    #declare tag CO.IsLatter 後半戦
+    #declare tag CO.IsRematch 再戦
+    #declare tag CO.IsInvulnerable 無敵
+    # - スキル
+    #declare tag CO.Skill.Activate 起動
+    #declare tag CO.Skill.Activate.Short 起動・演出短縮版
+    #declare tag CO.Skill.ChangeHead 後半戦移行
+    #declare tag CO.Skill.Move 移動
+    #declare tag CO.Skill.Move.End 移動
+    #declare tag CO.Skill.Move.Near 近距離移動
+    #declare tag CO.Skill.SwordAttack 剣叩きつけ
+    #declare tag CO.Skill.SwordAttack.Charge 剣叩きつけ
+    #declare tag CO.Skill.SwordAttack.Attack 剣叩きつけ
+    #declare tag CO.Skill.SwordAttack.Double 剣叩きつけ
+    #declare tag CO.Skill.HalfBeam 半面焼きビーム
+    #declare tag CO.Skill.HalfBeam.Charge 半面焼きビーム
+    #declare tag CO.Skill.HalfBeam.Attack 半面焼きビーム
+    #declare tag CO.Skill.HalfBeam.IsRight 半面焼きビーム
+    #declare tag CO.Skill.HalfBeamSword 半面焼きビーム
+    #declare tag CO.Skill.HalfBeamSword.Charge 半面焼きビーム
+    #declare tag CO.Skill.HalfBeamSword.Attack 半面焼きビーム
+    #declare tag CO.Skill.HalfBeamSword.IsRight 半面焼きビーム
+    #declare tag CO.Skill.HalfBeamShot 半面焼きビーム
+    #declare tag CO.Skill.HalfBeamShot.Charge 半面焼きビーム
+    #declare tag CO.Skill.HalfBeamShot.Attack 半面焼きビーム
+    #declare tag CO.Skill.HalfBeamShot.IsRight 半面焼きビーム
+    #declare tag CO.Skill.SuperJump スーパージャンプ
+    #declare tag CO.Skill.SuperJump.Attack スーパージャンプ
+    #declare tag CO.Skill.FieldModify フィールド・モディファイ
+    #declare tag CO.Skill.Transform.Shoot 銃変形
+    #declare tag CO.Skill.Transform.Sword 剣変形
+    #declare tag CO.Skill.RocketPunch ロケットパンチ
+    #declare tag CO.Skill.RocketPunch.Cross 交差ロケットパンチ
+    #declare tag CO.Skill.RocketPunch.Alter 交互ロケットパンチ
+    #declare tag CO.Skill.RocketPunch.AlterInv 交互ロケットパンチ
+    #declare tag CO.Skill.Shot 射撃
+    #declare tag CO.Skill.UpperShot 上空射撃
+    #declare tag CO.UpperShot.Asyuc 上空射撃攻撃判定用
+    #declare tag CO.UpperShot.Pt.Random ランダムパターン
+    #declare tag CO.UpperShot.Pt.Target 追尾パターン
+    #declare tag CO.UpperShot.Pt.MoveLine 移動直線範囲パターン
+    #declare tag CO.UpperShot.Pt.Cross 交差パターン
+    #declare tag CO.UpperShot.Pt.Panto パンクラパターン
+    #declare tag CO.Skill.BluteForce ブルートフォースアタック
+    #declare tag CO.Skill.BluteForce.First ブルートフォースアタック
+    #declare tag CO.Skill.BluteForce.Async ブルートフォースアタック攻撃判定用
+    #declare tag CO.Skill.BluteForce.Pt.Tutorial 全員お披露目パターン
+    #declare tag CO.Skill.BluteForce.Pt.Spin 回転パターン
+    #declare tag CO.Skill.BluteForce.Pt.SpinInv 回転パターン
+    #declare tag CO.Skill.BluteForce.Pt.Exa エクサパターン
+    #declare tag CO.Skill.BluteForce.Pt.ExaInv エクサパターン
+    #declare tag CO.Skill.BluteForce.Pt.Half 半面焼きパターン
+    #declare tag CO.Skill.BluteForce.Pt.HalfInv 半面焼きパターン
+    # - オブジェクト用
+    #declare tag CO.Shadow
+    #declare tag CO.Object
+    #declare tag CO.Object.FieldModify
+    # - 汎用
+    #declare tag CO.ScapeSheep
+    #declare tag CO.MainTarget
+    #declare tag CO.Aec.Target
+    #declare tag CO.Temp.Rotation
+    #declare tag CO.Aec.Destination
+    #declare tag CO.Aec.AttackPosition
+    #declare tag CO.Aec.AttackPosition.Init
+    #declare tag CO.Aec.UpperShotPosition
+    #declare tag CO.Aec.FieldModify
+    #declare tag CO.Aec.FieldModify.A
+    #declare tag CO.Aec.FieldModify.B
+    #declare tag CO.Aec.FieldModify.C
+    #declare tag CO.Aec.FieldModify.D
+    #declare tag CO.Aec.FieldModify.Init
+    #declare tag CO.Temp.Ground
+    #declare tag CO.Temp.Dummy
+    # - 自動生成
+    #declare tag aj.global.data
+    #declare tag aj.gargo_ex_machina.animation.idle.playing
+    #declare tag aj.gargo_ex_machina.animation.idle_shot.playing
+    #declare tag aj.gargo_ex_machina.bone.head
+    #declare function animated_java:gargo_ex_machina/summon
+    #declare function animated_java:gargo_ex_machina/as_own_locator_entities
+    #declare function animated_java:gargo_ex_machina/animations/pause_all
+    #declare function animated_java:gargo_ex_machina/animations/idle/tween
+    #declare function animated_java:gargo_ex_machina/animations/activation/tween
+    #declare function animated_java:gargo_ex_machina/animations/change_head_start/tween
+    #declare function animated_java:gargo_ex_machina/animations/change_head/tween
+    #declare function animated_java:gargo_ex_machina/animations/move_to_field_fast/resume
+    #declare function animated_java:gargo_ex_machina/animations/move_to_field_fast/tween
+    #declare function animated_java:gargo_ex_machina/animations/move_to_field_fast/pause
+    #declare function animated_java:gargo_ex_machina/animations/move_to_field_short/tween
+    #declare function animated_java:gargo_ex_machina/animations/sword_smash_start/tween
+    #declare function animated_java:gargo_ex_machina/animations/sword_smash_charge/tween
+    #declare function animated_java:gargo_ex_machina/animations/sword_smash_attack/tween
+    #declare function animated_java:gargo_ex_machina/animations/sword_smash_attack/pause
+    #declare function animated_java:gargo_ex_machina/animations/sword_smash_attack/resume
+    #declare function animated_java:gargo_ex_machina/animations/sword_smash_attack_double/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_start/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_charge/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_attack_right/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_attack_left/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_end/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_sword_start/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_sword_charge/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_sword_attack_right/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_sword_attack_left/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_shot_start/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_shot_charge/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_shot_attack_right/tween
+    #declare function animated_java:gargo_ex_machina/animations/beam_shot_attack_left/tween
+    #declare function animated_java:gargo_ex_machina/animations/walk_start/tween
+    #declare function animated_java:gargo_ex_machina/animations/walk/tween
+    #declare function animated_java:gargo_ex_machina/animations/walk_end/tween
+    #declare function animated_java:gargo_ex_machina/animations/super_jump_start/tween
+    #declare function animated_java:gargo_ex_machina/animations/super_jump_end/tween
+    #declare function animated_java:gargo_ex_machina/animations/super_jump_end/pause
+    #declare function animated_java:gargo_ex_machina/animations/super_jump_end/resume
+    #declare function animated_java:gargo_ex_machina/animations/call_drone/tween
+    #declare function animated_java:gargo_ex_machina/animations/call_drone_first/tween
+    #declare function animated_java:gargo_ex_machina/animations/change_to_shot/tween
+    #declare function animated_java:gargo_ex_machina/animations/change_to_sword/tween
+    #declare function animated_java:gargo_ex_machina/animations/idle_shot/tween
+    #declare function animated_java:gargo_ex_machina/animations/shot_target_spin/tween
+    #declare function animated_java:gargo_ex_machina/animations/shot_upper/tween
+    #declare function animated_java:gargo_ex_machina/animations/summon_punch/tween
+    #declare function animated_java:gargo_ex_machina/variants/blue/apply
+    #declare function animated_java:gargo_ex_machina/remove/all
+    #declare function animated_java:gem_attack_drone/remove/all
+    #declare function animated_java:gem_tnt_drone/remove/all
+    #declare function animated_java:gem_panjan_drone/remove/all

Asset/data/asset/functions/mob/0456.gargo_ex_machina/death/.mcfunction

@@ -0,0 +1,65 @@
+#> asset:mob/0456.gargo_ex_machina/death/
+#
+# Mobの死亡時の処理
+#
+# @within function asset:mob/alias/456/death
+
+#> Val
+# @private
+    #declare score_holder $Min
+    #declare score_holder $Sec
+
+# 継承元の処理実行
+    function asset:mob/super.death
+
+# kill時のparticleが見えないように
+    tp @s ~ ~-100 ~
+
+# 死亡演出
+    data modify storage api: Argument.ID set value 2273
+    function api:object/summon
+
+# 中心点消去
+    kill @e[type=marker,tag=CO.CenterPosition]
+
+# 当たり判定消去
+    execute as @e[type=item_display,tag=CO.ModelRoot] run function animated_java:gargo_ex_machina/as_own_locator_entities {command:'function asset:mob/0456.gargo_ex_machina/death/kill_hitbox'}
+    # function animated_java:gargo_ex_machina/remove/all
+
+# その他リセット
+    # function asset:mob/0456.gargo_ex_machina/tick/util/remove_all_tag
+    bossbar remove asset:co_field_modify
+    bossbar remove asset:co_gem_former
+
+# オブジェクト消去
+    function animated_java:gem_attack_drone/remove/all
+    function animated_java:gem_tnt_drone/remove/all
+    function animated_java:gem_panjan_drone/remove/all
+    execute as @e[tag=CO.Object,distance=..160] on passengers run kill @s
+    kill @e[tag=CO.Object,distance=..160]
+
+# 石像移動
+    function asset:mob/0456.gargo_ex_machina/death/clone_statue
+
+# ---
+    tellraw @a[distance=..80] [{"text":"-------------------------------------------------"}]
+
+# クリアタイム表示
+    execute store result score $Sec Temporary store result score $Min Temporary run scoreboard players operation @s CO.BattleTimer /= $20 Const
+    scoreboard players operation $Min Temporary /= $60 Const
+    scoreboard players operation $Sec Temporary %= $60 Const
+    execute if score $Sec Temporary matches 10.. run tellraw @a[distance=..80] [{"text":"【 クリアタイム："},{"score":{"name":"$Min","objective":"Temporary"}},{"text": ":"},{"score":{"name":"$Sec","objective":"Temporary"}},{"text": " !! 】"}]
+    execute if score $Sec Temporary matches ..9 run tellraw @a[distance=..80] [{"text":"【 クリアタイム："},{"score":{"name":"$Min","objective":"Temporary"}},{"text": ":0"},{"score":{"name":"$Sec","objective":"Temporary"}},{"text": " !! 】"}]
+    scoreboard players reset $Min Temporary
+    scoreboard players reset $Sec Temporary
+
+# DPS表示
+    scoreboard players operation @s CO.ActualHealth /= @s CO.DpsTimer
+    scoreboard players operation @s CO.ActualHealth *= $20 Const
+    tellraw @a[distance=..80] [{"text":"【 DPS："},{"score":{"name":"@s","objective":"CO.ActualHealth"}},{"text": " !! 】"}]
+
+# ---
+    tellraw @a[distance=..80] [{"text":"-------------------------------------------------"}]
+
+# 再戦フラグ用marker設置
+    execute unless entity @e[type=marker,tag=CO.IsRematch,distance=..30] run summon marker ~ ~ ~ {Tags:["CO.IsRematch"]}

Asset/data/asset/functions/mob/0456.gargo_ex_machina/death/clone_statue.mcfunction

@@ -0,0 +1,9 @@
+#> asset:mob/0456.gargo_ex_machina/death/clone_statue
+#
+# Mobのinit時の処理
+#
+# @within asset:mob/0456.gargo_ex_machina/death/
+
+# 石像を移動
+    execute positioned 520 0 834 run clone ~ ~ ~ ~14 ~19 ~3 ~ 91 ~
+    execute positioned 520 0 834 run fill ~ ~ ~ ~14 ~19 ~3 air

Asset/data/asset/functions/mob/0456.gargo_ex_machina/death/kill_hitbox.mcfunction

@@ -0,0 +1,11 @@
+#> asset:mob/0456.gargo_ex_machina/death/kill_hitbox
+#
+# Mobの死亡時の処理
+#
+# @within asset:mob/0456.gargo_ex_machina/death/
+# @within asset:mob/0456.gargo_ex_machina/remove/
+
+# 当たり判定消去
+    execute if entity @s[type=slime] run data merge entity @s {Size:0,Tags:["CO.Temp.Dummy"]}
+    execute if entity @s[type=slime] run tp @s ~ ~-100 ~
+    kill @s[type=slime]

Asset/data/asset/functions/mob/0456.gargo_ex_machina/hurt/.mcfunction

@@ -0,0 +1,23 @@
+#> asset:mob/0456.gargo_ex_machina/hurt/
+#
+# Mobのダメージ時の処理
+#
+# @within function asset:mob/alias/456/hurt
+
+# 継承元の処理実行
+    function asset:mob/super.hurt
+
+# 効果音
+    playsound entity.generic.hurt hostile @a ~ ~ ~ 1 1
+
+# 前半戦
+    execute unless entity @s[tag=CO.IsLatter] run function asset:mob/0456.gargo_ex_machina/tick/util/update_former_bossbar
+
+# フェーズ処理
+    # 残HP割合取得
+        function api:mob/get_health_percent
+        execute store result score $HealthPer Temporary run data get storage api: Return.HealthPer 100
+    # フェーズ移行
+        execute unless entity @s[tag=CO.IsLatter] if score $HealthPer Temporary matches ..40 run function asset:mob/0456.gargo_ex_machina/tick/event/change_head/start
+    # 終了
+        scoreboard players reset $HealthPer Temporary

Asset/data/asset/functions/mob/0456.gargo_ex_machina/init/.mcfunction

@@ -0,0 +1,45 @@
+#> asset:mob/0456.gargo_ex_machina/init/
+#
+# Mobのinit時の処理
+#
+# @within asset:mob/alias/456/init
+
+# AJロード
+    # data modify storage asset:datapack ActivationState set value [{Datapack:"gargo_ex_machina",Active:true}]
+    # function asset:datapack/set_activation_state
+
+# 継承元の処理実行
+    function asset:mob/super.init
+
+# 再戦フラグチェック
+    execute if entity @e[type=marker,tag=CO.IsRematch,distance=..80] run tag @s add CO.IsRematch
+
+# 独自init処理
+    # 登場演出再生
+        # tag @s add CO.Skill.Start
+    # 中心点設置
+        summon marker ~ ~0.5 ~ {Tags:["CO.CenterPosition"]}
+        execute as @e[type=marker,tag=CO.CenterPosition] at @s run tp @s ~ ~ ~ 0 0
+    # NBT設定
+    # Aj関連初期化
+        function asset:mob/0456.gargo_ex_machina/init/animated_java.m with storage asset:context this.FirstPos
+    # じゃまにならないよう移動
+        execute at @e[type=marker,tag=CO.CenterPosition] run tp @s ~ ~10 ~
+    # スコア初期化
+        scoreboard players set @s CO.EventTimer 0
+        scoreboard players set @s CO.Counter 0
+
+# ダミー用ひつじ召喚
+    execute unless entity @s[tag=CO.IsRematch] run data modify storage api: Argument.ID set value 2264
+    execute unless entity @s[tag=CO.IsRematch] run function api:object/summon
+
+# 登場モーション再生
+    tag @s add CO.Skill.Activate
+    # 再戦フラグ有効の場合、短縮版登場モーションを再生する
+        execute if entity @s[tag=CO.IsRematch] run tag @s add CO.Skill.Activate.Short
+
+# DPSタイマー計算開始
+    function asset:mob/0456.gargo_ex_machina/init/set_dps_timer
+
+# デバッグ
+    # tag @s add CO.IsLatter

Asset/data/asset/functions/mob/0456.gargo_ex_machina/init/animated_java.m.mcfunction

@@ -0,0 +1,23 @@
+#> asset:mob/0456.gargo_ex_machina/init/animated_java.m
+#
+# 初期化処理 Aj関連
+#
+# @within asset:mob/0456.gargo_ex_machina/init/
+
+# AjModelの召喚
+    # execute positioned 527.5 91.0 836.0 rotated 180 ~ run function animated_java:gargo_ex_machina/summon {args: {animation: 'activation'}}
+    $execute unless entity @s[tag=CO.IsRematch] positioned $(X) $(Y) $(Z) rotated 180 ~ run function animated_java:gargo_ex_machina/summon {args: {animation: 'activation'}}
+    execute if entity @s[tag=CO.IsRematch] positioned ^ ^ ^15 rotated 180 ~ run function animated_java:gargo_ex_machina/summon {args: {animation: 'move_to_field_short'}}
+    # AjModelのパーツに以下処理を実行する
+        execute as @e[type=item_display,tag=CO.ModelRoot,distance=..80] run data merge entity @s {view_range:16f,width:0f,height:0f,teleport_duration:2}
+        execute as @e[type=item_display,tag=CO.ModelRoot,distance=..80] on passengers if entity @s[type=item_display] run data merge entity @s {view_range:16f,width:0f,height:0f,teleport_duration:2}
+    # Locatorの初期化
+        execute as @e[type=item_display,tag=CO.ModelRoot,distance=..80] run function animated_java:gargo_ex_machina/as_own_locator_entities {command:'function asset:mob/0456.gargo_ex_machina/init/locator'}
+
+# スコア初期化
+    execute as @e[type=item_display,tag=CO.ModelRoot,distance=..80] run scoreboard players set @s CO.EventTimer 0
+    execute as @e[type=item_display,tag=CO.ModelRoot,distance=..80] run scoreboard players set @s CO.IdleTimer 60
+
+# テスト
+    # 待機モーション再生
+        # execute as @e[type=item_display,tag=CO.ModelRoot] at @s run function animated_java:gargo_ex_machina/animations/idle/tween {duration:1, to_frame: 1}

Asset/data/asset/functions/mob/0456.gargo_ex_machina/init/clone_statue.mcfunction

@@ -0,0 +1,9 @@
+#> asset:mob/0456.gargo_ex_machina/tick/event/activate/clone_statue
+#
+# 起動
+#
+# @within asset:mob/0456.gargo_ex_machina/tick/event/activate/
+
+# 石像を移動
+    execute positioned 520 91 834 run clone ~ ~ ~ ~14 ~19 ~3 ~ 0 ~
+    execute positioned 520 91 834 run fill ~ ~ ~ ~14 ~19 ~3 air

Asset/data/asset/functions/mob/0456.gargo_ex_machina/init/locator.mcfunction

@@ -0,0 +1,19 @@
+#> asset:mob/0456.gargo_ex_machina/init/locator
+#
+# 初期化処理 Aj関連
+#
+# @within asset:mob/0456.gargo_ex_machina/init/animated_java.m
+
+# slime以外では実行しない
+    execute unless entity @s[type=slime] run return 0
+
+# Locatorに以下処理を実行する
+    data merge entity @s {CustomName:'{"text":"絡繰仕掛の石像","italic":false}',Silent:1b,NoAI:1b,DeathLootTable:"minecraft:empty",PersistenceRequired :1b,Attributes:[{Name:"generic.max_health",Base:1024d}],ArmorDropChances:[0.000f,0.000f,0.000f,0.000f]}
+    scoreboard players operation @s ForwardTargetMobUUID = @e[type=slime,tag=CO.EntityRoot,limit=1] MobUUID
+    tag @s add Enemy
+    tag @s add Enemy.Boss
+    tag @s add ExtendedCollision
+    tag @s add AlwaysInvisible
+    tag @s add ProcessCommonTag
+    tag @s add CO.Hitbox
+    # effect give @s instant_health infinite 0 true

Asset/data/asset/functions/mob/0456.gargo_ex_machina/init/set_dps_timer.mcfunction

@@ -0,0 +1,11 @@
+#> asset:mob/0456.gargo_ex_machina/init/set_dps_timer
+#
+# Mobのinit時の処理
+#
+# @within asset:mob/0456.gargo_ex_machina/init/
+
+# 実HP計算
+    function api:mob/get_max_health
+    execute store result score @s CO.ActualHealth run data get storage api: Return.MaxHealth 1
+    data remove storage api: Return
+    scoreboard players set @s CO.DpsTimer 0

Asset/data/asset/functions/mob/0456.gargo_ex_machina/load.mcfunction

@@ -0,0 +1,31 @@
+#> asset:mob/0456.gargo_ex_machina/load
+#
+# Mobに利用するスコアボード等の初期化処理
+#
+# @within tag/function asset:mob/load
+
+#> 定義類はここに
+# @within function asset:mob/0456.gargo_ex_machina/**
+    scoreboard objectives add CO.EventTimer dummy
+    scoreboard objectives add CO.EventTimer.UpperShot dummy
+    scoreboard objectives add CO.EventTimer.BluteForce dummy
+    scoreboard objectives add CO.FieldModify.Color dummy
+    scoreboard objectives add CO.Counter dummy
+    scoreboard objectives add CO.IdleTimer dummy
+    scoreboard objectives add CO.PreTimer dummy
+    scoreboard objectives add CO.JumpCount dummy
+    scoreboard objectives add CO.BattleTimer dummy
+    scoreboard objectives add CO.DpsTimer dummy
+    scoreboard objectives add CO.HealthOffset dummy
+    scoreboard objectives add CO.ActualHealth dummy
+#> Object管理用
+# @within function asset:mob/0456.gargo_ex_machina/**
+# @within function asset:object/2260.gem_attack_drone/**
+# @within function asset:object/2261.gem_yeeter_drone/**
+# @within function asset:object/2262.gem_panjan_drone/**
+# @within function asset:object/2269.gem_rocket_punch/**
+    scoreboard objectives add CO.ObjectId dummy
+#> Object管理用
+# @within function asset:mob/0456.gargo_ex_machina/**
+# @within function asset:mob/2268.gem_upper_shot/**
+    scoreboard objectives add CO.UpperShot.Hit dummy