compiler/scan.rkt at master · bdj/compiler · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
#lang racket
(require (for-syntax unstable/syntax))

(provide scan)

(struct token () #:transparent)
(provide (struct-out token))

(define-for-syntax (define-tokens stx fields)
  (define (define-token t)
    (define id (format-id t "~a-token" t))
    #`(begin
        (struct #,id token #,fields #:transparent)
        (provide (struct-out #,id))))
  (syntax-case stx ()
    [(_ t)
     (define-token #'t)]
    [(define-tokens t0 t1 ...)
     #`(begin
         #,(define-token #'t0)
         (define-tokens t1 ...))]))

(define-syntax (define-empty-tokens stx)
  (define-tokens stx #'()))

(define-syntax (define-value-tokens stx)
  (define-tokens stx #'(v)))

(define-empty-tokens lparen rparen quote quasiquote dot vector eof unquote splice)

(define-value-tokens boolean string number identifier character)

(define (scan)
  (define (whitespace-char? c) (memv c '(#\space #\newline)))
  (define (sign-char? c) (memv c '(#\+ #\-)))
  (define (digit-char? c) (char<=? #\0 c #\9))
  (define (initial-char? c) (or (letter-char? c) (special-initial-char? c)))
  (define (letter-char? c) (char<=? #\a c #\z))
  (define (special-initial-char? c) (memv c '(#\! #\$ #\% #\& #\* #\/ #\: #\< #\= #\? #\~ #\_ #\^)))
  (define (delimiter-char? c) (or (eof-object? c) (whitespace-char? c) (memv c '(#\( #\) #\" #\;))))
  (define (subsequent-char? c) (or (initial-char? c) (digit-char? c) (memv c '(#\. #\+ #\-))))
  (define (char->sign c) (if (eqv? #\+ c) + -))
  (define (char->digit c) (- (char->integer c) (char->integer #\0)))
  (define (scan-error c) (error 'scan "Unexpected char ~s" c))
  (define (start)
    (define c (read-char))
    (cond
      [(eof-object? c) (eof-token)]
      [(eqv? #\( c) (lparen-token)]
      [(eqv? #\) c) (rparen-token)]
      [(eqv? #\# c) (scan-hash)]
      [(eqv? #\' c) (quote-token)]
      [(eqv? #\` c) (quasiquote-token)]
      [(eqv? #\, c) (scan-unquote)]
      [(eqv? #\" c) (scan-string)]
      [(eqv? #\; c) (scan-comment)]
      [(eqv? #\. c) (scan-dot)]
      [(whitespace-char? c) (start)]
      [(sign-char? c) (scan-sign c)]
      [(digit-char? c) (scan-number + (char->digit c))]
      [(initial-char? c) (scan-identifier c)]
      [else (scan-error c)]))
  (define (scan-hash)
    (define c (read-char))
    (cond
      [(eqv? #\t c) (boolean-token #t)]
      [(eqv? #\f c) (boolean-token #f)]
      [(eqv? #\( c) (vector-token)]
      [(eqv? #\\ c) (scan-character)]
      [else (scan-error c)]))
  (define (scan-unquote)
    (define c (peek-char))
    (cond
      [(eqv? #\@ c) (read-char) (splice-token)]
      [else (unquote-token)]))
  (define (scan-string)
    (string-token (list->string (scan-string-elements))))
  (define (scan-string-elements)
    (define c (read-char))
    (cond
      [(eqv? c #\\) (scan-escape)]
      [(eqv? c #\") empty]
      [else (cons c (scan-string-elements))]))
  (define (scan-escape)
    (define c (read-char))
    (cond
      [(or (eqv? c #\\) (eqv? c #\")) c]
      [else (scan-error c)]))
  (define (scan-comment)
    (define c (read-char))
    (cond
      [(eof-object? c) (eof-token)]
      [(eqv? #\newline c) (start)]
      [else (scan-comment)]))
  (define (scan-dot)
    (define c (peek-char))
    (cond
      [(delimiter-char? c) (dot-token)]
      [(eqv? #\. c) (read-char) (scan-ellipsis)]
      [else (scan-error c)]))
  (define (scan-ellipsis)
    (define c (read-char))
    (cond
      [(eqv? #\. c) (identifier-token '...)]
      [else (scan-error c)]))
  (define (scan-sign c)
    (define cp (peek-char))
    (cond
      [(delimiter-char? cp) (identifier-token (string->symbol (string c)))]
      [else (scan-number (char->sign c) 0)]))
  (define (scan-number sign acc)
    (define c (peek-char))
    (cond
      [(delimiter-char? c) (number-token (sign acc))]
      [(digit-char? c) (read-char) (scan-number sign (+ (* 10 acc) (char->digit c)))]
      [else (scan-error c)]))
  (define (scan-identifier c)
    (define cp (peek-char))
    (cond
      [(delimiter-char? cp) (identifier-token (string->symbol (string c)))]
      [(subsequent-char? cp) (scan-subsequent (list (read-char) c))]
      [else (scan-error cp)]))
  (define (scan-subsequent acc)
    (define cp (peek-char))
    (cond
      [(delimiter-char? cp) (identifier-token (string->symbol (list->string (reverse acc))))]
      [(subsequent-char? cp) (scan-subsequent (cons (read-char) acc))]
      [else (scan-error cp)]))
  (define (scan-character)
    (define c (read-char))
    (define cp (peek-char))
    (cond
      [(delimiter-char? cp) (character-token c)]
      [(eqv? #\n c) (scan-newline)]
      [(eqv? #\s c) (scan-space)]
      [else (scan-error c)]))
  (define (scan-newline)
    (define s (read-string 6))
    (if (equal? "ewline" s)
        (character-token #\newline)
        (scan-error s)))
  (define (scan-space)
    (define s (read-string 4))
    (if (equal? "pace" s)
        (character-token #\space)
        (scan-error s)))
  (start))