python-re3data/justfile at main · afuetterer/python-re3data · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
# justfile
# Ref: https://just.systems/man/en/
# ------------------------------------------------------------------------------

export UV_LOCKED := "true"

_default:
    @just --list --unsorted

sync:
    uv sync

sync-docs:
    uv sync --group=docs

@project-version:
    uv version | awk '{print $2}'

pre-commit := "pre-commit run --all-files --color=always --show-diff-on-failure"

[group('lint')]
lint:
    SKIP=mypy uv run {{ pre-commit }}

[group('lint')]
typecheck:
    uv run {{ pre-commit }} mypy

[group('lint')]
check: lint typecheck

[group('test')]
test:
    uv run pytest tests

[group('test')]
e2e-test:
    uv run pytest -m e2e

[group('test')]
cov:
    uv run pytest --cov=src

[group('test')]
cov-report-markdown:
    uv run python -m coverage report --format=markdown > coverage.md

[group('test')]
cov-total:
    uv run python -m coverage json --quiet
    uv run python -c "import json;print(json.load(open('coverage.json'))['totals']['percent_covered_display'])"

config := "--config-file=docs/mkdocs.yml"

[group('docs')]
docs-cli:
    uv run typer src/re3data/_cli.py utils docs --name=re3data --title='Command Line Interface' --output docs/src/cli.md

[group('docs')]
docs-build: docs-cli
    uv run mkdocs build {{ config }}

[group('docs')]
docs-serve: docs-cli
    uv run mkdocs serve {{ config }} --verbose

[group('docs')]
docs-deploy: docs-cli
    uv run mike deploy {{ config }} --push --update-aliases $(just project-version) latest