rustemo/flake.nix at main · igordejanovic/rustemo · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
    crane = {
      url = "github:ipetkov/crane";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    mdbook-theme = {
      url = "github:zjp-CN/mdbook-theme";
      flake = false;
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      rust-overlay,
      crane,
      mdbook-theme,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs {
          inherit system overlays;
        };

        rustStable = pkgs.rust-bin.stable.latest.default.override {
          extensions = [
            "rust-src"
            "clippy"
            "rustfmt"
            "rust-docs"
            "rust-analyzer"
          ];
          targets = [ "wasm32-unknown-unknown" ];
        };

        rustNightly = pkgs.rust-bin.nightly.latest.default.override {
          extensions = [
            "rust-src"
            "clippy"
            "rustfmt"
            "rust-docs"
            "rust-analyzer"
          ];
        };

        rev = if (self ? rev) then self.rev else self.dirtyRev;
        book = import ./docs {
          inherit pkgs crane mdbook-theme;
        };
        rustemo = import ./. {
          inherit crane pkgs rev;
        };
        inherit (rustemo) msrv;
        shellPkgs = [
          pkgs.cargo-nextest
          pkgs.just
          rustemo.packages.compiler
        ];
      in
      {
        devShells.default = pkgs.mkShell {
          buildInputs = book.buildInputs ++ shellPkgs ++ [ rustStable ];
          RUST_SRC_PATH = "${rustStable}/lib/rustlib/src/rust/library";
          LD_LIBRARY_PATH = "${pkgs.lib.makeLibraryPath [ pkgs.zlib ]}";
          shellHook = ''
            echo "Using STABLE Rust environment"
          '';
        };

        devShells.base = pkgs.mkShell {
          buildInputs = book.buildInputs ++ shellPkgs ++ [ pkgs.rust-bin.stable.${msrv}.default ];
          shellHook = ''
            echo "Using BASE (${msrv}) Rust environment"
          '';
        };
        devShells.nightly = pkgs.mkShell {
          buildInputs = book.buildInputs ++ shellPkgs ++ [ rustNightly ];
          RUST_SRC_PATH = "${rustNightly}/lib/rustlib/src/rust/library";
          LD_LIBRARY_PATH = "${pkgs.lib.makeLibraryPath [ pkgs.zlib ]}";
          shellHook = ''
            echo "Using NIGHTLY Rust environment"
          '';
        };
        inherit (rustemo) checks;
        packages = rustemo.packages // book.packages;
      }
    );

  nixConfig = {
    bash-prompt-prefix = "rustemo-dev:";
  };
}