feat: add license dialog and update about dialog

1. Added new LicenseDialog.qml component for displaying open-source
software licenses
2. Modified AboutDialog.qml to replace inline license text with link to
license dialog
3. Updated DialogTitleBar.qml to support left content area for back
navigation
4. Added DLicenseInfoProvider C++ class to parse and provide license
information
5. Updated copyright years from 2022 to 2026 across modified files
6. Added LicenseDialog to QML resources and build system

Log: Added license dialog for displaying open-source software
acknowledgements

feat: 添加许可证对话框并更新关于对话框

1. 新增 LicenseDialog.qml 组件用于显示开源软件许可证信息
2. 修改 AboutDialog.qml，将内联许可证文本替换为指向许可证对话框的链接
3. 更新 DialogTitleBar.qml 以支持左侧内容区域用于返回导航
4. 新增 DLicenseInfoProvider C++ 类用于解析和提供许可证信息
5. 将修改文件的版权年份从 2022 更新至 2026
6. 将 LicenseDialog 添加到 QML 资源和构建系统中

Log: 新增用于显示开源软件致谢的许可证对话框

PMS: TASK-387863

Author: mhduiy

qmlplugin/qmlplugin_plugin.cpp

@@ -1,4 +1,4 @@
-// SPDX-FileCopyrightText: 2020 - 2022 UnionTech Software Technology Co., Ltd.
+// SPDX-FileCopyrightText: 2020 - 2026 UnionTech Software Technology Co., Ltd.
 //
 // SPDX-License-Identifier: LGPL-3.0-or-later
 
@@ -28,6 +28,7 @@
 #include "private/dquickarrowboxpath_p.h"
 #include "private/dquickcoloroverlay_p.h"
 #include "private/dquickapploaderitem_p.h"
+#include "private/dlicenseinfoprovider_p.h"
 #endif
 
 #include "private/dquickimageprovider_p.h"
@@ -195,6 +196,7 @@ void QmlpluginPlugin::registerTypes(const char *uri)
     dtkRegisterType<DQuickArrowBoxPath>(uri, implUri, 1, 0, "ArrowBoxPath");
     dtkRegisterType<DQuickAppLoaderItem>(uri, implUri, 1, 0, "AppLoader");
     dtkRegisterType<DQuickColorOverlay>(uri, implUri, 1, 0, "SoftwareColorOverlay");
+    dtkRegisterType<DLicenseInfoProvider>(uri, implUri, 1, 0, "LicenseInfoProvider");
 
     dtkRegisterAnonymousType<DQUICK_NAMESPACE::DQuickDciIcon>(uri, implUri, 1);
     dtkRegisterAnonymousType<DQuickControlColor>(uri, implUri, 1);

qt6/src/qml.cmake

@@ -100,6 +100,7 @@ set(QML_DTK_CONTROLS
     "qml/ControlGroup.qml"
     "qml/ControlGroupItem.qml"
     "qml/DragItemsImage.qml"
+    "qml/LicenseDialog.qml"
 )
 
 foreach(QML_FILE ${QML_DTK_CONTROLS})

qt6/src/qml/AboutDialog.qml

@@ -1,4 +1,4 @@
-// SPDX-FileCopyrightText: 2021 - 2022 UnionTech Software Technology Co., Ltd.
+// SPDX-FileCopyrightText: 2021 - 2026 UnionTech Software Technology Co., Ltd.
 //
 // SPDX-License-Identifier: LGPL-3.0-or-later
 
@@ -18,8 +18,9 @@ DialogWindow {
     property alias productIcon: logoLabel.icon.name
     property alias version: versionLabel.text
     property alias description: descriptionLabel.text
-    property alias license: licenseLabel.text
     property alias companyLogo: companyLogoLabel.source
+    property alias license: licenseLabel.text
+    property string licensePath
     property string websiteName
     property string websiteLink
 
@@ -59,6 +60,7 @@ DialogWindow {
                 Layout.alignment: Qt.AlignCenter
                 Layout.topMargin: 30
             }
+
             Label {
                 id: licenseLabel
                 font: D.DTK.fontManager.t10
@@ -68,7 +70,7 @@ DialogWindow {
                 Layout.leftMargin: 30
                 wrapMode: Text.WordWrap
                 elide: Text.ElideRight
-                visible: license !== ""
+                visible: control.license !== ""
             }
         }
         ColumnLayout {
@@ -127,6 +129,31 @@ DialogWindow {
                     elide: Text.ElideRight
                 }
             }
+
+            ColumnLayout {
+                spacing: 1
+                Label {
+                    font: D.DTK.fontManager.t10
+                    text: qsTr("Acknowledgements")
+                }
+                Label {
+                    id: acknowledgmentsLabel
+                    text: qsTr("Sincerely appreciate the %1 used.").arg(control.__websiteLinkTemplate.arg("-").arg(qsTr("open-source software")))
+                    textFormat: Text.RichText
+                    Layout.fillWidth: true
+                    font: D.DTK.fontManager.t8
+                    wrapMode: Text.WordWrap
+                    elide: Text.ElideRight
+
+                    onLinkActivated: function(link) {
+                        licenseDialogLoader.active = true
+                    }
+
+                    HoverHandler {
+                        cursorShape: acknowledgmentsLabel.hoveredLink !== "" ? Qt.PointingHandCursor : Qt.ArrowCursor
+                    }
+                }
+            }
        }
 
         Component.onCompleted: {
@@ -141,4 +168,18 @@ DialogWindow {
             event.accepted = true
         }
     }
