jactor-shared/build.gradle.kts at main · jactor-rises/jactor-shared · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
plugins {
    `java-library`
    alias(libs.plugins.kotlin.jvm)
    alias(libs.plugins.ktlint)
    alias(libs.plugins.versions)
    `maven-publish`
}

group = "com.github.jactor-rises"
val cliVersion = providers.gradleProperty("version").orNull?.trim()
version = cliVersion.takeIf { !it.isNullOrBlank() } ?: "0.0.0-SNAPSHOT"

dependencies {
    implementation(libs.springdoc.openapi.ui)
    implementation(libs.fasterxml.core)
    implementation(libs.fasterxml.datatype)

    testImplementation(libs.assertk)
    testImplementation(libs.junit.jupiter)
    testImplementation(libs.junit.platform.suite)
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(libs.versions.jvm.get().toInt())
    }

    withSourcesJar()
}

repositories {
    gradlePluginPortal()
    mavenCentral()
    mavenLocal()
}

tasks.register("printVersion") {
    doLast { println(project.version) }
}

kotlin {
    compilerOptions {
        freeCompilerArgs.addAll("-Xjsr305=strict", "-Xannotation-default-target=param-property")
    }
}

tasks {
    val ktlintFormatAndCheck by registering {
        dependsOn("ktlintFormat")
        doLast {
            ProcessBuilder("${project.rootDir}/gradlew", "ktlintCheck")
                .directory(project.rootDir).inheritIO()
                .start().waitFor() // venter på at prosessen skal fullføre før vi går videre til testene
        }
    }

    matching { it.name.startsWith("runKtlintCheck") }.configureEach {
        mustRunAfter(project.tasks.matching { it.name.startsWith("runKtlintFormat") })
    }

    test {
        useJUnitPlatform()

        jvmArgs("--add-opens", "java.base/java.lang.reflect=ALL-UNNAMED")
        exclude("**/RunCucumberTest*")
        dependsOn(ktlintFormatAndCheck)

        testLogging {
            events("passed", "skipped", "failed")
            showStandardStreams = true
            exceptionFormat = org.gradle.api.tasks.testing.logging.TestExceptionFormat.FULL
        }
    }
}

publishing {
    publications {
        create<MavenPublication>("mavenJava") {
            from(components["java"])
            groupId = project.group.toString()
            artifactId = project.name
            version = project.version.toString()
        }
    }
}