MaxBeneficiaries.t.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.28;

import {Test} from "forge-std/Test.sol";

import {VestingParams} from "src/tokenDistribution/vesting/VestingParams.sol";
import {Beneficiary, VestingType} from "src/tokenDistribution/utils/Common.sol";

contract MaxBeneficiariesTest is Test {
    uint256 public constant MONTH = 30 days;
    uint64 public vestingStartTime;

    VestingParams vestingParams;

    function setUp() external {
        // forge-lint: disable-next-line(unsafe-typecast)
        vestingStartTime = uint64(block.timestamp + MONTH);
    }

    /// @dev Deployment cost of 401 beneficiaries is equal 19_448_973 (≈ half a block gas limit)
    /// Checked with the command:
    /// `forge test -vvv --mt test_deploy_moreBeneficiaries --gas-report`
    function test_maxBeneficiaries() external {
        // Stage 0. Create liquidity beneficiaries
        uint256 liquidityTotalAmount = 287_500_000e18; // equal vestingParams.LIQUIDITY_TOTAL_AMOUNT()
        Beneficiary[] memory liquidityBeneficiaries = new Beneficiary[](1); // min number of beneficiary
        liquidityBeneficiaries[0] =
            Beneficiary({account: makeAddr("liquidityBeneficiary"), amount: liquidityTotalAmount});

        // Stage 1. Create team beneficiary. Simulate 400 beneficiaries
        uint256 teamBeneficiariesCount = 400;
        uint256 teamTotalAmount = 100_000_000e18; // equal vestingParams.TEAM_TOTAL_AMOUNT()

        Beneficiary[] memory teamBeneficiaries = new Beneficiary[](teamBeneficiariesCount);

        for (uint256 i = 0; i < teamBeneficiariesCount; i++) {
            teamBeneficiaries[i] = Beneficiary({
                account: vm.addr(uint256(keccak256(abi.encodePacked("OneOfBeneficiary", i)))),
                amount: teamTotalAmount / teamBeneficiariesCount
            });
        }

        // Stage 2. Deploy VestingParams
        vestingParams = new VestingParams(vestingStartTime, teamBeneficiaries, liquidityBeneficiaries);

        assertEq(vestingParams.getBeneficiaries(VestingType.TEAM).length, teamBeneficiariesCount);
    }
}