✨ [Artifact 1144] 蒼き月の揺り籠を作成

Asset/data/asset/functions/artifact/1144.cradle_of_azure_moon/give/1.trigger.mcfunction

@@ -0,0 +1,7 @@
+#> asset:artifact/1144.cradle_of_azure_moon/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1144} run function asset:artifact/1144.cradle_of_azure_moon/give/2.give

Asset/data/asset/functions/artifact/1144.cradle_of_azure_moon/give/2.give.mcfunction

@@ -0,0 +1,71 @@
+#> asset:artifact/1144.cradle_of_azure_moon/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1144.cradle_of_azure_moon/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1144
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:carrot_on_a_stick"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '[{"text":"蒼","color":"#6a9cff"},{"text":"き","color":"#69a1ff"},{"text":"月","color":"#68a7ff"},{"text":"の","color":"#66acff"},{"text":"揺","color":"#65b2ff"},{"text":"り","color":"#64b7ff"},{"text":"籠","color":"#63bdff"}]'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['{"text":"周囲の敵に攻撃するクラゲを召喚する","color":"white"}','{"text":"蒼い海月を抱いた水の揺り籠","color":"gray"}','{"text":"月は水面に揺らめき、静寂に漂う","color":"gray"}']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    # data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
+    # data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "auto"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "onClick"
+# 神器の発動条件 (TextComponentString) (オプション)
+    # data modify storage asset:artifact Condition set value
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.Damage set value [300,500]
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackType set value [Magic]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.ElementType set value [Water]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.IsRangeAttack set value "every"
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackRange set value "4.5"
+# MP消費量 (int)
+    data modify storage asset:artifact MPCost set value 200
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# MP回復量 (int)
+    # data modify storage asset:artifact MPHealWhenHit set value
+# 神器のクールダウン (int) (オプション)
+    # data modify storage asset:artifact LocalCooldown set value
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    data modify storage asset:artifact TypeCooldown.Type set value "summon"
+    data modify storage asset:artifact TypeCooldown.Duration set value 550
+# 第二種別クールダウン ({Type: string, Duration: int}) (オプション)
+    data modify storage asset:artifact SecondaryTypeCooldown.Type set value "longRange"
+    data modify storage asset:artifact SecondaryTypeCooldown.Duration set value 100
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableCooldownMessage set value
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableMPMessage set value
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ["Flora", "Wi-ki", "Rumor"]
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give

Asset/data/asset/functions/artifact/1144.cradle_of_azure_moon/register.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1144.cradle_of_azure_moon/register
+#
+# 神器プールへの登録処理
+#
+# @within tag/function asset:artifact/register
+
+data modify storage asset:artifact RarityRegistry[4] append value [1144]
+data modify storage asset:artifact RarityRegistryWithColor.Red[4] append value [1144]

Asset/data/asset/functions/artifact/1144.cradle_of_azure_moon/trigger/1.trigger.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1144.cradle_of_azure_moon/trigger/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのautoに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{auto:1144} run function asset:artifact/1144.cradle_of_azure_moon/trigger/2.check_condition

Asset/data/asset/functions/artifact/1144.cradle_of_azure_moon/trigger/2.check_condition.mcfunction

@@ -0,0 +1,12 @@
+#> asset:artifact/1144.cradle_of_azure_moon/trigger/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1144.cradle_of_azure_moon/trigger/1.trigger
+
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/auto
+# 他にアイテム等確認する場合はここに書く
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1144.cradle_of_azure_moon/trigger/3.main

Asset/data/asset/functions/artifact/1144.cradle_of_azure_moon/trigger/3.main.mcfunction

@@ -0,0 +1,18 @@
+#> asset:artifact/1144.cradle_of_azure_moon/trigger/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1144.cradle_of_azure_moon/trigger/2.check_condition
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/auto
+
+# ここから先は神器側の効果の処理を書く
+
+# Object召喚
+    data modify storage api: Argument.ID set value 1061
+    data modify storage api: Argument.FieldOverride.Damage set value {Min:300,Max:500}
+    data modify storage api: Argument.FieldOverride.Tick set value 750
+    data modify storage api: Argument.FieldOverride.AttackCD.Max set value 45
+    execute store result storage api: Argument.FieldOverride.UserID int 1 run scoreboard players get @s UserID
+    execute anchored eyes rotated ~ 0 positioned ^ ^-1 ^1.5 run function api:object/summon

Asset/data/asset/functions/object/1061.azure_jelly/_index.d.mcfunction

