documentation-generator/build.gradle at main · patrickfust/documentation-generator · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
plugins {
    id 'java-library'
    id 'groovy'
    id 'maven-publish'
    id 'org.jreleaser' version '1.23.0'
}

allprojects {
    group = 'dk.fust.docgen'
    version = '1.17.0'

    plugins.withType(JavaPlugin).whenPluginAdded {
        dependencies {
            implementation 'org.projectlombok:lombok:1.18.46'
            annotationProcessor 'org.projectlombok:lombok:1.18.46'

            implementation 'org.slf4j:slf4j-api:2.0.17'
            testRuntimeOnly 'org.slf4j:slf4j-log4j12:2.0.17'
            testRuntimeOnly 'org.apache.logging.log4j:log4j-api:2.25.4'
            testRuntimeOnly 'org.apache.logging.log4j:log4j-core:2.25.4'

            testImplementation project(':helpers:documentation-generator-test-utilities')
            testImplementation platform('org.spockframework:spock-bom:2.4-groovy-5.0')
            testImplementation 'org.spockframework:spock-core'
            testRuntimeOnly 'org.junit.platform:junit-platform-launcher:6.0.3'
        }

        tasks.withType(Test).configureEach {
            // Using JUnitPlatform for running tests
            useJUnitPlatform()

        }
        java {
            withSourcesJar()
            withJavadocJar()
        }
    }

    plugins.withType(MavenPublishPlugin).whenPluginAdded {
        publishing {
            publications {
                maven(MavenPublication) {
                    groupId = group
                    artifactId = project.name
                    version = version

                    from components.java

                    pom {
                        name = 'Documentation Generator'
                        url = 'https://github.com/patrickfust/documentation-generator'
                        licenses {
                            license {
                                name = 'The Apache License, Version 2.0'
                                url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                            }
                        }
                        developers {
                            developer {
                                id = 'patrickfust'
                                name = 'Patrick Fust'
                                email = 'patrick.fust@gmail.com'
                            }
                        }
                        scm {
                            connection = 'scm:git:git://github.com/patrickfust/documentation-generator.git'
                            developerConnection = 'scm:git:git://github.com/patrickfust/documentation-generator.git'
                            url = 'https://github.com/patrickfust/documentation-generator'
                        }
                    }
                }
            }
        }
    }

    repositories {
        mavenLocal()
        mavenCentral()
    }

}

jreleaser {
    configFile = 'jreleaser.yml'
}