2 new events to avoid "Item.Testfield("Inventory Value Zero", false)"

[MirenToledo]

Why do you need this change?

Hello,

A few months ago I opened 2 tickets which are already solved and the code is being released. The tickets were:
https://github.com/microsoft/ALAppExtensions/issues/29283
https://github.com/microsoft/ALAppExtensions/issues/29284

We tested the functionality and it partially works, but unfortunately there are another 2 places into the code where the instruction Item.Testfield("Inventory Value Zero", false) is included and it prevents working with these type of items.

The instruction is found here:

1. codeunit 99000762 "Mfg. Item Journal Mgt." - procedure OnValidateItemNoOnAfterValidateUnitofMeasureCode
2. table 83 "Item Journal Line" - "Item No." - trigger OnValidate()

We didn't notice these 2 cases when we requested the first 2 tickets, but now that we're conducting the initial tests, we've realized it.

Would it be possible to make the same change also on these two objects in a short amount of time?

Thank you in advance.

Describe the request

A few months ago I opened 2 tickets which are already solved and the code is being released. The tickets were:
https://github.com/microsoft/ALAppExtensions/issues/29283
https://github.com/microsoft/ALAppExtensions/issues/29284

We tested the functionality and it partially works, but unfortunately there are another 2 places into the code where the instruction Item.Testfield("Inventory Value Zero", false) is included and it prevents working with these type of items.

The instruction is found here:

1. codeunit 99000762 "Mfg. Item Journal Mgt." - procedure OnValidateItemNoOnAfterValidateUnitofMeasureCode
2. table 83 "Item Journal Line" - "Item No." - trigger OnValidate()

We didn't notice these 2 cases when we requested the first 2 tickets, but now that we're conducting the initial tests, we've realized it.

Would it be possible to make the same change also on these two objects in a short amount of time?

Thank you in advance.

Internal work item: AB#632879

[tomasevicst]

Hi @MirenToledo,

Thanks for submitting this extensibility request. To help us process it efficiently, please update the issue to include the required information.

📚 Extensibility Guidelines

Missing Information:

• Exact proposed code change with surrounding context: Please show the current code area and the exact event or bypass pattern you want added at each requested location.
• Justification for IsHandled/bypass behavior: Explain why an IsHandled-style bypass is required here instead of a regular integration event or another extensibility approach.
• Performance considerations: Describe any expected runtime or posting/manufacturing-volume impact of the requested change.
• Data sensitivity review: Confirm whether any sensitive or business-critical data would be exposed to subscribers and how that should be handled.
• Multi-extension interaction/conflict risk: Briefly assess how multiple extensions subscribing to this event could interact and whether conflicts are acceptable.

Please update the issue with the missing details. We'll automatically re-analyze once updated.

[MirenToledo]

Hello @tomasevicst ,

Thank you for your quick response, I really appreciate it.

Below you can find the code proposal for the two requested changes. I designed it according to the code on the previous tickets, so that the complete solution to be quite similar. Please don't hesitate to contact me if you have any question or you need further details.

Change #1: codeunit 99000762 "Mfg. Item Journal Mgt." – procedure OnValidateItemNoOnAfterValidateUnitofMeasureCode

Current code:

[EventSubscriber(ObjectType::Table, Database::"Item Journal Line", 'OnValidateItemNoOnAfterValidateUnitofMeasureCode', '', true, false)]
local procedure OnValidateItemNoOnAfterValidateUnitofMeasureCode(var ItemJournalLine: Record "Item Journal Line"; var xItemJournalLine: Record "Item Journal Line"; var Item: Record Item; CurrentFieldNo: Integer)
var
    ProdOrderLine: Record "Prod. Order Line";
    ProdOrderComp: Record "Prod. Order Component";
    ShouldCopyFromSingleProdOrderLine: Boolean;
    ShouldThrowRevaluationError: Boolean;
