wcm/meson.build at master · WayfireWM/wcm · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
project('wcm', 'c', 'cpp', version : '0.11.0', default_options : 'cpp_std=c++17')

fs = import('fs')

add_global_arguments('-DWAYFIRE_CONFIG_FILE="' + get_option('wayfire_config_file_path') + '"', language : 'cpp')
add_global_arguments('-DWF_SHELL_CONFIG_FILE="' + get_option('wf_shell_config_file_path') + '"', language : 'cpp')

dependency('pkg-config', required : true)
evdev = dependency('libevdev')
wayfire = dependency('wayfire', version: '>=0.11.0')
wf_shell = dependency('wf-shell', required : get_option('wf_shell'))

wayfire_metadata_dir = wayfire.get_variable(pkgconfig: 'metadatadir')
wayfire_sysconf_dir = wayfire.get_variable(pkgconfig: 'sysconfdir')

share_dir = join_paths(get_option('prefix'), 'share')
wayfire_locale_dir = join_paths(share_dir, 'locale')
wcm_icon_dir = join_paths(share_dir, 'icons', 'hicolor', 'scalable', 'apps')
wayfire_icon_dir = wayfire.get_variable(pkgconfig: 'icondir')

add_global_arguments('-DWAYFIRE_METADATADIR="' + wayfire_metadata_dir + '"', language : 'cpp')
add_global_arguments('-DWAYFIRE_LOCALEDIR="' + wayfire_locale_dir + '"', language : 'cpp')
add_global_arguments('-DWAYFIRE_SYSCONFDIR="' + wayfire_sysconf_dir + '"', language : 'cpp')
if wf_shell.found()
    wf_shell_metadata_dir = wf_shell.get_variable(pkgconfig: 'metadatadir')
    wf_shell_sysconf_dir = wf_shell.get_variable(pkgconfig: 'sysconfdir')
    add_global_arguments('-DHAVE_WFSHELL=1', language : 'cpp')
    add_global_arguments('-DWFSHELL_METADATADIR="' + wf_shell_metadata_dir + '"', language : 'cpp')
    add_global_arguments('-DWFSHELL_SYSCONFDIR="' + wf_shell_sysconf_dir + '"', language : 'cpp')
endif

add_global_arguments('-DWAYFIRE_ICONDIR="' + wayfire_icon_dir + '"', language : 'cpp')
add_global_arguments('-DWCM_ICONDIR="' + wcm_icon_dir + '"', language : 'cpp')

subdir('icons')
subdir('proto')
subdir('src')
subdir('locale')

install_data('wcm.desktop', install_dir: join_paths(share_dir, 'applications'))