feat: add ERC1155 Data and Metadata facets and module

Author: aapsi

src/token/ERC1155/Data/ERC1155DataFacet.sol

@@ -0,0 +1,91 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.30;
+
+/* Compose
+ * https://compose.diamonds
+ */
+
+/**
+ * @title ERC-1155 Multi Token Standard
+ *
+ */
+contract ERC1155DataFacet {
+    /**
+     * @notice Error indicating array length mismatch in batch operations.
+     * @param _idsLength Length of the ids array.
+     * @param _valuesLength Length of the values array.
+     */
+    error ERC1155InvalidArrayLength(uint256 _idsLength, uint256 _valuesLength);
+
+    /**
+     * @dev Storage position determined by the keccak256 hash of the diamond storage identifier.
+     */
+    bytes32 constant STORAGE_POSITION = keccak256("erc1155");
+
+    /**
+     * @dev ERC-8042 compliant storage struct for ERC-1155 token data.
+     * @custom:storage-location erc8042:erc1155
+     */
+    struct ERC1155Storage {
+        mapping(uint256 id => mapping(address account => uint256 balance)) balanceOf;
+        mapping(address account => mapping(address operator => bool)) isApprovedForAll;
+        string uri;
+        string baseURI;
+        mapping(uint256 tokenId => string) tokenURIs;
+    }
+
+    /**
+     * @notice Returns the ERC-1155 storage struct from the predefined diamond storage slot.
+     * @dev Uses inline assembly to set the storage slot reference.
+     * @return s The ERC-1155 storage struct reference.
+     */
+    function getStorage() internal pure returns (ERC1155Storage storage s) {
+        bytes32 position = STORAGE_POSITION;
+        assembly {
+            s.slot := position
+        }
+    }
+
+    /**
+     * @notice Returns the amount of tokens of token type `id` owned by `account`.
+     * @param _account The address to query the balance of.
+     * @param _id The token type to query.
+     * @return The balance of the token type.
+     */
+    function balanceOf(address _account, uint256 _id) external view returns (uint256) {
+        return getStorage().balanceOf[_id][_account];
+    }
+
+    /**
+     * @notice Batched version of {balanceOf}.
+     * @param _accounts The addresses to query the balances of.
+     * @param _ids The token types to query.
+     * @return balances The balances of the token types.
+     */
+    function balanceOfBatch(address[] calldata _accounts, uint256[] calldata _ids)
+        external
+        view
+        returns (uint256[] memory balances)
+    {
+        if (_accounts.length != _ids.length) {
+            revert ERC1155InvalidArrayLength(_ids.length, _accounts.length);
+        }
+
+        ERC1155Storage storage s = getStorage();
+        balances = new uint256[](_accounts.length);
+
+        for (uint256 i = 0; i < _accounts.length; i++) {
+            balances[i] = s.balanceOf[_ids[i]][_accounts[i]];
+        }
+    }
+
+    /**
+     * @notice Returns true if `operator` is approved to transfer `account`'s tokens.
+     * @param _account The token owner.
+     * @param _operator The operator to query.
+     * @return True if the operator is approved, false otherwise.
+     */
+    function isApprovedForAll(address _account, address _operator) external view returns (bool) {
+        return getStorage().isApprovedForAll[_account][_operator];
+    }
+}

src/token/ERC1155/Metadata/ERC1155MetadataFacet.sol