begin
    case ItemJournalLine."Entry Type" of
        ItemJournalLine."Entry Type"::Output:
            begin
                Item.TestField("Inventory Value Zero", false);
                ProdOrderLine.SetFilterByReleasedOrderNo(ItemJournalLine."Order No.");
                ProdOrderLine.SetRange("Item No.", ItemJournalLine."Item No.");
                ItemJournalLine.RunOnValidateItemNoOnAfterSetProdOrderLineItemNoFilter(ItemJournalLine, xItemJournalLine, ProdOrderLine);
                if ProdOrderLine.FindFirst() then begin
                    ItemJournalLine."Routing No." := ProdOrderLine."Routing No.";
                    ItemJournalLine."Source Type" := ItemJournalLine."Source Type"::Item;
                    ItemJournalLine."Source No." := ProdOrderLine."Item No.";
                end else begin
                    ShouldThrowRevaluationError := (ItemJournalLine."Value Entry Type" <> ItemJournalLine."Value Entry Type"::Revaluation) and (CurrentFieldNo <> 0);
                    ItemJournalLine.RunOnValidateItemNoOnAfterCalcShouldThrowRevaluationError(ItemJournalLine, ShouldThrowRevaluationError);
                    if ShouldThrowRevaluationError then
                        Error(CannotInsertItemErr, ItemJournalLine."Item No.", ItemJournalLine."Order No.");
                end;

Proposed change:

[EventSubscriber(ObjectType::Table, Database::"Item Journal Line", 'OnValidateItemNoOnAfterValidateUnitofMeasureCode', '', true, false)]
local procedure OnValidateItemNoOnAfterValidateUnitofMeasureCode(var ItemJournalLine: Record "Item Journal Line"; var xItemJournalLine: Record "Item Journal Line"; var Item: Record Item; CurrentFieldNo: Integer)
var
    ProdOrderLine: Record "Prod. Order Line";
    ProdOrderComp: Record "Prod. Order Component";
    ShouldCopyFromSingleProdOrderLine: Boolean;
    ShouldThrowRevaluationError: Boolean;
    SkipInventoryValueZeroCheck: Boolean;   //New line
begin
    case ItemJournalLine."Entry Type" of
        ItemJournalLine."Entry Type"::Output:
            Begin
        ItemJournalLine.RunOnValidateItemNoOnBeforeEntryTypeOutput(ItemJournalLine, ProdOrderLine, SkipInventoryValueZeroCheck);   //New line
        If not SkipInventoryValueZeroCheck then   //New line
                    Item.TestField("Inventory Value Zero", false);
                ProdOrderLine.SetFilterByReleasedOrderNo(ItemJournalLine."Order No.");
                ProdOrderLine.SetRange("Item No.", ItemJournalLine."Item No.");
                ItemJournalLine.RunOnValidateItemNoOnAfterSetProdOrderLineItemNoFilter(ItemJournalLine, xItemJournalLine, ProdOrderLine);
                if ProdOrderLine.FindFirst() then begin
                    ItemJournalLine."Routing No." := ProdOrderLine."Routing No.";
                    ItemJournalLine."Source Type" := ItemJournalLine."Source Type"::Item;
                    ItemJournalLine."Source No." := ProdOrderLine."Item No.";
                end else begin
                    ShouldThrowRevaluationError := (ItemJournalLine."Value Entry Type" <> ItemJournalLine."Value Entry Type"::Revaluation) and (CurrentFieldNo <> 0);
                    ItemJournalLine.RunOnValidateItemNoOnAfterCalcShouldThrowRevaluationError(ItemJournalLine, ShouldThrowRevaluationError);
                    if ShouldThrowRevaluationError then
                        Error(CannotInsertItemErr, ItemJournalLine."Item No.", ItemJournalLine."Order No.");
                end;

//New procedures
tableextension 99000758 "Mfg. Item Journal Line" extends "Item Journal Line":

internal procedure RunOnValidateItemNoOnBeforeEntryTypeOutput (var ItemJournalLine: Record "Item Journal Line"; var ProdOrderLine: Record "Prod. Order Line"; var SkipInventoryValueZeroCheck: Boolean)
begin
    OnValidateItemNoOnBeforeEntryTypeOutput (ItemJournalLine, xItemJournalLine, ProdOrderLine);
end;

[IntegrationEvent(false, false)]
local procedure OnValidateItemNoOnBeforeEntryTypeOutput (var ItemJournalLine: Record "Item Journal Line"; var ProdOrderLine: Record "Prod. Order Line"; var SkipInventoryValueZeroCheck: Boolean)
begin
end;

• NOTE: I let to you the decision of where to place the above procedures. My proposal is in tableextension 99000758, together with many other ones, but it’s just a proposal.

Change #2: Table 83 – Field 3 “Item No.” – OnValidate() trigger

