dreamy/dreamy.pro at main · textbrowser/dreamy · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
purge.commands = find . -name \'*~*\' -exec rm -f {} \;

CONFIG		+= qt release warn_on
DEFINES		+= QT_DEPRECATED_WARNINGS
LANGUAGE        = C++
QT		+= concurrent widgets
TEMPLATE        = app

QMAKE_CLEAN	+= Dreamy

android {
QMAKE_CXXFLAGS  += -Wall \
                   -Wcast-align \
                   -Wcast-qual \
                   -Werror \
                   -Werror=format-security \
                   -Wextra \
                   -Wformat=2 \
                   -Woverloaded-virtual \
                   -Wpointer-arith \
                   -Wstack-protector \
                   -Wstrict-overflow=1 \
                   -Wundef \
                   -fPIC \
                   -fstack-protector-all \
                   -fwrapv \
                   -pedantic \
                   -std=c++11
} else {
QMAKE_CXXFLAGS  += -Wall \
                   -Wcast-qual \
                   -Werror \
                   -Werror=format-security \
                   -Wextra \
                   -Wformat=2 \
                   -Wold-style-cast \
                   -Woverloaded-virtual \
                   -Wpointer-arith \
                   -Wstack-protector \
                   -Wstrict-overflow=1 \
                   -Wzero-as-null-pointer-constant \
                   -fPIE \
                   -fstack-protector-all \
                   -fwrapv \
                   -pedantic \
                   -std=c++11

linux-* {
QMAKE_CXXFLAGS  += -Wformat-overflow=2 \
                   -pie
}
}

greaterThan(QT_MAJOR_VERSION, 5) {
QMAKE_CXXFLAGS += -std=c++17
QMAKE_CXXFLAGS -= -std=c++11
}

QMAKE_EXTRA_TARGETS = purge

FORMS		= UI/dreamy.ui \
                  UI/dreamy_options.ui

HEADERS		= Source/dreamy.h \
                  Source/dreamy_label.h \
                  Source/dreamy_options.h

RESOURCES       = Icons/icons.qrc

SOURCES		= Source/dreamy_main.cc

PROJECTNAME	= Dreamy
TARGET		= Dreamy

android {
DISTFILES += Android/AndroidManifest.xml \
             Android/build.gradle \
             Android/gradle.properties \
             Android/gradle/wrapper/gradle-wrapper.jar \
             Android/gradle/wrapper/gradle-wrapper.properties \
             Android/gradlew \
             Android/gradlew.bat \
             Android/res/values/libs.xml \
             Android/res/xml/qtprovider_paths.xml

contains(ANDROID_TARGET_ARCH,armeabi-v7a) {
    ANDROID_PACKAGE_SOURCE_DIR = $$PWD/Android
}
}