@@ -0,0 +1,8 @@
+#> asset:object/1061.azure_jelly/_index.d
+# @private
+
+#> tag
+# @within function asset:object/1061.azure_jelly/**
+    #declare tag 1061.Owner
+    #declare score_holder $Interval
+    #declare score_holder $Recursive

Asset/data/asset/functions/object/1061.azure_jelly/init/.mcfunction

@@ -0,0 +1,8 @@
+#> asset:object/1061.azure_jelly/init/
+#
+# Objectのinit時の処理
+#
+# @within asset:object/alias/1061/init
+
+# 初期化
+    scoreboard players set @s General.Object.Tick -1

Asset/data/asset/functions/object/1061.azure_jelly/load.mcfunction

@@ -0,0 +1,9 @@
+#> asset:object/1061.azure_jelly/load
+#
+# Objectに利用するスコアボード等の初期化処理
+#
+# @within tag/function asset:object/load
+
+#> 定義類はここに
+# @within function asset:object/1061.azure_jelly/**
+    scoreboard objectives add 1061.Pitch dummy

Asset/data/asset/functions/object/1061.azure_jelly/predicate/far_player.mcfunction

@@ -0,0 +1,11 @@
+#> asset:object/1061.azure_jelly/predicate/far_player
+#
+#
+#
+# @within function asset:object/1061.azure_jelly/tick/turn/
+
+# プレイヤーが近くにいたらfail
+    execute positioned ~-6 ~-1 ~-6 if entity @p[tag=1061.Owner,dx=11,dy=1,dz=11] run return 0
+
+# 成功
+    return 1

Asset/data/asset/functions/object/1061.azure_jelly/predicate/near_enemy.mcfunction

