mswin: use shellsplit sub batch

Introduce shellsplit.cmd to simplify configure.bat command line parsing.
Makefile macro definition and opt-dir list now free from quoting.
eg. now can use as
```
configure --with-opt-dir=c:/src/zlib;c:/src/libffi CC="cl -std:clatest"
```

Author: YO4

win32/configure.bat

@@ -19,20 +19,49 @@ call set "WIN32DIR=%%WIN32DIR:/%~n0:/:=:/:%%"
 set "WIN32DIR=%WIN32DIR:~0,-3%"
 
 set configure=%~0
+set target=
 set optdirs=
 set pathlist=
 set config_make=confargs~%RANDOM%.mak
 set confargs=%config_make:.mak=.sub%
 set debug_configure=
 echo>%config_make% # CONFIGURE
 type nul > %confargs%
+set args=%*
+goto :loop
+
+:shift_argv
+call %~dp0shellsplit.cmd
+set "argv1=%argv2%"
+set "argv2=%argv%"
+if not defined argv1 if defined argv2 goto :shift_argv
+exit /b
+
+:set_arg
+set next_is_opt=
+if defined arg exit /b
+if not defined argv2 exit /b
+if not "%argv2:~0,1%"=="-" (set "arg=%argv2%" & call :shift_argv)
+exit /b
+
 :loop
