dotfiles/flake.nix at master · wrrn/dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
    flake-utils.url = "github:numtide/flake-utils/main";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      ...
    }@inputs:
    let
      dotFiles = (
        let
          ignoredFiles = [
            ".git"
            ".gitignore"
            "LICENSE"
            "Makefile"
            "flake.lock"
            "flake.nix"
          ];
          isIgnored = f: builtins.elem f ignoredFiles;
          allFiles = builtins.attrNames (builtins.readDir ./.);
        in
        builtins.filter (p: !isIgnored p) allFiles
      );

      mkDotfile =
        { pkgs, pname }:
        pkgs.stdenv.mkDerivation {
          inherit pname;
          name = pname;
          src = ./${pname};
          installPhase = ''
            mkdir -p $out
            cp -r $src/.* $out/ || true
            cp -r $src/* $out/  || true
          '';
        };

      packageDotfiles =
        { pkgs }: pkgs.lib.attrsets.genAttrs dotFiles (dir: (pkgs.callPackage mkDotfile { pname = dir; }));
    in
    {
      packages = flake-utils.lib.eachDefaultSystem (
        system:
        let
          pkgs = import nixpkgs { system = system; };
        in
        pkgs.callPackage packageDotfiles { }
      );

      overlays.default = (
        final: prev: {
          dotfiles = (final.callPackage packageDotfiles { });
        }
      );

    };
}