@@ -0,0 +1,11 @@
+#> asset:object/1061.azure_jelly/predicate/near_enemy
+#
+#
+#
+# @within function asset:object/1061.azure_jelly/tick/turn/
+
+# 敵が近くにいるかを判定
+    execute positioned ~-8 ~-8 ~-8 unless entity @e[type=#lib:living_without_player,tag=Enemy,dx=15,dy=15,dz=15,limit=1] run return 0
+
+# 成功
+    return 1

Asset/data/asset/functions/object/1061.azure_jelly/predicate/near_player.mcfunction

@@ -0,0 +1,11 @@
+#> asset:object/1061.azure_jelly/predicate/near_player
+#
+#
+#
+# @within function asset:object/1061.azure_jelly/tick/turn/
+
+# プレイヤーが近くにいないならfail
+    execute positioned ~-6 ~-1 ~-6 unless entity @p[tag=1061.Owner,dx=11,dy=1,dz=11] run return 0
+
+# 成功
+    return 1

Asset/data/asset/functions/object/1061.azure_jelly/predicate/no_collision.mcfunction

@@ -0,0 +1,17 @@
+#> asset:object/1061.azure_jelly/predicate/no_collision
+#
+#
+#
+# @within function asset:object/1061.azure_jelly/tick/move/**
+
+# 判定
+    execute unless block ~ ~-0.75 ~ #lib:no_collision/ run return 0
+    execute unless block ~ ~-0.5 ~ #lib:no_collision/ run return 0
+    execute unless block ~ ~0.0 ~ #lib:no_collision/ run return 0
+    execute unless block ~0.35 ~1.0 ~0.35 #lib:no_collision/ run return 0
+    execute unless block ~0.35 ~1.0 ~-0.35 #lib:no_collision/ run return 0
+    execute unless block ~-0.35 ~1.0 ~0.35 #lib:no_collision/ run return 0
+    execute unless block ~-0.35 ~1.0 ~-0.35 #lib:no_collision/ run return 0
+
+# 成功
+    return 1

Asset/data/asset/functions/object/1061.azure_jelly/register.mcfunction

@@ -0,0 +1,28 @@
+#> asset:object/1061.azure_jelly/register
+#
+# Objectのデータを指定
+#
+# @within function asset:object/alias/1061/register
+
+# 継承(オプション)
+    # data modify storage asset:object Extends append value
+    # function asset:object/extends
+# 他のObjectに継承されることを許可するか (boolean) (オプション)
+    # data modify storage asset:object ExtendsSafe set value
+# 継承されることを前提とした、抽象的なObjectであるかどうか(boolean)
+    data modify storage asset:object IsAbstract set value false
+# Tickするかどうか(boolean) (オプション)
+    # data modify storage asset:object IsTicking set value
+
+# ID (int)
+    data modify storage asset:object ID set value 1061
+# フィールド(オプション)
+    data modify storage asset:object Field.Tick set value 750
+    data modify storage asset:object Field.IsFirst set value true
+    data modify storage asset:object Field.IsUpper set value true
+    data modify storage asset:object Field.WaveLeftRotate set value true
+    data modify storage asset:object Field.AttackCD._ set value 0
+    data modify storage asset:object Field.AttackCD.Max set value 45
+    data modify storage asset:object Field.SpeedMultiplier set value 1
+    data modify storage asset:object Field.Damage set value {Min:1,Max:10}
+    data modify storage asset:object Field.UserID set value -1

Asset/data/asset/functions/object/1061.azure_jelly/summon/.mcfunction

@@ -0,0 +1,11 @@
+#> asset:object/1061.azure_jelly/summon/
+#
+# Object召喚処理の呼び出し時に実行されるfunction
+#
+# @within asset:object/alias/1061/summon
+
+# 元となるEntityを召喚する
+    execute as 0-0-0-0-0 in minecraft:overworld positioned as @s run tp @s ~ ~ ~ ~ 0
+    data modify storage asset:temp Args.Rotation set from entity 0-0-0-0-0 Rotation
+    function asset:object/1061.azure_jelly/summon/m with storage asset:temp Args
+    data remove storage asset:temp Args

Asset/data/asset/functions/object/1061.azure_jelly/summon/m.mcfunction

@@ -0,0 +1,7 @@
+#> asset:object/1061.azure_jelly/summon/m
+#
+#
+#
+# @within function asset:object/1061.azure_jelly/summon/
+
+$summon armor_stand ~ ~ ~ {Tags:["ObjectInit","Friend"],Rotation:$(Rotation),Marker:1b,Invisible:1b,Passengers:[{id:"minecraft:item_display",Rotation:[90f,0f],Tags:["ProcessCommonTag","AutoKillWhenDieVehicle"],teleport_duration:1,brightness:{sky:10,block:10},item:{id:"minecraft:stick",Count:1b,tag:{CustomModelData:20578}},transformation:{left_rotation:[0f,0f,0f,1f],right_rotation:[0f,0f,0f,1f],scale:[1f,1f,1f],translation:[0f,-0.5f,0f]}}]}

Asset/data/asset/functions/object/1061.azure_jelly/tick/.mcfunction

@@ -0,0 +1,50 @@
+#> asset:object/1061.azure_jelly/tick/
+#
+# Objectのtick時の処理
+#
+# @within asset:object/alias/1061/tick
+
+#> Private
+# @private
+    #declare score_holder $UserID
+
+# 存在時間フィールド減算
+    execute store result storage asset:context this.Tick int 0.9999999999 run data get storage asset:context this.Tick
+
+# 常時演出
+    particle dust 0.267 0.729 0.945 0.9 ~ ~ ~ 0.4 0.6 0.4 0 1 normal @a
+    execute if predicate lib:random_pass_per/40 run particle scrape ~ ~ ~ 0.4 0.6 0.4 0 1 normal @a
+
+# 召喚演出 その間はreturnする
+    execute if data storage asset:context this{IsFirst:true} run return run function asset:object/1061.azure_jelly/tick/summon_effect/
+
+# OwnerにTag付与
+    execute store result score $UserID Temporary run data get storage asset:context this.UserID
+    execute as @a if score @s UserID = $UserID Temporary run tag @s add 1061.Owner
+
+# インターバル
+    execute store result score $Interval Temporary run data get storage asset:context this.Tick
+    scoreboard players operation $Interval Temporary %= $50 Const
+
+# 移動方向設定
+    execute if score $Interval Temporary matches 0 run function asset:object/1061.azure_jelly/tick/turn/
+
+# 角度
+    execute if score $Interval Temporary matches 0 at @s run function asset:object/1061.azure_jelly/tick/pitch/init
+    execute at @s run function asset:object/1061.azure_jelly/tick/pitch/
+
+# 移動
+    execute at @s run function asset:object/1061.azure_jelly/tick/move/
+
+# 攻撃関連の処理
+    execute at @s run function asset:object/1061.azure_jelly/tick/attack/
+
+    #execute at @s run particle flame ^ ^ ^ 0 0 0 0 1
+
+# リセット
+    scoreboard players reset $UserID Temporary
+    scoreboard players reset $Interval Temporary
+    tag @p[tag=1061.Owner] remove 1061.Owner
+
+# 消滅処理
+    execute if data storage asset:context this{Tick:0} run function asset:object/1061.azure_jelly/tick/kill

Asset/data/asset/functions/object/1061.azure_jelly/tick/attack/.mcfunction

@@ -0,0 +1,14 @@
+#> asset:object/1061.azure_jelly/tick/attack/
+#
+# 攻撃関連の処理
+#
+# @within function asset:object/1061.azure_jelly/tick/
+
+# クールダウンをデクリメント
+    execute store result storage asset:context this.AttackCD._ int 0.9999999999 run data get storage asset:context this.AttackCD._
+
+# CDが0でなければreturn
+    execute unless data storage asset:context this.AttackCD{_:0} run return fail
+
+# 敵が近くにいたら攻撃
+    execute positioned ~-3 ~-3 ~-3 if entity @e[type=#lib:living_without_player,tag=Enemy,tag=!Uninterferable,dx=5,dy=5,dz=5] at @s run function asset:object/1061.azure_jelly/tick/attack/attack

Asset/data/asset/functions/object/1061.azure_jelly/tick/attack/attack.mcfunction

@@ -0,0 +1,29 @@
+#> asset:object/1061.azure_jelly/tick/attack/attack
+#
+#
+#
+# @within function asset:object/1061.azure_jelly/tick/attack/
+
+# 演出
+    execute rotated ~ 0 positioned ~ ~-0.3 ~ run function asset:object/1061.azure_jelly/tick/vfx/circle1
+    execute rotated ~ 0 positioned ~ ~-0.3 ~ run function asset:object/1061.azure_jelly/tick/vfx/circle2
+
+# 波Objectの演出
+    function asset:object/1061.azure_jelly/tick/attack/summon_wave/
+
+# 円柱Libを用いて判定する
+    data modify storage lib: Argument.BoundingCylinder.Radius set value 4.5d
+    data modify storage lib: Argument.BoundingCylinder.Height set value 7.0d
+    data modify storage lib: Argument.BoundingCylinder.Selector set value "@e[type=#lib:living_without_player,tag=Enemy,tag=!Uninterferable,distance=..7]"
+    execute positioned ~ ~-3 ~ run function lib:bounding_cylinder/
+
+# 壁貫通していない敵にダメージ
+    function api:damage/single_damage_session/open
+    execute as @e[type=#lib:living_without_player,tag=Enemy,tag=BoundingCylinder,tag=!Uninterferable,distance=..7] if function asset:object/1061.azure_jelly/tick/attack/check_block/ run function asset:object/1061.azure_jelly/tick/attack/damage.m with storage asset:context this.Damage
+    function api:damage/single_damage_session/close
+
+# リセット
+    tag @e[type=#lib:living_without_player,tag=BoundingCylinder,distance=..7] remove BoundingCylinder
+
+# AttackCD初期化
+    data modify storage asset:context this.AttackCD._ set from storage asset:context this.AttackCD.Max

Asset/data/asset/functions/object/1061.azure_jelly/tick/attack/check_block/.mcfunction

@@ -0,0 +1,20 @@
+#> asset:object/1061.azure_jelly/tick/attack/check_block/
+#
+#
+#
+# @within function asset:object/1061.azure_jelly/tick/attack/attack
+
+# 自身の方を見て再帰
+    execute facing entity @s feet run function asset:object/1061.azure_jelly/tick/attack/check_block/recursive
+
+# リセット
+    scoreboard players reset $Recursive Temporary
+
+# 失敗
+    execute unless data storage asset:temp 1061{Success:true} run return fail
+
+# storageをリセット
+    data remove storage asset:temp 1061
+
+# 成功
+    return 1

Asset/data/asset/functions/object/1061.azure_jelly/tick/attack/check_block/recursive.mcfunction

@@ -0,0 +1,16 @@
+#> asset:object/1061.azure_jelly/tick/attack/check_block/recursive
+#
+#
+#
+# @within function
+#   asset:object/1061.azure_jelly/tick/attack/check_block/
+#   asset:object/1061.azure_jelly/tick/attack/check_block/recursive
+
+# 再帰防止スコアをインクリメント
+    scoreboard players add $Recursive Temporary 1
+
+# 成功
+    execute positioned ~-0.5 ~-0.5 ~-0.5 if entity @s[dx=0] run data modify storage asset:temp 1061.Success set value true
+
+# 0.5ブロックずつ再帰
+    execute if score $Recursive Temporary matches ..14 positioned ^ ^ ^0.5 if block ~ ~ ~ #lib:no_collision/ run function asset:object/1061.azure_jelly/tick/attack/check_block/recursive