Current code:

        trigger OnValidate()
        var
            DummyMachineCenter: Record Microsoft.Manufacturing.MachineCenter."Machine Center";
            DummyWorkCenter: Record Microsoft.Manufacturing.WorkCenter."Work Center";
        begin
            if "Item No." <> xRec."Item No." then begin
                "Variant Code" := '';
                "Bin Code" := '';
                "Unit of Measure Code" := '';
                if CurrFieldNo <> 0 then begin
                    GetItem();
                    if Item.IsInventoriableType() then
                        WMSManagement.CheckItemJnlLineFieldChange(Rec, xRec, FieldCaption("Item No."));
                end;
                if ("Location Code" <> '') then begin
                    GetLocation("Location Code");
                    if IsDefaultBin() and Item.IsInventoriableType() then
                        WMSManagement.GetDefaultBin("Item No.", "Variant Code", "Location Code", "Bin Code")
                end;
                SetNewBinCodeForSameLocationTransfer();
            end;

            if IsEntryTypeProduction() then begin
                if "Item No." <> '' then
                    GetItem();
                if Item.IsInventoriableType() then
                    WhseValidateSourceLine.ItemLineVerifyChange(Rec, xRec);
            end;

            if "Item No." = '' then begin
                CreateDimFromDefaultDim(Rec.FieldNo("Item No."));
                OnValidateItemNoOnAfterCreateDimInitial(Rec);
                exit;
            end;

            GetItem();
            OnValidateItemNoOnAfterGetItem(Rec, Item);
            DisplayErrorIfItemIsBlocked(Item);
            ValidateTypeWithItemNo();

            if "Value Entry Type" = "Value Entry Type"::Revaluation then
                Item.TestField("Inventory Value Zero", false);
            OnValidateItemNoOnBeforeSetDescription(Rec, Item);
            Description := Item.Description;
            "Inventory Posting Group" := Item."Inventory Posting Group";
            "Item Category Code" := Item."Item Category Code";

Proposed change:

        trigger OnValidate()
        var
            DummyMachineCenter: Record Microsoft.Manufacturing.MachineCenter."Machine Center";
            DummyWorkCenter: Record Microsoft.Manufacturing.WorkCenter."Work Center";
    SkipInventoryValueZeroCheck: Boolean;   //New line
        Begin
    OnBeforeOnValidateItemNo(Rec, SkipInventoryValueZeroCheck);   //New line

            if "Item No." <> xRec."Item No." then begin
                "Variant Code" := '';
                "Bin Code" := '';
                "Unit of Measure Code" := '';
                if CurrFieldNo <> 0 then begin
                    GetItem();
                    if Item.IsInventoriableType() then
                        WMSManagement.CheckItemJnlLineFieldChange(Rec, xRec, FieldCaption("Item No."));
                end;
                if ("Location Code" <> '') then begin
                    GetLocation("Location Code");
                    if IsDefaultBin() and Item.IsInventoriableType() then
                        WMSManagement.GetDefaultBin("Item No.", "Variant Code", "Location Code", "Bin Code")
                end;
                SetNewBinCodeForSameLocationTransfer();
            end;

            if IsEntryTypeProduction() then begin
                if "Item No." <> '' then
                    GetItem();
                if Item.IsInventoriableType() then
                    WhseValidateSourceLine.ItemLineVerifyChange(Rec, xRec);
            end;

            if "Item No." = '' then begin
                CreateDimFromDefaultDim(Rec.FieldNo("Item No."));
                OnValidateItemNoOnAfterCreateDimInitial(Rec);
                exit;
            end;

            GetItem();
            OnValidateItemNoOnAfterGetItem(Rec, Item);
            DisplayErrorIfItemIsBlocked(Item);
            ValidateTypeWithItemNo();

            if "Value Entry Type" = "Value Entry Type"::Revaluation then
       if not SkipInventoryValueZeroCheck then   //New line
                Item.TestField("Inventory Value Zero", false);
            OnValidateItemNoOnBeforeSetDescription(Rec, Item);
            Description := Item.Description;
            "Inventory Posting Group" := Item."Inventory Posting Group";
            "Item Category Code" := Item."Item Category Code";

//New event
[IntegrationEvent(false, false)]
local procedure OnBeforeOnValidateItemNo (var ItemJournalLine: Record "Item Journal Line"; var SkipInventoryValueZeroCheck: Boolean)
begin
end;

