perf-devnets/terraform/devnet-4/cloudflare.tf at 8f9d1969d3fe1a28e4e9129e878e95d3446d4646 · ethpandaops/perf-devnets · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

////////////////////////////////////////////////////////////////////////////////////////
//                                   DNS NAMES
////////////////////////////////////////////////////////////////////////////////////////

data "cloudflare_zone" "default" {
  name = "ethpandaops.io"
}

locals {
  # Combine bootnodes from both providers
  bootnodes = merge(
    {
      for vm in local.digitalocean_vms : vm.id => {
        name     = vm.name
        has_ipv6 = vm.ipv6
        ipv4     = digitalocean_droplet.main[vm.id].ipv4_address
        ipv6     = try(digitalocean_droplet.main[vm.id].ipv6_address, null)
      } if can(regex("bootnode", vm.name))
    },
    {
      for vm in local.hcloud_vms : vm.id => {
        name     = vm.name
        has_ipv6 = vm.ipv6_enabled
        ipv4     = hcloud_server.main[vm.id].ipv4_address
        ipv6     = try(hcloud_server.main[vm.id].ipv6_address, null)
      } if can(regex("bootnode", vm.name))
    }
  )
}

resource "cloudflare_record" "server_record_v4" {
  for_each = local.bootnodes
  zone_id  = data.cloudflare_zone.default.id
  name     = "${each.value.name}.${var.ethereum_network}"
  type     = "A"
  value    = each.value.ipv4
  proxied  = false
  ttl      = 120
}

resource "cloudflare_record" "server_record_v6" {
  for_each = { for k, v in local.bootnodes : k => v if v.has_ipv6 }
  zone_id  = data.cloudflare_zone.default.id
  name     = "${each.value.name}.${var.ethereum_network}"
  type     = "AAAA"
  value    = each.value.ipv6
  proxied  = false
  ttl      = 120
}

resource "cloudflare_record" "server_record_ns" {
  for_each = local.bootnodes
  zone_id  = data.cloudflare_zone.default.id
  name     = "srv.${var.ethereum_network}"
  type     = "NS"
  value    = "${each.value.name}.${var.ethereum_network}.${data.cloudflare_zone.default.name}"
  proxied  = false
  ttl      = 120
}