api/build.gradle at main · anisekai-project/api · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
plugins {
    id 'java'
    alias(libs.plugins.spring.framework)
    alias(libs.plugins.spring.dependencyManagement)
    alias(libs.plugins.catalogUpdater)
    alias(libs.plugins.reckon)
    alias(libs.plugins.sentry)
}

group = 'fr.anisekai'

apply from: 'gradle/reckon.gradle'
apply from: 'gradle/java.gradle'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
    mavenLocal()
}

dependencies {
    implementation(libs.springframework.actuator)
    implementation(libs.springframework.data.jpa)
    implementation(libs.springframework.jdbc)
    implementation(libs.springframework.web)

    testImplementation(libs.testing.springframework.test)

    implementation(libs.springdoc.openapi)

    implementation(libs.security.uuid)
    implementation(libs.security.jjwt.api)
    runtimeOnly(libs.security.jjwt.impl)
    runtimeOnly(libs.security.jjwt.jackson)

    runtimeOnly(libs.database.mariadb.client)
    implementation(libs.database.flyway.core)
    implementation(libs.database.flyway.mysql)

    implementation(libs.api.discord.jda)
    implementation(libs.api.discord.jda.interactions)
    implementation(libs.api.anisekai.sanctum)
    implementation(libs.api.anisekai.proxy)
    implementation(libs.api.anisekai.ffmpeg)

    implementation(libs.util.http.client)
    implementation(libs.util.json)
    implementation(libs.util.jsoup)
    implementation(libs.util.rome)
    implementation(libs.util.slugify)

    annotationProcessor(libs.dev.spring.configuration.processor)
    implementation(libs.dev.annotations.jetbrains)
}

test {
    useJUnitPlatform()
}

sentry {
    includeSourceContext = true

    org = 'anisekai'
    projectName = 'service'
    authToken = providers.gradleProperty('sentry.authToken')
            .orElse(providers.environmentVariable('SENTRY_AUTH_TOKEN'))
            .getOrNull()
}

// Thanks, Sentry (pls fix your plugin idk)
tasks.named('sourcesJar') {
    dependsOn('generateSentryDebugMetaPropertiesjava')
    dependsOn('collectExternalDependenciesForSentry')
}

tasks.matching { it.name.contains("sentry") || it.name.contains("Sentry") }.configureEach {
    mustRunAfter('generateJava')
}