jenkins-plugin/build.gradle at master · crossbrowsertesting/jenkins-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
plugins {
    id 'org.jenkins-ci.jpi' version '0.22.0'
    id 'net.researchgate.release' version '2.6.0'
    id "se.bjurr.gitchangelog.git-changelog-gradle-plugin" version "1.50"
    id 'java'
    id 'idea'
}

group = 'org.jenkins-ci.plugins'
version = '2.5.1'
description = """This plugin integrates Jenkins users with Selenium Testing on CrossBrowserTesting.com. CrossBrowserTesting.com provides cross browser testing of websites, webpages, and web applications on Windows, Macs, and real iPhones, iPads, and Android Phones and Tablets."""

sourceCompatibility = 1.8
targetCompatibility = 1.8

tasks.withType(JavaCompile) {
	options.encoding = 'UTF-8'
}

repositories {
    mavenCentral()
    maven { url "https://jitpack.io" }
}
/*
 * gradle-jpi
 * https://github.com/jenkinsci/gradle-jpi-plugin/blob/master/README.md
*/
jenkinsPlugin {
    coreVersion = '2.5'
    displayName = 'CrossBrowserTesting.com Plugin'
    url = 'https://wiki.jenkins-ci.org/display/JENKINS/CrossBrowserTesting+Plugin'
    gitHubUrl = 'http://github.com/jenkinsci/crossbrowsertesting-plugin'
    repoUrl = 'https://repo.jenkins-ci.org/releases'
    fileExtension = 'hpi'

    developers {
        developer {
            id 'crossbrowsertesting'
            name 'CrossBrowserTesting.com LLC'
            email 'info@crossbrowsertesting.com'
        }
    }
    licenses {
        license {
            name 'MIT License'
            url 'http://opensource.org/licenses/MIT'
        }
    }
}
/*
 * gradle-release
 * https://github.com/researchgate/gradle-release/blob/master/README.md
 */
release {
    failOnSnapshotDependencies = false
    failOnUnversionedFiles = false
    tagTemplate = '$name-$version'
    buildTasks = ['build']
    scmAdapters = [net.researchgate.release.GitAdapter]

    git {
        requireBranch = 'master'
        pushToRemote = 'jenkins'
        commitVersionFileOnly = false
        signTag = false
    }
}

dependencies {
    compile group: 'org.json', name: 'json', version:'20151123'
    compile group: 'commons-codec', name: 'commons-codec', version:'1.9'
    compile group: 'com.github.crossbrowsertesting', name: 'ci-common', version:'1.4.6'
    testCompile group: 'org.codehaus.mojo', name: 'findbugs-maven-plugin', version: '3.0.4'

    jenkinsPlugins group: 'org.jenkins-ci.plugins', name: 'junit', version: '1.9', ext: 'jar'
    jenkinsPlugins group: 'org.jenkins-ci.plugins', name: 'credentials', version: '2.1.12', ext: 'jar'
    //jenkinsPlugins group: 'org.jenkins-ci.plugins', name: 'credentials', version: '2.1.16', ext: 'jar'

    jenkinsPlugins group: 'org.jenkins-ci.plugins.workflow', name: 'workflow-step-api', version: '2.12', ext: 'jar'
}

/*
 * specify a Jenkins version
 * otherwise uses what is specified in 'jenkinsPlugin.coreVersion'
 * -Pjenkins=${jenkins_version}
 */
if (project.hasProperty('jenkins')) {
    jenkinsPlugin.coreVersion = project.getProperty('jenkins')
}
task wrapper(type: Wrapper) {
    gradleVersion = '4.0.2'
}
task changelog(type: se.bjurr.gitchangelog.plugin.gradle.GitChangelogTask) {
    file = new File("CHANGELOG.md");
    templateContent = """

{{#tags}}
## {{name}}
{{#issues}}
### {{title}}
{{#commits}}
  {{#hash}}
  {{#message}}
   * [{{hash}}](https://github.com/jenkinsci/crossbrowsertesting-plugin/commit/{{hash}}) {{{message}}}
  {{/message}}
  {{/hash}}
{{/commits}}
{{/issues}}
{{/tags}}
 """;
}