feedless/build.gradle.kts at master · damoeb/feedless · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
import java.util.*

buildscript {
  repositories {
    gradlePluginPortal()
  }
}

plugins {
  id("org.ajoberstar.grgit")
  alias(libs.plugins.kotlin.jvm) apply false
  alias(libs.plugins.kotlin.spring) apply false
  alias(libs.plugins.kapt) apply false
}

val buildDockerAioWeb = tasks.register("buildDockerAioWeb", Exec::class) {
  dependsOn(appWebDockerImagePath(), serverCoreDockerImagePath(), agentDockerImagePath())

  val semver = findProperty("feedlessVersion") as String
  val baseTag = findProperty("dockerImageTag")
  val gitHash = grgit.head().id.take(7)

  inputs.property("baseTag", findProperty("dockerImageTag"))
  inputs.property("gitHash", gitHash)
  inputs.property("semver", semver)

  // with web
  commandLine(
    "docker", "build",
    "--build-arg", "APP_VERSION=$semver",
    "--build-arg", "APP_GIT_COMMIT=$gitHash",
    "--build-arg", "APP_BUILD_TIMESTAMP=${Date().time}",
    "--platform=linux/amd64",
//    "--platform=linux/arm64v8",
    "-t", "$baseTag:aio-latest",
    "-t", "$baseTag:aio-$gitHash",
    "docker/aio-with-web"
  )
}

val validateAgentServerCanConnect = tasks.register("validateAgentServerCanConnect", Exec::class) {
  commandLine(
    "./test/system/validate-agent-server-can-connect.sh"
  )
}

val buildImages = tasks.register("buildImages") {
// todo enable finalizedBy(validateAgentServerCanConnect)
  dependsOn(
    appWebDockerImagePath(),
    serverCoreDockerImagePath(),
    agentDockerImagePath(),
  )
}

val buildDockerAioChromium = tasks.register("buildDockerAioChromium", Exec::class) {
  dependsOn(buildDockerAioWeb)

  val semver = findProperty("feedlessVersion") as String
  val baseTag = findProperty("dockerImageTag")
  val gitHash = grgit.head().id.take(7)

  inputs.property("baseTag", findProperty("dockerImageTag"))
  inputs.property("gitHash", gitHash)
  inputs.property("semver", semver)

  // with chromium
  commandLine(
    "docker", "build",
    "--build-arg", "APP_VERSION=$semver",
    "--build-arg", "APP_GIT_COMMIT=$gitHash",
    "--build-arg", "APP_BUILD_TIMESTAMP=${Date().time}",
    "--platform=linux/amd64",
//    "--platform=linux/arm64v8",
    "-t", "$baseTag:aio-chromium-latest",
    "-t", "$baseTag:aio-chromium-$gitHash",
    "docker/aio-with-chromium"
  )
}

subprojects {
  tasks.register("lintDockerImage", Exec::class) {
    commandLine(
      "sh",
      rootProject.file("lintDockerfile.sh").getAbsolutePath(),
      project.file("Dockerfile").getAbsolutePath()
    )
  }
}

fun appWebDockerImagePath() = "packages:app-web:bundle"
fun serverCoreDockerImagePath() = "packages:server-core:bundle"
fun agentDockerImagePath() = "packages:agent:bundle"