Snapper/build.gradle.kts at main · SpiritGameStudios/Snapper · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
plugins {
    java

    alias(libs.plugins.fabric.loom)
    alias(libs.plugins.modpublish)
}

val mappingsAttribute = Attribute.of("net.minecraft.mappings", String::class.java)

val modVersion = "1.1.1"
val modId = "snapper"
val modName = "Snapper"

val modrinthProject = "snapper"
val githubRepository = "SpiritGameStudios/Snapper"

group = "dev.spiritstudios"
base.archivesName = modId

version = "$modVersion+${libs.versions.minecraft.get()}"

@Suppress("UnstableApiUsage")
repositories {
    maven("https://maven.parchmentmc.org/") {
        name = "ParchmentMC"
        content { includeGroupAndSubgroups("org.parchmentmc") }
    }

    maven("https://maven.terraformersmc.com/") {
        name = "Terraformers"
        content { includeGroupAndSubgroups("com.terraformersmc") }
    }

    maven("https://moehreag.duckdns.org/maven/releases/") {
        name = "AxolotlClient Releases"
        content { includeGroupAndSubgroups("io.github.axolotlclient") }
    }

    maven("https://maven.greenhouse.lgbt/releases/") {
        name = "Greenhouse Releases"
        content { includeGroupAndSubgroups("lgbt.greenhouse") }
    }

    maven("https://maven.greenhouse.lgbt/snapshots/") {
        name = "Greenhouse Snapshots"
        content { includeGroupAndSubgroups("lgbt.greenhouse") }
    }

    mavenCentral()
}

loom {
    runtimeOnlyLog4j = true

    splitEnvironmentSourceSets()

    mods.create(modId) {
        sourceSet(sourceSets["main"])
        sourceSet(sourceSets["client"])
    }

    accessWidenerPath = file("src/main/resources/snapper.classtweaker")
}

dependencies {
    minecraft(libs.minecraft)
    @Suppress("UnstableApiUsage")
    mappings(
        loom.layered {
            officialMojangMappings()
            parchment(libs.parchment)
        }
    )

    modImplementation(libs.fabric.loader)
    modImplementation(libs.fabric.api)

    modCompileOnlyApi(libs.greenhouse.config.api) {
        attributes { attribute(mappingsAttribute, "intermediary") }
    }

    modRuntimeOnly(libs.greenhouse.config)
    include(libs.greenhouse.config)

    modCompileOnly(libs.modmenu)

    implementation(libs.objc.bridge)
}

tasks.processResources {
    val map = mapOf(
        "version" to modVersion,
        "loader_version" to libs.versions.fabric.loader.get()
    )

    inputs.properties(map)

    filesMatching("fabric.mod.json") { expand(map) }
}

java {
    withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

tasks.withType<JavaCompile> {
    options.encoding = "UTF-8"
    options.release = 21
}

tasks.jar {
    from("LICENSE") { rename { "${it}_$modId" } }
}

publishMods {
    file = tasks.remapJar.get().archiveFile
    modLoaders.add("fabric")

    version = modVersion
    type = STABLE
    displayName = "$modName $modVersion for Minecraft ${libs.versions.minecraft.get()}"

    changelog = providers.fileContents(layout.projectDirectory.file("CHANGELOG.md")).asText

    modrinth {
        accessToken = providers.gradleProperty("secrets.modrinth_token")
        projectId = modrinthProject
        minecraftVersions.add(libs.versions.minecraft.get())

        projectDescription = providers.fileContents(layout.projectDirectory.file("README.md")).asText

        requires("fabric-api")
        embeds("greenhouse-config")
    }

    github {
        accessToken = providers.gradleProperty("secrets.github_token")
        repository = githubRepository
        commitish = "main"

        tagName = modVersion
    }
}