build.gradle

/*
 * Copyright (c) 2010-2026 Progress Software Corporation and/or its subsidiaries or affiliates. All Rights Reserved.
 */

buildscript {
	repositories {
		mavenCentral()

		mavenLocal()

		// Needed for ml-gradle 6.2-SNAPSHOT
		maven {
			url = "https://bed-artifactory.bedford.progress.com:443/artifactory/ml-maven-snapshots/"
		}
	}
	dependencies {
		classpath "com.marklogic:ml-gradle:6.2-SNAPSHOT"
	}
}

plugins {
	id "net.saliman.properties" version "1.5.2"
	id "com.github.psxpaul.execfork" version "0.2.2"
}

apply plugin: "com.marklogic.ml-gradle"

// Sometimes, 3 x 20 isn't enough on Jenkins.
mlWaitTillReady {
	maxAttempts = 40
}

dependencies {
	implementation "io.undertow:undertow-core:2.3.20.Final"
	implementation "io.undertow:undertow-servlet:2.3.20.Final"
	implementation 'org.slf4j:slf4j-api:2.0.17'
	implementation 'ch.qos.logback:logback-classic:1.5.23'
	implementation "com.fasterxml.jackson.core:jackson-databind:${jacksonVersion}"
	implementation "com.squareup.okhttp3:okhttp:${okhttpVersion}"
}

// See https://github.com/psxpaul/gradle-execfork-plugin for docs.
// Note that the task will stop at the end of the build by default, which is typically the behavior we want when
// running tests.
tasks.register("runReverseProxyServer", com.github.psxpaul.task.JavaExecFork) {
	dependsOn compileJava
	description = "Run a reverse proxy so that the Java tests can be verified when talking to a reverse proxy instead of " +
		"directly to MarkLogic"
	classpath = sourceSets.main.runtimeClasspath
	main = "com.marklogic.client.test.ReverseProxyServer"
	workingDir = "${layout.buildDirectory.get()}"
	standardOutput = file("${layout.buildDirectory.get()}/reverse-proxy.log")
	errorOutput = file("${layout.buildDirectory.get()}/reverse-proxy-error.log")
}

tasks.register("runBlockingReverseProxyServer", JavaExec) {
	description = "Run the reverse proxy server so that it blocks and waits for requests; use ctrl-C to stop it. " +
		"This is intended for manual testing with the reverse proxy server. If you wish to enable an HTTPS port that is 443" +
		"or any value less than 1024, you will need to use sudo to run this - e.g. " +
		"sudo ./gradlew runBlockingReverseProxyServer -PrpsHttpsPort=443 ."
	classpath = sourceSets.main.runtimeClasspath
	mainClass = "com.marklogic.client.test.ReverseProxyServer"
	args = [rpsMarkLogicServer, rpsProxyServer, rpsHttpPort, rpsHttpsPort, rpsCustomMappings]
}