JGiven/settings.gradle at master · TNG/JGiven · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
pluginManagement {
    plugins {
        id 'com.tngtech.jgiven.gradle-plugin' version "${version}"

    }

    repositories {
        gradlePluginPortal()
        google()
        maven {
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
        maven {
            url = "https://oss.sonatype.org/content/repositories/staging/"
        }
    }
}

plugins {
    id 'com.gradle.develocity' version '4.4.1'
}


develocity{
    buildScan {
        termsOfUseUrl = 'https://gradle.com/terms-of-service'
        termsOfUseAgree = 'yes'
    }
}

rootProject.name = 'JGiven'
includeBuild('build-conventions')
include ':jgiven-core',
        ':jgiven-maven-plugin',
        ':jgiven-junit',
        ':jgiven-spock2',
        ':jgiven-testng',
        ':jgiven-spring',
        ':jgiven-spring-junit4',
        ':jgiven-html-app',
        ':jgiven-html5-report',
        ':jgiven-asciidoc-report',
        ':jgiven-tests',
        ':jgiven-examples',
        ':jgiven-junit5',
        ':jgiven-spring-junit5',
        ':jgiven-gradle-plugin'

def timingEnabled = System.getenv("JGivenTiming")

if (timingEnabled) {
    include ':jgiven-timing'
}

def release = System.env.RELEASE == "true"
def android = System.env.ANDROID == "true"
boolean hasAndroidSourcePath = (System.env.ANDROID_SDK_ROOT)

if ((android || release) && hasAndroidSourcePath) {
    include ':jgiven-android'
}

if (android && !release && hasAndroidSourcePath) {
    include ':jgiven-android-test'
}

if (JavaVersion.current().isCompatibleWith(JavaVersion.VERSION_21)) {
    include ':jgiven-future-java-tests'
}