rtype/CMakeLists.txt at main · drawpitech/rtype · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
cmake_minimum_required(VERSION 3.28)
project(R-Type LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)                # Export compile commands (used by clangd)
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION_RELEASE ON)   # Enable LTO
set(CMAKE_CXX_SCAN_FOR_MODULES OFF)                  # Disable cpp modules (not supported by clangd)

enable_testing()
message("CXX FLAGS: ${CMAKE_CXX_FLAGS}")

# Dependencies
include(cmake/CPM.cmake)
find_package(Threads REQUIRED)

CPMUsePackageLock(package-lock.cmake)
CPMGetPackage(raylib-cpp)
CPMGetPackage(raylib)
CPMGetPackage(sol2)
CPMGetPackage(lua)
CPMGetPackage(ldtk-loader)
CPMGetPackage(asio)
CPMGetPackage(spdlog)
CPMGetPackage(serialize)
CPMGetPackage(googletest)
CPMGetPackage(argparse)

include(cmake/dep-asio.cmake)
include(cmake/dep-serialize.cmake)
include(cmake/dep-lua.cmake)

add_compile_options(
        "$<$<CXX_COMPILER_ID:MSVC>:/W4>"
        "$<$<CXX_COMPILER_ID:GNU,Clang>:-Wall;-Wextra;-Wpedantic>"
)

option(BUILD_SANITIZE "Build with sanitizers" OFF)

if (BUILD_SANITIZE)
    add_compile_options("$<$<CXX_COMPILER_ID:Clang,GNU>:-fsanitize=address,undefined;-fno-omit-frame-pointer>")
    add_link_options("$<$<CXX_COMPILER_ID:Clang,GNU>:-fsanitize=address,undefined;-fno-omit-frame-pointer>")
endif ()

add_subdirectory(engine)
add_subdirectory(r-type)
add_subdirectory(pong)