nebula-plugin-plugin/build.gradle.kts at main · nebula-plugins/nebula-plugin-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
/*
 * Copyright 2015-2019 Netflix, Inc.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
plugins {
    id("com.netflix.nebula.plugin-plugin")
    `kotlin-dsl`
}

description = "Project plugin for Nebula plugins"

contacts {
    addPerson("nebula-plugins-oss@netflix.com") {
        moniker = "Nebula Plugins Maintainers"
        github = "nebula-plugins"
    }
}

dependencies {
    compileOnly("io.github.gradle-nexus:publish-plugin:2.0.0")
    implementation("com.netflix.nebula:nebula-archrules-gradle-plugin:0.+")
    implementation("com.netflix.nebula:nebula-oss-publishing-plugin:latest.release")
    implementation("com.netflix.nebula:gradle-contacts-plugin:latest.release")
    implementation("com.netflix.nebula:gradle-dependency-lock-plugin:latest.release")
    implementation("com.netflix.nebula:gradle-info-plugin:latest.release")
    implementation("com.netflix.nebula:gradle-java-cross-compile-plugin:latest.release")
    implementation("com.netflix.nebula:nebula-publishing-plugin:latest.release")
    implementation("com.netflix.nebula:nebula-project-plugin:latest.release")
    implementation("com.netflix.nebula:nebula-release-plugin:latest.release")
    implementation("com.netflix.nebula:nebula-gradle-interop:latest.release")
    implementation("com.netflix.nebula:gradle-info-plugin:latest.release")
    implementation(platform("com.fasterxml.jackson:jackson-bom:2.14.+"))

    implementation("com.gradle.publish:plugin-publish-plugin:2.+")
    implementation("org.gradle.plugin:compatibility-plugin:1.+")
    implementation("com.gradle.develocity:com.gradle.develocity.gradle.plugin:4.+")

    testImplementation("com.netflix.nebula:nebula-test:latest.release")
    testImplementation("org.ajoberstar.grgit:grgit-core:4.1.1") {
        exclude(group = "org.codehaus.groovy", module = "groovy")
    }
    testImplementation("org.mock-server:mockserver-netty:5.15.0")
}

gradlePlugin {
    plugins {
        create("pluginPlugin") {
            id = "com.netflix.nebula.plugin-plugin"
            displayName = "Nebula Plugin Plugin"
            description = "Sets up publishing and release process for all of the other nebula plugins"
            implementationClass = "nebula.plugin.plugin.NebulaPluginPlugin"
            tags.set(listOf("nebula", "nebula-plugin"))
        }
        create("libraryPlugin") {
            id = "com.netflix.nebula.library"
            displayName = "Nebula Library Plugin"
            description = "Sets up publishing and release process for Nebula Libraries"
            implementationClass = "nebula.plugin.plugin.NebulaLibraryPlugin"
            tags.set(listOf("nebula"))
        }
        create("rootPlugin") {
            id = "com.netflix.nebula.root"
            displayName = "Nebula Root Plugin"
            description = "Sets up publishing and release process for Nebula Multiproject Repos"
            implementationClass = "nebula.plugin.plugin.NebulaRootPlugin"
            tags.set(listOf("nebula"))
        }
        create("com.netflix.nebula.oss.settings") {
            id = "com.netflix.nebula.oss.settings"
            displayName = "Nebula OSS Settings Plugin"
            description = "Sets up build scans"
            implementationClass = "com.netflix.nebula.oss.settings.NebulaSettingsPlugin"
            tags.set(listOf("nebula"))
        }
        create("com.netflix.nebula.resolve") {
            id = "com.netflix.nebula.resolve"
            displayName = "Nebula Dependency Resolve Plugin"
            description = "Used to trigger dependency resolution on all configurations of all projects"
            implementationClass = "com.netflix.nebula.convention.ResolvePlugin"
            tags.set(listOf("nebula"))
        }
    }
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(17))
    }
}
testing {
    suites {
        named<JvmTestSuite>("test") {
            useJUnitJupiter()
            targets.all {
                testTask.configure {
                    maxParallelForks = 2
                }
            }
        }
    }
}