Shopkeepers-ExecutableItems/build.gradle at master · Shopkeepers/Shopkeepers-ExecutableItems · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

ext.getGitHash = { ->
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'rev-parse', '--short', 'HEAD'
        standardOutput = stdout
        ignoreExitValue = true // Ignore error if there is no Git commit yet
    }
    return stdout.toString().trim() ?: "0"
}

// We embed the git hash into jar files, and also use it for the plugin version of snapshot builds.
ext.buildVersion = version + '+' + getGitHash()
ext.isSnapshot = version.contains('-SNAPSHOT')
ext.pluginVersion = isSnapshot ? buildVersion : version

println 'Project version: ' + version
println 'Build version: ' + buildVersion
println 'Plugin version: ' + pluginVersion

repositories {
    mavenCentral()
    maven {
        name = "spigotmc-repo"
        url = "https://hub.spigotmc.org/nexus/content/repositories/snapshots/"
    }
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }

    maven {
        url = uri("https://raw.githubusercontent.com/Shopkeepers/Repository/main/releases/")
    }
}

dependencies {
    compileOnly "org.spigotmc:spigot-api:1.20.4-R0.1-SNAPSHOT" // spigot api

    annotationProcessor 'org.projectlombok:lombok:1.18.32' // lombok anotation processor (used only in configurate-yaml)

    implementation "org.spongepowered:configurate-yaml:4.1.2" // config files
    implementation "com.google.inject:guice:7.0.0" // dependency injection
    implementation "net.kyori:adventure-text-serializer-plain:4.16.0" // text serializer
    implementation "net.kyori:adventure-text-serializer-legacy:4.16.0" // text serializer
    implementation "net.kyori:adventure-platform-bukkit:4.3.2" // adventure platform
    implementation "net.kyori:adventure-text-minimessage:4.16.0" // minimessage
    implementation "net.kyori:adventure-api:4.16.0" // adventure api
    implementation "org.slf4j:slf4j-api:2.0.0-alpha1" // logging

    compileOnly 'com.nisovin.shopkeepers:ShopkeepersAPI:2.24.0'

    compileOnly "org.projectlombok:lombok:1.18.32" // lombok

    implementation files('libs/SCore-5.25.12.24.jar') // SCore plugin (EI)
    // to add: ExecutableBlocks, ExecutableEvents, Oraxen, MMOItems
}


def targetJavaVersion = 21
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

shadowJar {
    version = version
    archiveClassifier.set('') // remove the classifier
}

processResources {
    def props = [
        'pluginVersion': pluginVersion,
        'pluginUrl': pluginUrl,
        'pluginDescription': pluginDescription
    ]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}