thread_pool/CMakeLists.txt at master · revl/thread_pool · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
cmake_minimum_required(VERSION 3.6)

set(CMAKE_CXX_STANDARD 11)

project(thread_pool LANGUAGES CXX VERSION 0.5.0)

add_compile_options(-Wall -Wextra -Werror)

include(CheckCXXCompilerFlag)
CHECK_CXX_COMPILER_FLAG(-Wpedantic COMPILER_SUPPORTS_WPEDANTIC)
if(COMPILER_SUPPORTS_WPEDANTIC)
	add_compile_options(-Wpedantic)
endif()

add_library(${PROJECT_NAME} src/${PROJECT_NAME}.cpp)

set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
set(THREADS_PREFER_PTHREAD_FLAG TRUE)
find_package(Threads REQUIRED)

target_link_libraries(${PROJECT_NAME} Threads::Threads)

target_include_directories(${PROJECT_NAME} PUBLIC
	$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
	$<INSTALL_INTERFACE:include>
)

if(${CMAKE_PROJECT_NAME} STREQUAL ${PROJECT_NAME})
	set(EXPORT_NAME ThreadPoolOnMutexes)

	set_target_properties(${PROJECT_NAME}
		PROPERTIES EXPORT_NAME ${EXPORT_NAME})

	include(GNUInstallDirs)

	install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include/
		DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
	)

	install(TARGETS ${PROJECT_NAME}
		EXPORT ${EXPORT_NAME}Targets
		DESTINATION ${CMAKE_INSTALL_LIBDIR}
	)

	install(EXPORT ${EXPORT_NAME}Targets
		FILE ${EXPORT_NAME}Targets.cmake
		DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${EXPORT_NAME}
	)

	include(CMakePackageConfigHelpers)
	write_basic_package_version_file(
		${CMAKE_CURRENT_BINARY_DIR}/${EXPORT_NAME}ConfigVersion.cmake
		VERSION ${PROJECT_VERSION}
		COMPATIBILITY SameMajorVersion
	)

	configure_package_config_file(
		${PROJECT_SOURCE_DIR}/cmake/${EXPORT_NAME}Config.cmake.in
		${CMAKE_CURRENT_BINARY_DIR}/${EXPORT_NAME}Config.cmake
		INSTALL_DESTINATION
		${CMAKE_INSTALL_LIBDIR}/cmake/${EXPORT_NAME}
	)

	install(FILES
		${CMAKE_CURRENT_BINARY_DIR}/${EXPORT_NAME}Config.cmake
		${CMAKE_CURRENT_BINARY_DIR}/${EXPORT_NAME}ConfigVersion.cmake
		DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${EXPORT_NAME}
	)

	export(EXPORT ${EXPORT_NAME}Targets FILE
		${CMAKE_CURRENT_BINARY_DIR}/${EXPORT_NAME}Targets.cmake
	)

	export(PACKAGE ${EXPORT_NAME})

	include(CTest)

	if(BUILD_TESTING)
		option(BUILD_COVERAGE "Enable code coverage report" OFF)

		if(BUILD_COVERAGE)
			include(CodeCoverage)

			append_coverage_compiler_flags()
		endif()

		add_subdirectory(tests)
	endif()

	include(InstallRequiredSystemLibraries)
	set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
	include(CPack)
endif()