[builtins] download instead of bundle xxhash

add CMakeLists patch

rm bundled copy

Author: ferdymercury

builtins/xxhash/CMakeLists.txt

@@ -1,35 +1,71 @@
-# Copyright (C) 1995-2021, Rene Brun and Fons Rademakers.
-# All rights reserved.
+# Copyright (C) 1995-2026, Rene Brun and Fons Rademakers. All rights reserved.
 #
-# For the licensing terms see $ROOTSYS/LICENSE.
-# For the list of contributors see $ROOTSYS/README/CREDITS.
+# For the licensing terms see $ROOTSYS/LICENSE. For the list of contributors see
+# $ROOTSYS/README/CREDITS.
 
-project(xxhash C)
+# **PLEASE UPDATE ALSO THE FOLLOWING LINE WHEN UPDATING THE VERSION** 30 Dec
+# 2024, https://github.com/Cyan4973/xxHash/releases/tag/v0.8.3
+set(ROOT_XXHASH_VERSION 0.8.3)
+set(ROOT_XXHASH_HASH "aae608dfe8213dfd05d909a57718ef82f30722c392344583d3f39050c7f29a80")
+# The sources come w/o CMakeList.txt as of version 0.8.3. We add ours, it's very
+# simple.
+set(ROOT_XXHASH_PATCH_FILE
+    ${CMAKE_CURRENT_SOURCE_DIR}/xxhash_add_cmakelists.patch)
 
-unset(xxHash_FOUND CACHE)
-unset(xxHash_FOUND PARENT_SCOPE)
-set(xxHash_FOUND TRUE CACHE BOOL "" FORCE)
+set(ROOT_XXHASH_PREFIX ${CMAKE_BINARY_DIR}/builtins/XXHASH-prefix)
 
-file(STRINGS xxhash.h XXHASH_H REGEX "^#define XXH_VERSION_[A-Z]+[ ]+[0-9]+$")
-string(REGEX REPLACE ".+XXH_VERSION_MAJOR[ ]+([0-9]+).*$"   "\\1" xxHash_VERSION_MAJOR "${XXHASH_H}")
-string(REGEX REPLACE ".+XXH_VERSION_MINOR[ ]+([0-9]+).*$"   "\\1" xxHash_VERSION_MINOR "${XXHASH_H}")
-string(REGEX REPLACE ".+XXH_VERSION_RELEASE[ ]+([0-9]+).*$" "\\1" xxHash_VERSION_PATCH "${XXHASH_H}")
-set(xxHash_VERSION_STRING "${xxHash_VERSION_MAJOR}.${xxHash_VERSION_MINOR}.${xxHash_VERSION_PATCH}")
+set(ROOT_XXHASH_LIBRARY
+    ${ROOT_XXHASH_PREFIX}/lib/${CMAKE_STATIC_LIBRARY_PREFIX}xxhash-static${CMAKE_STATIC_LIBRARY_SUFFIX}
+)
 
-set(xxHash_VERSION ${xxHash_VERSION_STRING} CACHE INTERNAL "")
-set(xxHash_VERSION_STRING ${xxHash_VERSION_STRING} CACHE INTERNAL "")
+if(WIN32 AND NOT CMAKE_GENERATOR MATCHES Ninja)
+  if(winrtdebug)
+    set(ROOT_LIBGIF_BUILD_COMMAND_FLAGS "--config Debug")
+  else()
+    set(ROOT_LIBGIF_BUILD_COMMAND_FLAGS
+        "--config $<IF:$<CONFIG:Debug,RelWithDebInfo>,RelWithDebInfo,Release>")
+  endif()
+endif()
 
-set(xxHash_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR} CACHE INTERNAL "")
-set(xxHash_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR} CACHE INTERNAL "")
-mark_as_advanced(xxHash_INCLUDE_DIR)
+ExternalProject_Add(
+  BUILTIN_XXHASH
+  PREFIX ${ROOT_XXHASH_PREFIX}
+  URL https://github.com/Cyan4973/xxHash/archive/refs/tags/v${ROOT_XXHASH_VERSION}.tar.gz
+  URL_HASH SHA256=${ROOT_XXHASH_HASH}
+  PATCH_COMMAND git apply ${ROOT_XXHASH_PATCH_FILE}
+  CMAKE_ARGS -G
+             ${CMAKE_GENERATOR}
+             -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
+             -DCMAKE_INSTALL_PREFIX=<INSTALL_DIR>
+             -DCMAKE_POSITION_INDEPENDENT_CODE=ON
+             -DCMAKE_C_VISIBILITY_PRESET=hidden
+  BUILD_COMMAND ${CMAKE_COMMAND} --build . ${ROOT_XXHASH_BUILD_COMMAND_FLAGS}
+  INSTALL_COMMAND ${CMAKE_COMMAND} --build . ${ROOT_XXHASH_BUILD_COMMAND_FLAGS}
+                  --target install
+  LOG_CONFIGURE 1
+  LOG_BUILD 1
+  LOG_INSTALL 1
+  LOG_OUTPUT_ON_FAILURE 1
+  BUILD_BYPRODUCTS ${ROOT_XXHASH_LIBRARY}
+  TIMEOUT 600)
 
-add_library(xxhash STATIC xxhash.h xxhash.c)
-set_target_properties(xxhash PROPERTIES C_VISIBILITY_PRESET hidden POSITION_INDEPENDENT_CODE ON)
-target_include_directories(xxhash INTERFACE $<BUILD_INTERFACE:${xxHash_INCLUDE_DIR}>)
+file(MAKE_DIRECTORY ${ROOT_XXHASH_PREFIX})
+add_library(xxHash::xxHash IMPORTED STATIC GLOBAL)
+set_target_properties(
+  xxHash::xxHash PROPERTIES IMPORTED_LOCATION ${ROOT_XXHASH_LIBRARY}
+                            INTERFACE_INCLUDE_DIRECTORIES ${ROOT_XXHASH_PREFIX})
 
-add_library(xxHash::xxHash ALIAS xxhash)
-
-set(xxHash_LIBRARY $<TARGET_FILE:xxhash> CACHE INTERNAL "")
-set(xxHash_LIBRARIES xxHash::xxHash CACHE INTERNAL "")
-
-set_property(GLOBAL APPEND PROPERTY ROOT_BUILTIN_TARGETS xxHash::xxHash)
+# Set the canonical output of find_package according to
+# https://cmake.org/cmake/help/latest/manual/cmake-developer.7.html#standard-variable-names
+set(xxHash_INCLUDE_DIRS
+    ${ROOT_XXHASH_PREFIX}
+    PARENT_SCOPE)
+set(xxHash_LIBRARIES
+    ${ROOT_XXHASH_LIBRARY}
+    PARENT_SCOPE)
+set(xxHash_FOUND
+    TRUE
+    PARENT_SCOPE)
+set(xxHash_VERSION
+    ${ROOT_XXHASH_VERSION}
+    PARENT_SCOPE)