rc/modules/home/git.nix at b4140d15b7d4653c9345c3a9abe71eee696b434d · stackptr/rc · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
{
  config,
  lib,
  pkgs,
  ...
}: let
  inherit (lib) mkIf mkOption;

  cfg = config.rc.git;
in {
  options = {
    rc.git = {
      enable = lib.mkEnableOption "Git-related configuration";

      enableHubWrapper = mkOption {
        default = true;
        example = true;
        description = "Whether to enable hub wrapper for git.";
        type = lib.types.bool;
      };

      enableInteractiveRebase = mkOption {
        default = true;
        example = true;
        description = "Whether to enable interactive rebase.";
        type = lib.types.bool;
      };

      enableJujutsu = mkOption {
        default = false;
        example = true;
        description = "Whether to enable jujutsu.";
        type = lib.types.bool;
      };
    };
  };

  config = lib.mkMerge [
    (mkIf cfg.enable {
      home.packages = [
        pkgs.onefetch
      ];

      programs.gh = {
        enable = true;
        gitCredentialHelper.enable = true;
      };

      programs.git = {
        enable = true;
        signing = {
          key = "F88C08579051AB48";
          signByDefault = true;
        };
        settings = {
          user = {
            name = "✿ corey";
            email = "corey@x64.co";
          };
          pull.rebase = true;
          push.autosetupremote = true;
          init.defaultBranch = "main";
          merge.conflictstyle = "zdiff3";
          rerere.enabled = true;
        };
      };

      programs.delta = {
        enable = true;
        enableGitIntegration = true;
      };

      programs.gpg = {
        enable = true;
        settings = {
          default-key = "413D1A0152BCB08D2E3DDACAF88C08579051AB48";
        };
      };
    })

    (mkIf cfg.enableHubWrapper {
      home.packages = [pkgs.hub];

      programs.zsh.shellAliases = {
        git = "${lib.getExe' pkgs.hub "hub"}";
      };
    })

    (mkIf cfg.enableInteractiveRebase {
      home.packages = [pkgs.git-interactive-rebase-tool];

      programs.git.settings.sequence.editor = "interactive-rebase-tool";
    })

    (mkIf cfg.enableJujutsu {
      programs.jujutsu = {
        enable = true;
      };
      programs.jjui = {
        enable = true;
      };

      programs.delta = {
        enable = true;
        enableJujutsuIntegration = true;
      };
    })
  ];
}