gitlab.nvim/flake.nix at bbcb640d3b1f9d65085f197fbd0324488bb93b61 · harrisoncramer/gitlab.nvim · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, flake-utils, nixpkgs }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs { inherit system; config.allowUnfree = true; };
        gitlab-nvim-server = pkgs.buildGoModule {
          pname = "gitlab.nvim-server";
          version = "git";
          src = ./.;
          vendorHash = "sha256-OLAKTdzqynBDHqWV5RzIpfc3xZDm6uYyLD4rxbh0DMg=";
          postInstall = ''
            cp -r ${./cmd/config} $out/bin/config
            mv $out/bin/cmd $out/bin/gitlab.nvim
          '';
        };
        gitlab-nvim = pkgs.vimUtils.buildVimPlugin {
          name = "gitlab.nvim";
          src = ./.;
          doCheck = false;
        };
      in
      rec {
        formatter = pkgs.nixpkgs-fmt;
        packages.gitlab-nvim-server = gitlab-nvim-server;
        packages.gitlab-nvim = gitlab-nvim;
        packages.default = packages.gitlab-nvim;
        devShell = pkgs.mkShell {
          packages = with pkgs; [
            git
            go
            go-tools
            golangci-lint
            luajitPackages.busted
            luajitPackages.luacheck
            luajitPackages.luarocks
            neovim
            stylua
          ];
        };
      }
    );
}