ViaProxyRakNetProviders/build.gradle at 204b9c7219299fe7c2c913e20e64d6835bffa243 · ViaVersionAddons/ViaProxyRakNetProviders · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
plugins {
    id "viaproxy.plugin-conventions"
    id "net.lenni0451.repackager" version "1.0.2"
}

configurations {
    repackagedIncludeInJar

    includeInJar.extendsFrom(repackagedIncludeInJar)
}

repositories {
    maven {
        name = "OpenCollab Releases"
        url = "https://repo.opencollab.dev/maven-releases"

        content {
            includeGroupByRegex "org\\.cloudburstmc(\\..+)?"
        }
    }
    maven {
        name = "OpenCollab Snapshots"
        url = "https://repo.opencollab.dev/maven-snapshots"

        content {
            includeGroupByRegex "org\\.cloudburstmc(\\..+)?"
        }
    }
    maven {
        name = "Jitpack"
        url = "https://jitpack.io"

        content {
            includeGroupByRegex "com\\.github\\..+"
        }
    }
}

dependencies {
    implementation("net.raphimc:ViaProxy:3.4.9-SNAPSHOT") {
        transitive = false
    }

    includeInJar "net.java.dev.jna:jna:5.18.1"

    // For dependency sources, see RakNetBackend class
    includeInJar "com.github.RelativityMC.netty-raknet:netty-raknet-client:15536296c2"
    includeInJar("com.github.telecran-telecrit:JRakNet:d757e139ce") {
        exclude group: "org.apache.logging.log4j"
        exclude group: "io.netty"
    }
    repackagedIncludeInJar("org.cloudburstmc.netty:netty-transport-raknet:1.0.0.CR3-20251031.125212-22") {
        transitive = false
    }
}

dependencyRepackager {
    configuration = configurations.repackagedIncludeInJar
    relocations = [
            "org.cloudburstmc.netty": "org.cloudburstmc.upstream.netty"
    ]
    removeEmptyDirs = true
}