+
+    Loader {
+        id: licenseDialogLoader
+        active: false
+        sourceComponent: LicenseDialog {
+            licensePath: control.licensePath
+            onClosing: function (close) {
+                licenseDialogLoader.active = false
+            }
+        }
+        onLoaded: function () {
+            licenseDialogLoader.item.show()
+        }
+    }
 }

qt6/src/qml/DialogTitleBar.qml

@@ -1,4 +1,4 @@
-// SPDX-FileCopyrightText: 2021 - 2022 UnionTech Software Technology Co., Ltd.
+// SPDX-FileCopyrightText: 2021 - 2026 UnionTech Software Technology Co., Ltd.
 //
 // SPDX-License-Identifier: LGPL-3.0-or-later
 
@@ -15,6 +15,7 @@ Item {
     height: DS.Style.dialogWindow.titleBarHeight
 
     // custom control
+    property alias leftContent: customLeft.sourceComponent
     property alias content: customCenter.sourceComponent
     // dialog icon
     property alias icon: iconLabel
@@ -54,7 +55,7 @@ Item {
         }
 
         RowLayout {
-            spacing: 0
+            spacing: 10
             Layout.alignment: Qt.AlignHCenter
             Layout.fillHeight: true
             Layout.preferredWidth: parent.width
@@ -75,10 +76,17 @@ Item {
                 }
             }
 
+            // left custom area
+            Loader {
+                id: customLeft
+                Layout.alignment: Qt.AlignLeft
+                Layout.fillHeight: true
+                sourceComponent: null
+            }
+
             // center custom area
             Loader {
                 id: customCenter
-                Layout.leftMargin: closeBtn.width - iconLabel.width
                 Layout.alignment: Qt.AlignHCenter
                 Layout.fillHeight: true
                 Layout.fillWidth: true

qt6/src/qml/DialogWindow.qml

@@ -47,6 +47,7 @@ Window {
                 sourceComponent: DialogTitleBar {
                     enableInWindowBlendBlur: true
                     icon.name: control.icon
+                    title: control.title
                 }
             }
 

qt6/src/qml/LicenseDialog.qml

@@ -0,0 +1,139 @@
+// SPDX-FileCopyrightText: 2026 UnionTech Software Technology Co., Ltd.
+//
+// SPDX-License-Identifier: LGPL-3.0-or-later
+
+import QtQuick
+import QtQuick.Layouts
+import QtQuick.Window
+import QtQuick.Controls
+import org.deepin.dtk 1.0 as D
+import org.deepin.dtk.style 1.0 as DS
+
+DialogWindow {
+    id: control
+    width: 800
+    height: 900
+    title: qsTr("open-source software")
+
+    property alias licensePath: licenseProvider.path
+
+    header: D.DialogTitleBar {
+        title: control.title
+        leftContent: Item {
+            width: 32
+            D.IconButton {
+                anchors.centerIn: parent
+                visible: stackView.depth > 1
+                icon.name: "arrow_ordinary_left"
+                implicitWidth: 32
+                implicitHeight: 32
+                icon.width: 12
+                icon.height: 12
+                onClicked: stackView.pop()
+            }
+        }  
+    }
+
+    Item {
+        implicitWidth: control.width - control.leftPadding - control.rightPadding
+        implicitHeight: control.height - DS.Style.dialogWindow.titleBarHeight - DS.Style.dialogWindow.contentHMargin
+
+        D.LicenseInfoProvider {
+            id: licenseProvider
+        }
+
+        StackView {
+            id: stackView
+            anchors.fill: parent
+            initialItem: listPage
+            clip: true
+        }
+
+        Component {
+            id: listPage
+            Item {
+                ListView {
+                    id: licenseList
+                    anchors.fill: parent
+                    clip: true
+                    model: licenseProvider.licenseList
+                    ScrollBar.vertical: ScrollBar {}
+
+                    delegate: D.ItemDelegate {
+                        id: delegateItem
+                        implicitWidth: licenseList.width
+                        implicitHeight: 50
+                        text: modelData.name
+                        palette.windowText: undefined
+                        property D.Palette colorOdd: D.Palette {
+                            normal: Qt.rgba(0, 0, 0, 0.05)
+                            hovered: Qt.rgba(0, 0, 0, 0.1)
+                        }
+                        property D.Palette colorEven: D.Palette {
+                            normal: Qt.rgba(0, 0, 0, 0.02)
+                            hovered: Qt.rgba(0, 0, 0, 0.1)
+                        }
+
+                        onClicked: {
+                            stackView.push(detailPage, {
+                                packageName: modelData.name,
+                                licenseText: licenseProvider.licenseContent(modelData.licenseName)
+                            })
+                        }
+                        background: D.BoxPanel {
+                            color1: index % 2 === 0 ? delegateItem.colorOdd : delegateItem.colorEven
+                            insideBorderColor: null
+                            outsideBorderColor: null
+                            dropShadowColor: null
+                            innerShadowColor1: null
+                            innerShadowColor2: null
+                        }
+                    }
+                }
+            }
+        }
+
+        Component {
+            id: detailPage
+            Item {
+                property string packageName: ""
+                property string licenseText: ""
+
+                Flickable {
+                    anchors.fill: parent
+                    contentWidth: width
+                    contentHeight: detailColumn.implicitHeight
+                    clip: true
+                    topMargin: 20
+                    ScrollBar.vertical: ScrollBar {}
+
+                    ColumnLayout {
+                        id: detailColumn
+                        width: parent.width
+                        spacing: 20
+
+                        Text {
+                            Layout.fillWidth: true
+                            text: packageName
+                            font.pixelSize: D.DTK.fontManager.t5.pixelSize
+                            font.family: D.DTK.fontManager.t5.family
+                            font.bold: true
+                            color: D.DTK.palette.windowText
+                        }
+
+                        MenuSeparator{}
+
+                        Text {
+                            Layout.fillWidth: true
+                            text: licenseText
+                            font: D.DTK.fontManager.t6
+                            color: D.DTK.palette.windowText
+                            wrapMode: Text.WordWrap
+                            verticalAlignment: Text.AlignTop
+                        }
+                    }
+                }
+            }
+        }
+    }
+}

src/dtkdeclarative_qml.qrc

@@ -115,5 +115,6 @@
         <file>qml/private/ColorOverlay.qml</file>
         <file>qml/private/SoftwareColorOverlay.qml</file>
         <file>qml/private/ArrowListViewButton.qml</file>
+        <file>qml/LicenseDialog.qml</file>
     </qresource>
 </RCC>

src/private/dlicenseinfoprovider.cpp

@@ -0,0 +1,70 @@
+// SPDX-FileCopyrightText: 2026 UnionTech Software Technology Co., Ltd.
+//
+// SPDX-License-Identifier: LGPL-3.0-or-later
+
+#include "dlicenseinfoprovider_p.h"
+
+DQUICK_BEGIN_NAMESPACE
+
+DLicenseInfoProvider::DLicenseInfoProvider(QObject *parent)
+    : QObject(parent)
+{
+}
+
+DLicenseInfoProvider::~DLicenseInfoProvider() = default;
+
+QVariantList DLicenseInfoProvider::licenseList() const
+{
+    auto componentInfos = m_licenseInfo.componentInfos();
+    QVariantList list;
+    for (const auto &info : componentInfos) {
+        QVariantMap map;
+        map.insert("name", info->name());
+        map.insert("version", info->version());
+        map.insert("copyRight", info->copyRight());
+        map.insert("licenseName", info->licenseName());
+        list.append(map);
+    }
+    return list;
+}
+
+QString DLicenseInfoProvider::path() const
+{
+    return m_path;
+}
+
+void DLicenseInfoProvider::setPath(const QString &path)
+{
+    if (m_path == path)
+        return;
+    m_path = path;
+    Q_EMIT pathChanged();
+    setValid(m_licenseInfo.loadFile(path));
+    Q_EMIT licenseListChanged();
+}
+
+bool DLicenseInfoProvider::isValid() const
+{
+    return m_valid;
+}
+
+void DLicenseInfoProvider::setValid(bool valid)
+{
+    if (m_valid == valid)
+        return;
+    m_valid = valid;
+    Q_EMIT validChanged();
+}
+
+QString DLicenseInfoProvider::licenseContent(const QString &licenseName)
+{
+    return QString::fromUtf8(m_licenseInfo.licenseContent(licenseName));
+}
+
+void DLicenseInfoProvider::componentComplete()
+{
+    setValid(m_licenseInfo.loadFile({}));
+    Q_EMIT licenseListChanged();
+}
+
+DQUICK_END_NAMESPACE