build.gradle

/*
 * Copyright (c) 2010-2025 Progress Software Corporation and/or its subsidiaries or affiliates. All Rights Reserved.
 */

subprojects {
	apply plugin: 'java-library'

	tasks.withType(JavaCompile) {
		options.encoding = 'UTF-8'
		options.compilerArgs += ["-Xlint:unchecked", "-Xlint:deprecation"]
	}

	java {
		toolchain {
			languageVersion = JavaLanguageVersion.of(17)
		}
	}

	configurations {
		testImplementation.extendsFrom compileOnly

		all {
			resolutionStrategy {
				// Forcing the latest commons-lang3 version to eliminate CVEs.
				force "org.apache.commons:commons-lang3:3.19.0"
			}
		}
	}

	repositories {
		mavenLocal()
		mavenCentral()
	}

	test {
		useJUnitPlatform()
		testLogging {
			events = ['started', 'passed', 'skipped', 'failed']
			exceptionFormat = 'full'
		}
		systemProperty "file.encoding", "UTF-8"
		systemProperty "javax.xml.stream.XMLOutputFactory", "com.sun.xml.internal.stream.XMLOutputFactoryImpl"
	}

	// Until we do a cleanup of javadoc errors, the build (and specifically the javadoc task) fails on Java 11
	// and higher. Preventing that until the cleanup can occur.
	javadoc.failOnError = false

	// Ignores warnings on param tags with no descriptions. Will remove this once javadoc errors are addressed.
	// Until then, it's just a lot of noise.
	javadoc.options.addStringOption('Xdoclint:none', '-quiet')
}