Marrow/build.gradle.kts at main · Skeleton-Army/Marrow · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
plugins {
    base // provides the clean task
}

subprojects {
    apply(plugin = "com.android.library")
    apply(plugin = "io.deepmedia.tools.deployer")

    group = "com.skeletonarmyftc.marrow"
    version = "1.1.0"

    repositories {
        mavenCentral()
        google()
        maven("https://maven.brott.dev")
    }

    extensions.configure<io.deepmedia.tools.deployer.DeployerExtension> {
        projectInfo {
            name.set("Marrow")
            description.set("A lightweight library for building advanced robot behaviors.")
            url.set("https://skeleton-army.gitbook.io/marrow")
            scm.fromGithub("Skeleton-Army", "Marrow")
            developer("Skeleton Army", "skeleton.army23644@gmail.com")
            license(MIT)
        }

        signing {
            key.set(secret("SIGNING_KEY"))
            password.set(secret("SIGNING_PASSWORD"))
        }

        nexusSpec("snapshot") {
            repositoryUrl.set("https://central.sonatype.com/repository/maven-snapshots/")

            auth {
                user.set(secret("CENTRAL_PORTAL_USER"))
                password.set(secret("CENTRAL_PORTAL_PASSWORD"))
            }
        }

        centralPortalSpec {
            auth {
                user.set(secret("CENTRAL_PORTAL_USER"))
                password.set(secret("CENTRAL_PORTAL_PASSWORD"))
            }
        }

        localSpec() // For publishing to Maven Local

        content {
            androidComponents("release")
        }
    }
}

tasks.named<Delete>("clean") {
    delete(rootProject.layout.buildDirectory)
    delete(subprojects.map { it.layout.buildDirectory })
}

tasks.register("deployCentralPortal") {
    group = "publishing"
    description = "Publishes all subprojects to Maven Central."
    dependsOn("clean")
    dependsOn(subprojects.map { it.tasks.named("deployCentralPortal") })
}

tasks.register("deployNexusSnapshot") {
    group = "publishing"
    description = "Publishes all subprojects to Maven Central Snapshots."
    dependsOn("clean")
    dependsOn(subprojects.map { it.tasks.named("deployNexusSnapshot") })
}

tasks.register("deployLocal") {
    group = "publishing"
    description = "Publishes all subprojects to Maven Local."
    dependsOn(subprojects.map { it.tasks.named("deployLocal") })
}