build.gradle

/*
 * Copyright (c) 2010-2025 Progress Software Corporation and/or its subsidiaries or affiliates. All Rights Reserved.
 */

subprojects {
	apply plugin: 'java-library'

	java {
		toolchain {
			languageVersion = JavaLanguageVersion.of(17)
		}
	}

	configurations {
		testImplementation.extendsFrom compileOnly

		all {
			resolutionStrategy {
				// Forcing the latest commons-lang3 version to eliminate CVEs.
				force "org.apache.commons:commons-lang3:3.19.0"
			}
		}
	}

	repositories {
		mavenLocal()
		mavenCentral()

		// Needed so that ml-development-tools can resolve snapshots of marklogic-client-api.
		maven {
			url = "https://bed-artifactory.bedford.progress.com:443/artifactory/ml-maven-snapshots/"
		}
	}

	// Allows for identifying compiler warnings and treating them as errors.
	tasks.withType(JavaCompile).configureEach {
		options.compilerArgs += ["-Xlint:unchecked", "-Xlint:deprecation", "-Werror"]
		options.deprecation = true
		options.warnings = true
	}

	tasks.withType(Test).configureEach {
		// Can't use useJUnitPlatform here as it breaks ml-development-tools
		testLogging {
			events = ['started', 'passed', 'skipped', 'failed']
			exceptionFormat = 'full'
		}
	}

	tasks.withType(Javadoc).configureEach {
		// Until we do a cleanup of javadoc errors, the build (and specifically the javadoc task) fails on Java 11
		// and higher. Preventing that until the cleanup can occur.
		failOnError = false

		// Ignores warnings on param tags with no descriptions. Will remove this once javadoc errors are addressed.
		// Until then, it's just a lot of noise.
		options.addStringOption('Xdoclint:none', '-quiet')
	}
}