android-ui/app/build.gradle.kts at d7f9fd87f9f1ed0972534a26d2bbde416cb2e96d · THEOplayer/android-ui · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.dsl.KotlinVersion

plugins {
    alias(libs.plugins.android.application)
    alias(libs.plugins.kotlin.android)
    alias(libs.plugins.compose.compiler)
}

android {
    namespace = "com.theoplayer.android.ui.demo"
    compileSdk = libs.versions.android.compileSdk.get().toInt()

    defaultConfig {
        applicationId = "com.theoplayer.android.ui.demo"
        minSdk = libs.versions.android.minSdk.get().toInt()
        targetSdk = libs.versions.android.targetSdk.get().toInt()
        versionCode = 1
        versionName = "1.0"

        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
        vectorDrawables {
            useSupportLibrary = true
        }
    }

    buildTypes {
        release {
            isMinifyEnabled = false
            proguardFiles(
                getDefaultProguardFile("proguard-android-optimize.txt"),
                "proguard-rules.pro"
            )
        }
        // Build type that uses the latest android-ui from Maven
        register("maven") {
            initWith(getByName("debug"))
            matchingFallbacks += listOf("debug")
        }
    }

    flavorDimensions += "player"
    productFlavors {
        create("latestPlayer") {
            // Use the latest supported THEOplayer version
            dimension = "player"
        }
        create("minPlayer") {
            // Use the minimum supported THEOplayer version
            dimension = "player"
        }
    }

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }
    kotlin {
        compilerOptions {
            apiVersion = KotlinVersion.KOTLIN_2_0
            jvmTarget = JvmTarget.JVM_1_8
        }
    }
    buildFeatures {
        compose = true
    }
    packaging {
        resources {
            excludes += "/META-INF/{AL2.0,LGPL2.1}"
        }
    }
}

dependencies {
    val mavenImplementation = configurations.getByName("mavenImplementation")
    val latestPlayerImplementation = configurations.getByName("latestPlayerImplementation")
    val minPlayerImplementation = configurations.getByName("minPlayerImplementation")

    implementation(platform(libs.androidx.compose.bom))

    implementation(libs.androidx.ktx)
    implementation(libs.androidx.lifecycle.compose)
    implementation(libs.androidx.activity.compose)
    implementation(libs.androidx.appcompat)
    implementation(libs.androidx.core)
    implementation(libs.androidx.core.pip)
    implementation(libs.androidx.compose.ui.ui)
    implementation(libs.androidx.compose.ui.toolingPreview)
    implementation(libs.androidx.compose.material3)
    implementation(libs.androidx.compose.material.iconsExtended)
    implementation(libs.androidx.mediarouter)
    implementation(libs.playServices.castFramework)
    testImplementation(libs.junit4)
    androidTestImplementation(libs.androidx.junit)
    androidTestImplementation(libs.androidx.espresso)
    androidTestImplementation(libs.androidx.compose.ui.testJunit4)
    debugImplementation(libs.androidx.compose.ui.tooling)
    debugImplementation(libs.androidx.compose.ui.testManifest)

    debugImplementation(project(":ui"))
    releaseImplementation(project(":ui"))
    mavenImplementation("com.theoplayer.android-ui:android-ui:1.+")

    latestPlayerImplementation(libs.theoplayer)
    latestPlayerImplementation(libs.theoplayer.ads.ima)
    latestPlayerImplementation(libs.theoplayer.cast)

    minPlayerImplementation(libs.theoplayer.min)
    minPlayerImplementation(libs.theoplayer.min.ads.ima)
    minPlayerImplementation(libs.theoplayer.min.cast)
}