@@ -0,0 +1,64 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.30;
+
+/* Compose
+ * https://compose.diamonds
+ */
+
+/**
+ * @title ERC-1155 Metadata Facet
+ * @notice Provides URI metadata functionality for ERC-1155 tokens.
+ */
+contract ERC1155MetadataFacet {
+    /**
+     * @notice Emitted when the URI for token type `_id` changes to `_value`.
+     * @param _value The new URI for the token type.
+     * @param _id The token type whose URI changed.
+     */
+    event URI(string _value, uint256 indexed _id);
+
+    /**
+     * @dev Storage position determined by the keccak256 hash of the diamond storage identifier.
+     */
+    bytes32 constant STORAGE_POSITION = keccak256("erc1155");
+
+    /**
+     * @dev ERC-8042 compliant storage struct for ERC-1155 token data.
+     * @custom:storage-location erc8042:erc1155
+     */
+    struct ERC1155Storage {
+        mapping(uint256 id => mapping(address account => uint256 balance)) balanceOf;
+        mapping(address account => mapping(address operator => bool)) isApprovedForAll;
+        string uri;
+        string baseURI;
+        mapping(uint256 tokenId => string) tokenURIs;
+    }
+
+    /**
+     * @notice Returns the ERC-1155 storage struct from the predefined diamond storage slot.
+     * @dev Uses inline assembly to set the storage slot reference.
+     * @return s The ERC-1155 storage struct reference.
+     */
+    function getStorage() internal pure returns (ERC1155Storage storage s) {
+        bytes32 position = STORAGE_POSITION;
+        assembly {
+            s.slot := position
+        }
+    }
+
+    /**
+     * @notice Returns the URI for token type `_id`.
+     * @dev If a token-specific URI is set in tokenURIs[_id], returns the concatenation of baseURI and tokenURIs[_id].
+     *      Note that baseURI is empty by default and must be set explicitly if concatenation is desired.
+     *      If no token-specific URI is set, returns the default URI which applies to all token types.
+     *      The default URI may contain the substring `{id}` which clients should replace with the actual token ID.
+     * @param _id The token ID to query.
+     * @return The URI for the token type.
+     */
+    function uri(uint256 _id) external view returns (string memory) {
+        ERC1155Storage storage s = getStorage();
+        string memory tokenURI = s.tokenURIs[_id];
+
+        return bytes(tokenURI).length > 0 ? string.concat(s.baseURI, tokenURI) : s.uri;
+    }
+}

src/token/ERC1155/Metadata/ERC1155MetadataMod.sol

@@ -0,0 +1,83 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.30;
+
+/* Compose
+ * https://compose.diamonds
+ */
+
+/**
+ * @title ERC-1155 Metadata Module
+ * @notice Provides internal metadata functionality for ERC-1155 tokens.
+ */
+
+/**
+ * @notice Emitted when the URI for token type `_id` changes to `_value`.
+ * @param _value The new URI for the token type.
+ * @param _id The token type whose URI changed.
+ */
+event URI(string _value, uint256 indexed _id);
+
+/**
+ * @dev Storage position determined by the keccak256 hash of the diamond storage identifier.
+ */
+bytes32 constant STORAGE_POSITION = keccak256("erc1155");
+
+/**
+ * @dev ERC-8042 compliant storage struct for ERC-1155 token data.
+ * @custom:storage-location erc8042:erc1155
+ */
+struct ERC1155Storage {
+    mapping(uint256 id => mapping(address account => uint256 balance)) balanceOf;
+    mapping(address account => mapping(address operator => bool)) isApprovedForAll;
+    string uri;
+    string baseURI;
+    mapping(uint256 tokenId => string) tokenURIs;
+}
+
+/**
+ * @notice Returns the ERC-1155 storage struct from the predefined diamond storage slot.
+ * @dev Uses inline assembly to set the storage slot reference.
+ * @return s The ERC-1155 storage struct reference.
+ */
+function getStorage() pure returns (ERC1155Storage storage s) {
+    bytes32 position = STORAGE_POSITION;
+    assembly {
+        s.slot := position
+    }
+}
+
+/**
+ * @notice Sets the token-specific URI for a given token ID.
+ * @dev Sets tokenURIs[_tokenId] to the provided string and emits a URI event with the full computed URI.
+ *      The emitted URI is the concatenation of baseURI and the token-specific URI.
+ * @param _tokenId The token ID to set the URI for.
+ * @param _tokenURI The token-specific URI string to be concatenated with baseURI.
+ */
+function setTokenURI(uint256 _tokenId, string memory _tokenURI) {
+    ERC1155Storage storage s = getStorage();
+    s.tokenURIs[_tokenId] = _tokenURI;
+
+    string memory fullURI = bytes(_tokenURI).length > 0 ? string.concat(s.baseURI, _tokenURI) : s.uri;
+    emit URI(fullURI, _tokenId);
+}
+
+/**
+ * @notice Sets the base URI prefix for token-specific URIs.
+ * @dev The base URI is concatenated with token-specific URIs set via setTokenURI.
+ *      Does not affect the default URI used when no token-specific URI is set.
+ * @param _baseURI The base URI string to prepend to token-specific URIs.
+ */
+function setBaseURI(string memory _baseURI) {
+    ERC1155Storage storage s = getStorage();
+    s.baseURI = _baseURI;
+}
+
+/**
+ * @notice Sets the default URI for all token types.
+ * @dev This URI is used when no token-specific URI is set.
+ * @param _uri The default URI string.
+ */
+function setURI(string memory _uri) {
+    ERC1155Storage storage s = getStorage();
+    s.uri = _uri;
+}