docker-java/build.gradle at main · intisy/docker-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
plugins {
    id "java-library"
    id "com.github.johnrengelman.shadow" version "8.1.1"
    id "io.github.intisy.online-gradle" version "1.7.2"
    id "io.github.intisy.github-gradle" version "1.8.2.1"
}

online {
    autoUpdate = true
    updateDelay = 3600
    presets = [
            "https://raw.githubusercontent.com/intisy/gradle-snippets/presets/default.preset:1.8",
            "https://raw.githubusercontent.com/intisy/gradle-snippets/presets/publish.preset"
    ]
}

github {
    accessToken = System.getenv("GITHUB_TOKEN") ?: ""
}

publishGithub {
    releaseName = "Release ${project.findProperty('artifact_version') ?: project.version}"
    artifacts {
        artifact {
            classifier = ""
            jar = file("build/libs/docker-java.jar")
        }
        artifact {
            classifier = "standalone"
            jar = file("build/libs/docker-java-standalone.jar")
        }
    }
}

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    api "com.google.code.gson:gson:2.10.1"
    api "org.apache.commons:commons-compress:1.24.0"
    api "com.kohlschutter.junixsocket:junixsocket-core:2.9.0"
    implementation "org.slf4j:slf4j-simple:2.0.7"
    testImplementation "org.junit.jupiter:junit-jupiter:5.10.1"
}

test {
    useJUnitPlatform()
    onlyIf { gradle.startParameter.taskNames.any { it == 'test' || it == ':test' } }
}

task ciTest(type: Test) {
    useJUnitPlatform {
        includeTags 'unit'
    }
    description = 'Runs unit tests safe for CI (no Docker daemon required).'
    group = 'verification'
}

task integrationTest(type: Test) {
    useJUnitPlatform {
        includeTags 'integration'
    }
    description = 'Runs integration tests that require a Docker daemon (local only).'
    group = 'verification'
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}