build.gradle

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'

android {
    namespace 'com.mparticle.testutils'
    testNamespace 'com.mparticle.legacyTest'
    compileSdk 33

    defaultConfig {
        //This is set to 21 to avoid slow multidex.
        minSdk 21
        targetSdk 33
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner 'androidx.test.runner.AndroidJUnitRunner'

        if (legacyTest()) {
            testInstrumentationRunnerArgument 'annotation', 'com.mparticle.LegacyOnly'
        } else {
            testInstrumentationRunnerArgument 'notAnnotation', 'com.mparticle.LegacyOnly'
        }

        file("../android-core/src/androidTest/res/raw").mkdir()
        def file = file("../android-core/src/androidTest/res/raw/mparticle_js_sdk")
        file.createNewFile()
        if (project.hasProperty('js-sdk-file')) {
            file.text = new File(project.property('js-sdk-file')).text
            buildConfigField 'boolean', 'JS_TEST_SDK', 'true'
        } else {
            buildConfigField 'boolean', 'JS_TEST_SDK', 'false'
        }

    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    testOptions {
        execution 'ANDROIDX_TEST_ORCHESTRATOR'
    }
    sourceSets {
        main.java.srcDirs += 'src/main/kotlin'
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    compileOnly project(':android-core')
    compileOnly project(':android-kit-base')
    compileOnly 'org.mockito:mockito-android:5.4.0'

    api 'androidx.annotation:annotation:1.5.0'
    api 'androidx.test.ext:junit:1.1.4'
    api 'androidx.test:rules:1.5.0'

    androidTestCompileOnly project(':android-core')

    if (legacyTest()) {
        androidTestImplementation 'com.mparticle:android-core:4.17.1'
    } else {
        androidTestImplementation project(':android-core')

    }
    androidTestImplementation 'androidx.test:runner:1.3.0'
    androidTestImplementation 'androidx.test.ext:junit:1.1.4'
    androidTestImplementation 'androidx.test:rules:1.5.0'
    androidTestImplementation 'com.google.firebase:firebase-messaging:20.0.0'

    androidTestUtil 'androidx.test:orchestrator:1.4.2'
}

boolean legacyTest() {
    return project.hasProperty('legacy') ? project.property('legacy') : false
}