build.gradle

import aQute.bnd.gradle.Bundle

plugins {
    id("java")
    id("java-library")
    id("maven-publish")
    id("jacoco")
    id("biz.aQute.bnd.builder") version "5.1.2"
    id("org.gradle.test-retry") version "1.6.4"
    id("io.github.gradle-nexus.publish-plugin") version "2.0.0"
    id("signing")
}

def jarVersion = "2.25.3"
group = 'io.nats'

def isRelease = System.getenv("BUILD_EVENT") == "release"
def brn = System.getenv("BRANCH_REF_NAME")
def snap = brn == null || brn.equals("") ? "-SNAPSHOT" : "." + brn + "-SNAPSHOT"

version = isRelease ? jarVersion : jarVersion + snap // version is the variable the build actually uses.

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

repositories {
    mavenLocal()
    mavenCentral()
    maven { url="https://repo1.maven.org/maven2/" }
    maven { url="https://central.sonatype.com/repository/maven-snapshots/" }
}

dependencies {
    api 'org.bouncycastle:bcprov-lts8on:2.73.10'
    api 'org.jspecify:jspecify:1.0.0'

    testImplementation 'org.junit.jupiter:junit-jupiter:5.14.1'
    testImplementation 'io.nats:jnats-server-runner:3.0.1'
    testImplementation 'nl.jqno.equalsverifier:equalsverifier:3.12.3'
    testImplementation 'org.junit.platform:junit-platform-launcher:1.14.3'
}

def generateVersionProps = tasks.register("generateVersionProperties") {
    def propsDir = layout.buildDirectory.dir("generated-resources/main")
    outputs.dir(propsDir)
    doLast {
        def f = propsDir.get().file("io/nats/jnats/version.properties").asFile
        f.parentFile.mkdirs()
        f.text = "version=${version}\n"
    }
}

sourceSets.main.resources.srcDir(generateVersionProps.map { it.outputs.files })

tasks.register('bundle', Bundle) {
    from sourceSets.main.output
}

jar {
    manifest {
        attributes('Automatic-Module-Name': 'io.nats.jnats')
    }
    bundle {
        bnd("Bundle-Name": "io.nats.jnats",
                "Bundle-Vendor": "nats.io",
                "Bundle-Description": "Java Nats",
                "Bundle-DocURL": "https://github.com/nats-io/nats.java"
        )
    }
}

test {
    useJUnitPlatform()
    maxHeapSize = "2g"
    testLogging {
        exceptionFormat = 'full'
        events "started", "passed", "skipped", "failed"
        showStandardStreams = true
    }
    retry {
        failOnPassedAfterRetry = false
        maxFailures = 4
        maxRetries = 4
    }
    maxParallelForks = Runtime.runtime.availableProcessors()
    systemProperty 'junit.jupiter.execution.timeout.default', '3m'
}

javadoc {
    options.overview = 'src/main/javadoc/overview.html' // relative to source root
    options.memberLevel = JavadocMemberLevel.PUBLIC
    source = sourceSets.main.allJava
    title = "NATS.IO Java API"
    excludes = [
            "io/nats/client/impl",
            "io/nats/client/api/ConsumerCreateRequest.java",
            "io/nats/client/api/MessageGetRequest.java",
            "io/nats/client/api/MessageDeleteRequest.java",
            "io/nats/client/support/IncomingHeadersProcessor.java",
            "io/nats/client/support/**",
            "**/Debug**"
    ]
    classpath = sourceSets.main.runtimeClasspath
}

tasks.register('javadocJar', Jar) {
    archiveClassifier.set('javadoc')
    from javadoc
}

tasks.register('sourcesJar', Jar) {
    archiveClassifier.set('sources')
    from sourceSets.main.allSource
    dependsOn("generateVersionProperties")
}

tasks.register('testsJar', Jar) {
    archiveClassifier.set('tests')
    from sourceSets.test.allSource
}

tasks.register('copyToLib', Copy) {
    into "build/libs"
    from configurations.runtimeClasspath
}

tasks.register('uberJar', Jar) {
    archiveClassifier = 'uber'

    from sourceSets.main.output

    dependsOn configurations.runtimeClasspath
    from {
        configurations.runtimeClasspath.findAll { it.name.endsWith('jar') }.collect { zipTree(it) }
    }

    exclude ('META-INF/**')

    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    dependsOn copyToLib
}

artifacts {
    archives javadocJar, sourcesJar, testsJar
}

jacoco {
    toolVersion = "0.8.12"
}

jacocoTestReport {
    reports {
        xml.required = true // coveralls plugin depends on xml format report
        html.required = true
    }
    afterEvaluate { // only report on main library not examples
        classDirectories.setFrom(files(classDirectories.files.collect {
            fileTree(dir: it,
                    exclude: ['**/Debug**'])
        }))
    }
}

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
            username = System.getenv('OSSRH_USERNAME')
            password = System.getenv('OSSRH_PASSWORD')
        }
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            artifact sourcesJar
            artifact javadocJar
            artifact testsJar
            pom {
                name = "jnats"
                packaging = "jar"
                groupId = group
                artifactId = "jnats"
                description = 'Client library for working with the NATS messaging system.'
                url = 'https://github.com/nats-io/nats.java'
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = "synadia"
                        name = "Synadia"
                        email = "info@synadia.com"
                        url = "https://nats.io"
                    }
                }
                scm {
                    url = 'https://github.com/nats-io/nats.java'
                }
            }
        }
    }
}

if (isRelease) {
    signing {
        def signingKeyId = System.getenv('SIGNING_KEY_ID')
        def signingKey = System.getenv('SIGNING_KEY')
        def signingPassword = System.getenv('SIGNING_PASSWORD')
        useInMemoryPgpKeys(signingKeyId, signingKey, signingPassword)
        sign configurations.archives
        sign publishing.publications.mavenJava
    }
}