ring-headers/test/ring/middleware/proxy_headers_test.clj at eccc7c0c59485d3db2e493736230747f91db690a · ring-clojure/ring-headers · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
(ns ring.middleware.proxy-headers-test
  (:use clojure.test
        ring.middleware.proxy-headers
        [ring.mock.request :only [request header]]
        [ring.util.response :only [response]]))

(deftest test-wrap-forwarded-remote-addr
  (let [handler (wrap-forwarded-remote-addr (comp response :remote-addr))]
    (testing "without x-forwarded-for"
      (let [req  (assoc (request :get "/") :remote-addr "1.2.3.4")
            resp (handler req)]
        (is (= (:body resp) "1.2.3.4"))))

    (testing "with x-forwarded-for"
      (let [req  (-> (request :get "/")
                     (assoc :remote-addr "127.0.0.1")
                     (header "x-forwarded-for" "1.2.3.4"))
            resp (handler req)]
        (is (= (:body resp) "1.2.3.4"))))

    (testing "with multiple proxies"
      (let [req  (-> (request :get "/")
                     (assoc :remote-addr "127.0.0.1")
                     (header "x-forwarded-for" "10.0.1.9, 192.168.4.98, 1.2.3.4"))
            resp (handler req)]
        (is (= (:body resp) "1.2.3.4"))))))

(deftest test-wrap-forwarded-remote-addr-multiple-proxies
  (let [handler (wrap-forwarded-remote-addr (comp response :remote-addr) {:proxy-count 2})]
    (testing "without x-forwarded-for"
      (let [req (assoc (request :get "/") :remote-addr "1.2.3.4")
            resp (handler req)]
        (is (= (:body resp) "1.2.3.4"))))
    ;; TODO: what should happen if there aren't enough Forwarded addresses? Nothing?
    (testing "with not enough proxies"
      (let [req (-> (request :get "/")
                    (assoc :remote-addr "127.0.0.1")
                    (header "x-forwarded-for" "1.2.3.4"))
            resp (handler req)]
        (is (= (:body resp) "127.0.0.1"))))
    (testing "request with two proxies"
      (let [req (-> (request :get "/")
                    (assoc :remote-addr "127.0.0.1")
                    (header "x-forwarded-for" "122.54.196.223, 1.2.3.4"))
            resp (handler req)]
        (is (= (:body resp) "122.54.196.223"))))
    (testing "request with two trusted proxies and one untrusted proxy"
      (let [req (-> (request :get "/")
                    (assoc :remote-addr "127.0.0.1")
                    (header "x-forwarded-for" "10.0.1.9, 122.54.196.223, 1.2.3.4"))
            resp (handler req)]
        (is (= (:body resp) "122.54.196.223")))))
  (testing "proxy count of 0"
    (is (thrown?
          AssertionError
          (wrap-forwarded-remote-addr (comp response :remote-addr) {:proxy-count 0})))))

(deftest test-wrap-forwarded-remote-addr-cps
  (let [handler (wrap-forwarded-remote-addr
                 (fn [request respond _] (respond (response (:remote-addr request)))))]
    (testing "without x-forwarded-for"
      (let [req  (assoc (request :get "/") :remote-addr "1.2.3.4")
            resp (promise)
            ex   (promise)]
        (handler req resp ex)
        (is (not (realized? ex)))
        (is (= (:body @resp) "1.2.3.4"))))

    (testing "with x-forwarded-for"
      (let [req  (-> (request :get "/")
                     (assoc :remote-addr "127.0.0.1")
                     (header "x-forwarded-for" "1.2.3.4"))
            resp (promise)
            ex   (promise)]
        (handler req resp ex)
        (is (not (realized? ex)))
        (is (= (:body @resp) "1.2.3.4"))))))