micronaut-example/build.gradle.kts at master · efsn/micronaut-example · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
plugins {
    val kotlinVersion = "1.3.72"

    application
    kotlin("jvm") version kotlinVersion
    kotlin("kapt") version kotlinVersion
    kotlin("plugin.allopen") version kotlinVersion

    id("com.github.johnrengelman.shadow") version "5.2.0"
}

allprojects {
    apply(plugin = "application")
    apply(plugin = "kotlin")
    apply(plugin = "kotlin-kapt")
    apply(plugin = "kotlin-allopen")
    apply(plugin = "com.github.johnrengelman.shadow")
    apply(from = rootProject.file("gradle/ktlint.gradle.kts"))

    repositories {
        mavenCentral()
        jcenter()
    }

    configurations.create("developmentOnly")

    dependencies {
        implementation(platform("io.micronaut:micronaut-bom:2.0.0.M3"))

        implementation(kotlin("stdlib-jdk8"))
        implementation(kotlin("reflect"))

//        developmentOnly("io.micronaut:micronaut-http-server-netty")

        implementation("io.micronaut:micronaut-runtime")
        implementation("io.micronaut.reactor:micronaut-reactor")
        implementation("io.micronaut:micronaut-validation")
        implementation("io.micronaut.reactor:micronaut-reactor-http-client:1.0.0.RC1")

        kapt(platform("io.micronaut:micronaut-bom:2.0.0.M3"))
        kapt("io.micronaut:micronaut-inject-java")
        kapt("io.micronaut:micronaut-validation")
//        kapt("io.micronaut.configuration:micronaut-hibernate-validator")
        kapt("io.micronaut.configuration:micronaut-openapi")

        runtimeOnly("com.fasterxml.jackson.module:jackson-module-kotlin")
        runtimeOnly("ch.qos.logback:logback-classic:1.2.3")

        kaptTest(platform("io.micronaut:micronaut-bom:2.0.0.M3"))
        kaptTest("io.micronaut:micronaut-inject-java")

        testImplementation("org.junit.jupiter:junit-jupiter-engine")
        testImplementation("org.junit.jupiter:junit-jupiter-api")
        testImplementation("org.jetbrains.spek:spek-junit-platform-engine:1.1.5")

        testImplementation("io.kotlintest:kotlintest-runner-junit5:3.3.2")

        testImplementation("io.micronaut.test:micronaut-test-junit5")
        testImplementation("io.micronaut.test:micronaut-test-kotlintest")
        testImplementation("org.mockito:mockito-junit-jupiter:2.22.0")
        testImplementation("io.mockk:mockk:1.9.3")
    }

    tasks {
        compileKotlin {
            kotlinOptions {
                jvmTarget = JavaVersion.VERSION_1_8.toString()
                freeCompilerArgs = listOf("-Xjsr305=strict")
                javaParameters = true
            }
        }

        compileTestKotlin {
            kotlinOptions {
                jvmTarget = JavaVersion.VERSION_1_8.toString()
                javaParameters = true
            }
        }

        test {
            failFast = true
            useJUnitPlatform()
            testLogging {
                events("passed", "skipped", "failed")
            }
            classpath += configurations.getByName("developmentOnly")
        }

        shadowJar {
            mergeServiceFiles()
        }

        withType<JavaExec> {
            classpath += configurations.getByName("developmentOnly")
            jvmArgs("-noverify", "-XX:TieredStopAtLevel=1", "-Dcom.sun.management.jmxremote")
        }
    }

    allOpen {
        annotation("io.micronaut.aop.Around")
    }
}