-if [%1] == [] goto :end ;
-if "%~1" == "" (shift & goto :loop)
-for /f "delims== tokens=1,*" %%I in ("%~1") do ((set "opt=%%I") && (set "arg=%%J"))
-  set "eq=="
-  if "%arg%" == "" if not "%~1" == "%opt%=%arg%" (set "eq=")
-  shift
+call :shift_argv
+if not defined argv1 if not defined argv2 goto :end
+REM if %argv1% == "" goto :loop
+
+for /f "delims== tokens=1*" %%I in (" %argv1% ") do ((set "opt=%%I") && (set "arg=%%J"))
+  set "opt=%opt:~1%"
+  set "eq="
+  if defined arg (
+    set "eq=="
+    set "arg=%arg:~0,-1%"
+  ) else (
+    set "opt=%opt:~0,-1%"
+  )
+  if "%opt%"=="" (
+    echo 1>&2 %configure%: assignment for empty variable name %argv1%
+    exit /b 1
+  )
   if "%opt%" == "--debug-configure" (
     echo on
     set "debug_configure=yes"
@@ -78,7 +107,7 @@ for /f "delims== tokens=1,*" %%I in ("%~1") do ((set "opt=%%I") && (set "arg=%%J
   )
 goto :loop ;
 :target
-  if "%eq%" == "" (set "arg=%~1" & shift)
+  if "%eq%" == "" call :set_arg
   if "%arg%" == "" (
     echo 1>&2 %configure%: missing argument for %opt%
     exit /b 1
@@ -88,7 +117,6 @@ goto :loop ;
   echo>>%confargs%  "--target=%arg:$=$$%" \
 goto :loop ;
 :program_name
-  if "%eq%" == "" (set "arg=%~1" & shift)
   for /f "delims=- tokens=1,*" %I in ("%opt%") do set "var=%%J"
   if "%var%" == "prefix" (set "var=PROGRAM_PREFIX" & goto :name)
   if "%var%" == "suffix" (set "var=PROGRAM_SUFFIX" & goto :name)
@@ -99,32 +127,37 @@ goto :loop ;
   )
 goto :unknown_opt
 :name
-  if "%eq%" == "" (set "arg=%~1" & shift)
+  if "%eq%" == "" call :set_arg
   echo>> %config_make% %var% = %arg%
 goto :loopend ;
 :dir
-  if "%eq%" == "" (set "arg=%~1" & shift)
+  if "%eq%" == "" call :set_arg
   echo>> %config_make% %opt:~2% = %arg:\=/%
 goto :loopend ;
 :enable
-  echo>>%confargs%  "%opt%" \
-  if %enable% == yes (set "opt=%opt:~9%") else (set "opt=%opt:~10%")
-  if "%opt%" == "rdoc" (
+  if %enable% == yes (
+    if "%eq%" == "" call :set_arg
+    set "feature=%opt:~9%"
+  ) else (
+    set "feature=%opt:~10%"
+  )
+  if %enable% == yes if defined arg set "enable=%arg%"
+  if "%feature%" == "install-doc" (
     echo>> %config_make% RDOCTARGET = %enable:yes=r%doc
   )
-  if "%opt%" == "install-static-library" (
+  if "%feature%" == "install-static-library" (
     echo>> %config_make% INSTALL_STATIC_LIBRARY = %enable%
   )
-  if "%opt%" == "debug-env" (
+  if "%feature%" == "debug-env" (
     echo>> %config_make% ENABLE_DEBUG_ENV = %enable%
   )
-  if "%opt%" == "devel" (
+  if "%feature%" == "devel" (
     echo>> %config_make% RUBY_DEVEL = %enable%
   )
-  if "%opt%" == "rubygems" (
-    echo>> %config_make% USE_RUBYGEMS = %enable%
+  if "%feature%" == "rubygems" (
+     echo>> %config_make% USE_RUBYGEMS = %enable%
   )
-goto :loop ;
+goto :loopend ;
 :withoutarg
   echo>>%confargs%  "%opt%" \
   if "%opt%" == "--without-baseruby" goto :nobaseruby
@@ -134,7 +167,7 @@ goto :loop ;
 goto :loop ;
 :witharg
   if "%opt%" == "--with-static-linked-ext" goto :extstatic
-  if "%eq%" == "" (set "arg=%~1" & shift)
+  if "%eq%" == "" call :set_arg
   if not "%arg%" == "" (
     echo>>%confargs%  "%opt%=%arg:$=$$%" \
   ) else (
@@ -152,7 +185,7 @@ goto :loop ;
 :ntver
   ::- For version constants, see
   ::- https://learn.microsoft.com/en-us/cpp/porting/modifying-winver-and-win32-winnt#remarks
-  if "%eq%" == "" (set "NTVER=%~1" & shift) else (set "NTVER=%arg%")
+  if "%eq%" == "" (set "NTVER=%~1" & call :shift_argv) else (set "NTVER=%arg%")
   if /i not "%NTVER:~0,2%" == "0x" if /i not "%NTVER:~0,13%" == "_WIN32_WINNT_" (
     for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
       call set NTVER=%%NTVER:%%i=%%i%%
@@ -162,15 +195,15 @@ goto :loop ;
   echo>> %config_make% NTVER = %NTVER%
 goto :loopend ;
 :extout
-  if "%eq%" == "" (set "arg=%~1" & shift)
+  if "%eq%" == "" call :set_arg
   if not "%arg%" == ".ext" (echo>> %config_make% EXTOUT = %arg%)
 goto :loopend ;
 :path
-  if "%eq%" == "" (set "arg=%~1" & shift)
+  if "%eq%" == "" call :set_arg
   set "pathlist=%pathlist%%arg:\=/%;"
 goto :loopend ;
 :extstatic
-  if "%eq%" == "" (set "arg=static" & shift)
+  if "%eq%" == "" (set "arg=static")
   echo>> %config_make% EXTSTATIC = %arg%
 goto :loopend ;
 :baseruby
@@ -203,13 +236,16 @@ goto :loop ;
     exit /b 1
   )
   :optdir-loop
-  for /f "delims=; tokens=1,*" %%I in ("%arg%") do (set "d=%%I" & set "arg=%%J")
-    pushd %d:/=\% 2> nul && (
-      set "optdirs=%optdirs%;%CD:\=/%"
+  setlocal EnableDelayedExpansion
+  for /f "delims=; tokens=1,*" %%I in ("%arg%") do ((set "d=%%I" & set "arg=%%J")
+    pushd !d:/=\! 2> nul
+    if not ERRORLEVEL 1 (
+      call set d=%%cd%%
       popd
-    ) || (
-      set "optdirs=%optdirs%;%d:\=/%"
     )
+    call set "optdirs=%%optdirs%%;%%d:\=/%%"
+  )
+  endlocal & set "optdirs=%optdirs%" & set "arg=%arg%"
   if not "%arg%" == "" goto :optdir-loop
 goto :loop ;
 :help
@@ -241,7 +277,7 @@ goto :EOF
   exit /b 1
 :end
 if "%debug_configure%" == "yes" (type %confargs%)
-if defined optdirs (for %%I in ("%optdirs:~1%") do echo>>%config_make% optdirs = %%~I)
+if defined optdirs echo>>%config_make% optdirs = %optdirs:~1%
 (
   echo.
   echo configure_args = \

win32/shellsplit.cmd

@@ -0,0 +1,110 @@
+rem shellsplit.cmd
+rem input : %args%
+rem output: one unquoted %argv%, remains are in %args%
+rem note  : the empty argument "" is completely ignored.
+
+setlocal EnableExtensions DisableDelayedExpansion
+
+if not defined V set V=0
+
+set OUT=
+if not defined args (
+ goto :return_arg
+)
+set "PENDING=%args%"
+set UNQ=
+set QTD=
+
+rem set "PENDING=%PENDING:\"=`??%" &:: .subst(\", `DQ`) (currently disabled)
+set "PENDING=%PENDING:"=#sep%"     &:: .subst(", #sep)
+
+::#### split into unquoted part, quoted part, remains
+:loop
+
+for /F "tokens=1,2* delims=#" %%I in (" %PENDING%") do (
+  set "UNQ=%%I"
+  call set "UNQ=%%UNQ:~1%%"
+  set "QTD=%%J"
+  set "PENDING=%%K"
+)
+
+if %V%==1 (
+  echo unquoted:
+  (echo UNQ :"%UNQ%")&(echo QTD :"%QTD%")&(echo REST:"%PENDING%")&(if defined OUT echo OUT:"%OUT%")
+)
+
+if defined QTD call set "QTD=%%QTD:~3%%"             &:: remove sep
+if defined PENDING call set "PENDING=%%PENDING:~3%%" &:: ditto
+
+if %V%==1 (
+  (echo QTD :"%QTD%")&(echo REST:"%PENDING%")
+)
+
+if not defined UNQ if defined OUT (
+  set concat_next=true
+  goto :process_unquote
+)
+
+set concat_prev=
+set concat_check=
+if defined UNQ set "concat_check=%UNQ:~0,1%"
+if not "%concat_check%"==" " set concat_prev=true
+
+set concat_next=
+set concat_check=
+if defined UNQ set "concat_check=%UNQ:~-1%"
+if not "%concat_check%"==" " set concat_next=true
+
+if not defined concat_prev if defined OUT (
+  goto :return_arg
+)
+
+::#### process unquoted part
+:process_unquote
+
+if defined UNQ if "%UNQ: =%"=="" set UNQ=
+if not defined UNQ goto :process_quoted
+
+for /F "tokens=1*" %%I in ("%UNQ%") do (
+  set "token=%%I"
+  set "UNQ=%%J"
+)
+
+if %V%==1 (
+  (echo unq :"%token%")&(echo UNQ :"%UNQ%")
+)
+
+set "OUT=%OUT%%token%"
+if defined UNQ (
+  goto :return_arg
+) else (
+  if not defined concat_next (
+    goto :return_arg
+  )
+)
+
+::#### process quoted part
+:process_quoted
+
+if %V%==1 (
+  echo quoted:
+  (echo UNQ :"%UNQ%")&(echo QTD :"%QTD%")&(echo REST:"%PENDING%")&(if defined OUT echo OUT:"%OUT%")
+)
+
+set "OUT=%OUT%%QTD%"
+set QTD=
+
+if not defined PENDING (
+  goto :return_arg
+)
+goto :loop
+
+::#### return splitted argv
+:return_arg
+
+if defined PENDING call set "PENDING=%%PENDING:#sep="%%"
+set eq="
+
+endlocal & set "argv=%OUT%" & set "args=%UNQ%%eq%%QTD%%eq%%PENDING%"
+
+exit /b

win32/test_shellsplit.cmd

@@ -0,0 +1,36 @@
+@echo off & if not [%1]==[] goto :process
+
+echo This script demonstrates how shellsplit.cmd works.
+echo usage: %0 arg1 [arg2]...
+echo Prints (arg1) (arg2), shift the arguments, and loop until there are no more arguments.
+echo - splits commandline with spaces.
+echo - support quoting but only with double quotes.
+echo - escape character not supported.
+echo - standalone "" is ignored since cmd.exe variables cannot represent empty strings.
+exit /b 0
+
+:process
+setlocal
+set V=0
+set argv1=
+set argv2=
+
+set "args=%*"
+
+:loop
+call :shift_argv
+if not defined argv1 if not defined argv2 goto :end
+echo (%argv1%) (%argv2%)
+
+goto :loop
+
+:shift_argv
+call %~dp0\shellsplit.cmd
+set "argv1=%argv2%"
+set "argv2=%argv%"
+if not defined argv1 if defined argv2 goto :shift_argv
+
+exit /b
+
+:end
+exit /b 0