PackagePublishCommand.imba

import { Command } from '../Command'
import { copySync } from 'fs-extra'
import { existsSync } from 'fs-extra'
import { isString } from '../../../Support/Helpers'
import { join } from 'path'
import { Prop } from '@formidablejs/console'
import { readFileSync } from 'fs-extra'

export class PackagePublishCommand < Command

	get signature
		'package:publish {--package} {--tag} {?--force}'

	get description
		'Install Formidable package'

	get props
		{
			package: Prop.string!.description 'Package name'
			tag: Prop.string!.description 'Assets you want to publish'
			force: Prop.boolean!.default(false).description 'Overwrite any existing files'
		}

	get package
		join process.cwd!, 'node_modules', self.option('package')

	get basePackage
		join(process.cwd!, 'package.json')

	get language
		if existsSync(self.basePackage)
			return require(self.basePackage).language || 'imba'
		else
			'imba'

	get definition
		const npmFile = join self.package, 'package.json'

		if !existsSync npmFile then return self.message('error', 'Package is not installed.')

		JSON.parse readFileSync(npmFile, 'utf8').toString!

	get publisherPath
		self.definition['publisher']

	get publisher
		if !self.publisherPath
			return self.message 'error', 'This package is not publishable.'

		const publisherModule = join(package, self.publisherPath)

		if !existsSync(publisherModule)
			return self.message 'error', 'Publisher does not exist.'

		let publisher = require(publisherModule).Package

		publisher = new publisher

		if typeof publisher.publish !== 'function'
			return self.message 'error', 'Publish function missing.'

		publisher.publish(self.language.toLowerCase!)

	def handle
		let tags\string[] = self.option('tag').split(',')

		for optTag in tags
			self.persist optTag

		self.exit!

	def persist optTag\string
		if !self.publisher[optTag] || (self.publisher[optTag] && self.publisher[optTag].paths === undefined || self.publisher[optTag].paths === null)
			return self.write "<fg:red>{optTag} is missing.</fg:red>"

		if typeof self.publisher[optTag] !== 'object'
			return self.write "<fg:red>{optTag} is missing paths.</fg:red>"

		for entry in Object.keys(self.publisher[optTag].paths)
			const file = join self.package, self.publisher[optTag].paths[entry]

			if existsSync(entry) && !self.option('force', false)
				self.write "<fg:red>{entry} already exists. Skipping.</fg:red>"
			else
				copySync file, entry, { overwrite: true }

				self.write existsSync(entry) ? "<fg:green>Published</fg:green> {entry}" : "<fg:red>{entry} not published.</fg:red>"