netutils/build.gradle.kts at master · mishl-dev/netutils · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
plugins {
    id("architectury-plugin") version "3.4.161"
    id("dev.architectury.loom") version "1.13.467" apply false
    kotlin("jvm") version "2.3.0" apply false
}

architectury {
    minecraft = "1.21.11"
}

subprojects {
    apply(plugin = "dev.architectury.loom")
    apply(plugin = "org.jetbrains.kotlin.jvm")

    repositories {
        mavenCentral()
        maven("https://maven.fabricmc.net/")
        maven("https://maven.architectury.dev/")
        maven("https://maven.minecraftforge.net/")
        maven("https://maven.neoforged.net/releases/")
        maven("https://maven.terraformersmc.com/releases/")
    }
}

allprojects {
    group = "org.netutils"
    version = rootProject.property("mod_version")
}

tasks.register("collectJars", Copy::class) {
    dependsOn(subprojects.map { it.tasks.named("build") })

    from(project(":fabric").tasks.named("remapJar").map { (it as org.gradle.jvm.tasks.Jar).archiveFile })
    from(project(":neoforge").tasks.named("remapJar").map { (it as org.gradle.jvm.tasks.Jar).archiveFile })

    into(layout.buildDirectory.dir("libs"))

    val mcVer = rootProject.property("minecraft_version")

    rename {
        val nameWithoutExt = it.removeSuffix(".jar")
        "netutils-${nameWithoutExt}+${mcVer}.jar"
    }

    doLast {
        println("Universal compilation complete. Jars collected in: ${layout.buildDirectory.dir("libs").get()}")
    }
}