gradle-version-plugin/build.gradle at main · mathroule/gradle-version-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
plugins {
    id 'groovy'
    id 'java-gradle-plugin'
    id 'maven-publish'
    alias(libs.plugins.vanniktech.maven.publish)
}

repositories {
    mavenCentral()
}

dependencies {
    implementation gradleApi()
    implementation localGroovy()
    testImplementation platform(libs.junit.bom)
    testImplementation libs.junit.jupiter.engine
    testRuntimeOnly libs.junit.platform.launcher
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

test {
    useJUnitPlatform()
    testLogging {
        events 'passed', 'skipped', 'failed'
    }
}

mavenPublishing {
    coordinates('io.github.mathroule', 'gradle-version-plugin', '1.1.0')

    pom {
        name = 'Gradle Version Plugin'
        description = 'A Gradle plugin to manage semantic versioning (major.minor.patch) and generate version code and version name.'
        inceptionYear = '2019'
        url = 'https://github.com/mathroule/gradle-version-plugin'
        licenses {
            license {
                name = 'MIT License'
                url = 'https://opensource.org/licenses/MIT'
            }
        }
        developers {
            developer {
                id = 'mathroule'
                name = 'Mathieu Rul'
                url = "https://github.com/mathroule"
            }
        }
        scm {
            connection = 'scm:git://github.com/mathroule/gradle-version-plugin.git'
            developerConnection = 'scm:git://github.com/mathroule/gradle-version-plugin.git'
            url = 'git://github.com/mathroule/gradle-version-plugin.git'
        }
    }

    publishToMavenCentral()

    signAllPublications()
}