pixela-java-client/java8-impl/build.gradle at 823d2eac5651b412d73bba87391907fe2163df57 · mike-neck/pixela-java-client · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
plugins {
    id 'java-library'
    id 'jacoco'
    id 'maven'
    id 'signing'
    id "com.github.ben-manes.versions" version "0.20.0"
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

repositories {
    mavenCentral()
    jcenter()
}

dependencies {
    api project(':pixela-java-client-api')
    compileClasspath "org.jetbrains:annotations:$jetbrainsAnnotationsVersion"

    implementation "io.projectreactor.netty:reactor-netty:$reactorNettyVersion"

    implementation "com.fasterxml.jackson.core:jackson-databind:$jacksonVersion"
    implementation "com.fasterxml.jackson.datatype:jackson-datatype-jsr310:$jacksonVersion"

    testImplementation "org.junit.jupiter:junit-jupiter-api:$junitVersion"
    testImplementation "org.junit.jupiter:junit-jupiter-params:$junitVersion"
    testRuntimeClasspath "org.junit.jupiter:junit-jupiter-engine:$junitVersion"
    testImplementation "org.mockito:mockito-core:$mockitoVersion"
    testImplementation "io.projectreactor:reactor-test:$reactorVersion"
    testImplementation "org.assertj:assertj-core:$assertjVersion"
    testRuntimeClasspath "org.slf4j:slf4j-simple:1.7.25"
    testImplementation "net.javacrumbs.json-unit:json-unit-assertj:$jsonUnitAssertjVersion"

    testCompileClasspath "org.jetbrains:annotations:$jetbrainsAnnotationsVersion"
}

test {
    useJUnitPlatform()
}

jacoco {
    toolVersion = '0.8.2'
}

task sourcesJar(type: Jar, group: 'publish') {
    classifier = 'sources'
    from project.sourceSets.main.allSource
}

task javadocJar(type: Jar, group: 'publish') {
    dependsOn 'javadoc'
    from tasks.javadoc
    classifier = 'javadoc'
}

if (canPublish) {
    uploadArchives {
        repositories {
            mavenDeployer {
                beforeDeployment {MavenDeployment deployment ->
                    signing.signPom(deployment)
                }
                repository(url: sonatypeUrl) {
                    authentication userName: sonatypeUsername, password: sonatypePassword
                }
                pom.project {
                    name('pixela-java-client-api')
                    packaging 'jar'
                    description 'pixela-java-client API'
                    url 'https://github.com/mike-neck/pixela-java-client'

                    scm {
                        connection 'scm:git:https://github.com/mike-neck/pixela-java-client'
                        developerConnection 'scm:git:https://github.com/mike-neck/pixela-java-client'
                        url 'https://github.com/mike-neck/pixela-java-client'
                    }

                    licenses {
                        license {
                            name 'The Apache Software License, Version 2.0'
                            url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        }
                    }

                    developers {
                        developer {
                            id 'mikeneck'
                            name 'Shinya Mochida'
                            email 'jkrt3333[at]gmail.com'
                        }
                    }
                }
            }
        }
    }
}

signing {
    sign(project.configurations.archives)
}

artifacts {
    add('archives', javadocJar)
    add('archives', sourcesJar)
}

apply from: rootProject.file('dep.gradle')