python-jsonpath2/jsonpath2/parser/JSONPath.g4 at b50e86aae5bacc715660d8d8f31eb9ee5ad13eba · pacifica/python-jsonpath2 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
grammar JSONPath;

CURRENT_VALUE : '@' ;
RECURSIVE_DESCENT : '..' ;
ROOT_VALUE : '$' ;
SUBSCRIPT : '.' ;
WILDCARD_SUBSCRIPT : '*' ;

AND : 'and' ;
EQ : '=' ;
GE : '>=' ;
GT : '>' ;
LE : '<=' ;
LT : '<' ;
NE : '!=' ;
RE : '~=' ;
NOT : 'not' ;
OR : 'or' ;
CN : 'contains' ;

TRUE : 'true' ;
FALSE : 'false' ;
NULL : 'null' ;

BRACE_LEFT : '{' ;
BRACE_RIGHT : '}' ;
BRACKET_LEFT : '[' ;
BRACKET_RIGHT : ']' ;
COLON : ':' ;
COMMA : ',' ;
PAREN_LEFT : '(' ;
PAREN_RIGHT : ')' ;
QUESTION : '?' ;

jsonpath
   : ROOT_VALUE subscript? EOF
   ;

jsonpath_
   : ( ROOT_VALUE | CURRENT_VALUE ) subscript?
   ;

jsonpath__
   : jsonpath_
   | value
   ;


subscript
   : RECURSIVE_DESCENT ( subscriptableBareword | subscriptables ) subscript?
   | SUBSCRIPT subscriptableBareword subscript?
   | subscriptables subscript?
   ;

subscriptables
   : BRACKET_LEFT subscriptable ( COMMA subscriptable )* BRACKET_RIGHT
   ;

subscriptableArguments
   : PAREN_LEFT ( jsonpath__ ( COMMA jsonpath__ )* )? PAREN_RIGHT
   ;

subscriptableBareword
   : ID subscriptableArguments?
   | WILDCARD_SUBSCRIPT
   ;

subscriptable
   : STRING
   | NUMBER{self.tryCast(int)}? sliceable?
   | sliceable
   | WILDCARD_SUBSCRIPT
   | QUESTION PAREN_LEFT expression PAREN_RIGHT
   | jsonpath_
   | ID subscriptableArguments
   ;

sliceable
   : COLON ( NUMBER{self.tryCast(int)}? )? ( COLON ( NUMBER{self.tryCast(int)}? )? )?
   ;

expression
   : andExpression
   ;

andExpression
   : orExpression ( AND andExpression )?
   ;

orExpression
   : notExpression ( OR orExpression )?
   ;

notExpression
   : NOT notExpression
   | PAREN_LEFT expression PAREN_RIGHT
   | jsonpath__ ( ( EQ | NE | LT | LE | GT | GE | CN | RE ) jsonpath__ )?
   ;


ID
   : [_A-Za-z] [_A-Za-z0-9]*
   ;


/* c.f., https://github.com/antlr/grammars-v4/blob/master/json/JSON.g4 */

json
   : value
   ;

obj
   : BRACE_LEFT pair ( COMMA pair )* BRACE_RIGHT
   | BRACE_LEFT BRACE_RIGHT
   ;

pair
   : STRING COLON value
   ;

array
   : BRACKET_LEFT value ( COMMA value )* BRACKET_RIGHT
   | BRACKET_LEFT BRACKET_RIGHT
   ;

value
   : STRING
   | NUMBER
   | obj
   | array
   | TRUE
   | FALSE
   | NULL
   ;


STRING
   : '"' (ESC | SAFECODEPOINT)* '"'
   ;


fragment ESC
   : '\\' (["\\/bfnrt] | UNICODE)
   ;
fragment UNICODE
   : 'u' HEX HEX HEX HEX
   ;
fragment HEX
   : [0-9a-fA-F]
   ;
fragment SAFECODEPOINT
   : ~ ["\\\u0000-\u001F]
   ;


NUMBER
   : '-'? INT ('.' [0-9] +)? EXP?
   ;


fragment INT
   : '0' | [1-9] [0-9]*
   ;

// no leading zeros

fragment EXP
   : [Ee] [+\-]? INT
   ;

// \- since - means "range" inside [...]

WS
   : [ \t\n\r] + -> skip
   ;