[tomasevicst]

Hi @MirenToledo,

Thanks for submitting this extensibility request. To help us process it efficiently, please update the issue to include the required information.

📚 Extensibility Guidelines

Missing Information:

• Alternatives Evaluated: Which existing events or patterns were tried and why they are insufficient for your needs?
• Justification for IsHandled: Why is the bypass/IsHandled pattern necessary instead of a standard event or alternative approach? Please provide specific technical reasons why a standard integration event would not work for your scenario.
• Performance Considerations: What is the expected execution frequency and potential performance impact? A brief assessment is sufficient (e.g., "Called during item journal validation, expected low frequency").
• Data Sensitivity Review: Confirm whether any sensitive data will be exposed through the event parameters. A short confirmation is sufficient (e.g., "No sensitive data involved" or "Only standard item fields are exposed").
• Multi-Extension Interaction: What are the risks if multiple extensions subscribe to this event, and how should conflicts be handled? A brief acknowledgement is sufficient (e.g., "No major conflict expected" or "Multiple subscribers may set different skip values").

Please update the issue with the missing details. We'll automatically re-analyze once updated.

[MirenToledo]

Hi @tomasevicst,

here you have the requested information:

• Alternatives Evaluated: There's no event available to do what we need, which is just bypass the Testfield sentence.
• Justification for IsHandled: The proposal doesn't include an IsHandled event.
• Performance Considerations: Called during Production Journal opening, expected medium/low.
• Data Sensitivity Review: No sensitive data will be exposed.
• Multi-Extension Interaction: No major conflict expected.

[AleksandricMarko]

✅ Analysis complete - approved for implementation

---

Implementation:

Add one new skip-style integration event in Codeunit 99000762 "Mfg. Item Journal Mgt." before the Item.TestField("Inventory Value Zero", false); call in OnValidateItemNoOnAfterValidateUnitofMeasureCode(...), and extend the existing OnValidateItemNoOnAfterGetItem event in Table 83 "Item Journal Line" with a var SkipInventoryValueZeroCheck: Boolean parameter that is honored before the revaluation check.

Locations:

// MfgItemJournalMgt.Codeunit.al
case ItemJournalLine."Entry Type" of
    ItemJournalLine."Entry Type"::Output:
        begin
            OnValidateItemNoOnBeforeCheckInventoryValueZero(ItemJournalLine, ProdOrderLine, SkipInventoryValueZeroCheck);
            if not SkipInventoryValueZeroCheck then
                Item.TestField("Inventory Value Zero", false);
            ProdOrderLine.SetFilterByReleasedOrderNo(ItemJournalLine."Order No.");
            ProdOrderLine.SetRange("Item No.", ItemJournalLine."Item No.");
            ItemJournalLine.RunOnValidateItemNoOnAfterSetProdOrderLineItemNoFilter(ItemJournalLine, xItemJournalLine, ProdOrderLine);

// ItemJournalLine.Table.al
GetItem();
OnValidateItemNoOnAfterGetItem(Rec, Item, SkipInventoryValueZeroCheck);
DisplayErrorIfItemIsBlocked(Item);
ValidateTypeWithItemNo();

if ("Value Entry Type" = "Value Entry Type"::Revaluation) and not SkipInventoryValueZeroCheck then
    Item.TestField("Inventory Value Zero", false);
OnValidateItemNoOnBeforeSetDescription(Rec, Item);

Event Publisher (add/update with other events):

[IntegrationEvent(false, false)]
local procedure OnValidateItemNoOnBeforeCheckInventoryValueZero(var ItemJournalLine: Record "Item Journal Line"; var ProdOrderLine: Record "Prod. Order Line"; var SkipInventoryValueZeroCheck: Boolean)
begin
end;

[IntegrationEvent(false, false)]
local procedure OnValidateItemNoOnAfterGetItem(var ItemJournalLine: Record "Item Journal Line"; Item: Record Item; var SkipInventoryValueZeroCheck: Boolean)
begin
end;

---

File: MfgItemJournalMgt.Codeunit.al / ItemJournalLine.Table.al

[MirenToledo]

Hello @AleksandricMarko,

Do you might have any update on this ticket? When approximately is planned to be delivered? Thank you in advance.

BR,
Miren.