compatibility-test-plugin/build.gradle at main · spring-gradle-plugins/compatibility-test-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
plugins {
	id "checkstyle"
	id "io.spring.javaformat" version "$springJavaFormatVersion"
	id "io.spring.nohttp" version "0.0.11"
	id "java-gradle-plugin"
	id "maven-publish"
}

group "io.spring.gradle"
description = "Compatibility Test Plugin"

gradlePlugin {
	plugins {
		compatibilityTest {
			description = project.description
			displayName = project.description
			id = "io.spring.compatibility-test"
			implementationClass = "io.spring.gradle.compatibilitytest.CompatibilityTestPlugin"
		}
	}
}

repositories {
	mavenCentral()
}

dependencies {
	checkstyle("io.spring.javaformat:spring-javaformat-checkstyle:$springJavaFormatVersion")
	testImplementation("org.assertj:assertj-core:3.24.2")
	testImplementation("org.junit.jupiter:junit-jupiter:5.10.0")
}

sourceCompatibility = "1.8"
targetCompatibility = "1.8"

java {
	withJavadocJar()
	withSourcesJar()
}

test {
	useJUnitPlatform()
}

publishing {
	publications.withType(MavenPublication) {
		pom {
			name = project.description
			description = project.description
			url = "https://github.com/spring-gradle-plugins/compatibility-test-plugin"
			organization {
				name = "Spring IO"
				url = "https://spring.io"
			}
			licenses {
				license {
					name = "The Apache Software License, Version 2.0"
					url = "https://www.apache.org/licenses/LICENSE-2.0.txt"
					distribution = "repo"
				}
			}
			scm {
				url = "https://github.com/spring-gradle-plugins/compatibility-test-plugin"
				connection = "scm:git:git://github.com/spring-gradle-plugins/compatibility-test-plugin"
				developerConnection = "scm:git:git://github.com/spring-gradle-plugins/compatibility-test-plugin"
			}
			developers {
				developer {
					id = "wilkinsona"
					name = "Andy Wilkinson"
					email = "wilkinsona@vmware.com"
				}
			}
			issueManagement {
				system = "GitHub"
				url = "https://github.com/spring-gradle-plugins/compatibility-test-plugin"
			}
		}
	}
	if (project.hasProperty("deploymentRepository")) {
		repositories {
			maven {
				url = "${deploymentRepository}"
				name = "deployment"
			}
		}
	}
}