project51/flake.nix at main · lostbean/project51 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
{
  description = "Project 51 flake";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.11";
    nixpkgs-unstable.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };
  outputs =
    {
      nixpkgs,
      nixpkgs-unstable,
      flake-utils,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        unstable-packages = final: _prev: {
          unstable = import nixpkgs-unstable {
            inherit system;
            config.allowUnfree = true;
          };
        };

        pkgs = import nixpkgs {
          inherit system;
          overlays = [ unstable-packages ];
        };

        isDarwin = builtins.match ".*-darwin" pkgs.stdenv.hostPlatform.system != null;

        shell = pkgs.mkShell {
          buildInputs =
            with pkgs;
            [
              unstable.gleam
              unstable.elixir
              unstable.erlang
              # unstable.lexical
              unstable.elixir-ls
              # unstable.next-ls
              rebar3
              nodejs_22
            ]
            ++ (
              if isDarwin then
                [
                  darwin.apple_sdk.frameworks.Security
                  darwin.apple_sdk.frameworks.Foundation
                ]
              else
                [ ]
            );
          shellHook = ''
            echo "👽👾👽👾👽👾👽👾👽👾👽👾"
          '';
        };

        service_names = [ "area51" ];
        architectures = [
          "amd64"
          "arm64"
        ];

        containers =
          let
            os = "linux";
            all =
              pkgs.lib.mapCartesianProduct
                (
                  { arch, service_name }:
                  {
                    "${service_name}" = {
                      "${toString arch}" =
                        let
                          nix_arch =
                            builtins.replaceStrings
                              [ "arm64" "amd64" ]
                              [
                                "aarch64"
                                "x86_64"
                              ]
                              arch;

                          container_pkgs = import nixpkgs {
                            system = "${nix_arch}-${os}";
                            overlays = [ unstable-packages ];
                          };

                          service = container_pkgs.callPackage ./release {
                            erlang = container_pkgs.unstable.erlang;
                            elixir = container_pkgs.unstable.elixir;
                            gleam = container_pkgs.unstable.gleam;
                            nodejs = container_pkgs.nodejs_22;
                          };
                        in
                        container_pkgs.callPackage ./release/docker.nix {
                          area51 = service;
                          pkgs = container_pkgs;
                        };
                    };
                  }
                )
                {
                  arch = architectures;
                  service_name = service_names;
                };
          in
          pkgs.lib.foldl' (set: acc: pkgs.lib.recursiveUpdate acc set) { } all;
      in
      {
        devShells.default = shell;

        packages.image = containers;

        packages.default = pkgs.callPackage ./release {
          erlang = pkgs.unstable.erlang;
          nodejs = pkgs.nodejs_22;
          elixir = pkgs.elixir-dev;
          gleam = pkgs.gleam-dev;
        };
      }
    );
}