Sable/flake.nix at 61febb864a1cca7170cdbd9886ed44cd66cc8a25 · SableClient/Sable · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
# https://github.com/PleahMaCaka/svelte-tauri-template/blob/a598c33a34489b07680e14bb0d82ac01b0a9a4be/flake.nix
{
  description = "sable dev environment";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay.url = "github:oxalica/rust-overlay";
    android-nixpkgs.url = "github:tadfisher/android-nixpkgs";
  };

  nixConfig = {
    bash-prompt = "\\[\\e[1;35m\\]sable\\[\\e[0m\\]"; # bold magenta
    bash-prompt-suffix = " \\[\\e[0;36m\\]>\\[\\e[0m\\] ";  # cyan >
  };

  outputs =
    {
      nixpkgs,
      flake-utils,
      rust-overlay,
      android-nixpkgs,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ rust-overlay.overlays.default ];
          config = {
            android_sdk.accept_license = true;
            allowUnfree = true;
          };
        };

        rust = pkgs.rust-bin.stable.latest.default.override {
          targets = [
            "aarch64-linux-android"
            "armv7-linux-androideabi"
            "i686-linux-android"
            "x86_64-linux-android"
          ];
        };

        androidSdk = android-nixpkgs.sdk.${system} (
          sdkPkgs: with sdkPkgs; [
            build-tools-34-0-0
            platforms-android-34
            ndk-26-1-10909125
            cmdline-tools-latest
            platform-tools
            emulator
          ]
        );

        baseShell = {
          nativeBuildInputs = with pkgs; [
            pkg-config
            gobject-introspection
            cargo
            cargo-tauri
            nodejs
            xdg-utils
            desktop-file-utils
          ];

          buildInputs = with pkgs; [
            at-spi2-atk
            atkmm
            cairo
            gdk-pixbuf
            glib
            glib-networking
            gtk3
            gsettings-desktop-schemas
            harfbuzz
            librsvg
            libsoup_3
            pango
            webkitgtk_4_1
            openssl
            libayatana-appindicator
            gst_all_1.gstreamer
            gst_all_1.gst-plugins-base
            gst_all_1.gst-plugins-good
            gst_all_1.gst-plugins-bad
            gst_all_1.gst-plugins-ugly
            gst_all_1.gst-libav
          ];

          packages = with pkgs; [
            coreutils
            nix
            pnpm
            rust
          ];

          shellHook = ''
            export XDG_DATA_DIRS="$GSETTINGS_SCHEMAS_PATH:$XDG_DATA_DIRS"
            export GIO_EXTRA_MODULES="${pkgs.glib-networking}/lib/gio/modules"
            export GST_PLUGIN_SYSTEM_PATH="${pkgs.gst_all_1.gst-plugins-base}/lib/gstreamer-1.0:${pkgs.gst_all_1.gst-plugins-good}/lib/gstreamer-1.0:${pkgs.gst_all_1.gst-plugins-bad}/lib/gstreamer-1.0"
            alias tauri="pnpm exec tauri"
            echo "Done! Now make sable stable :3";
          '';
        };
      in
      {
        devShells = {
          default = pkgs.mkShell {
            name = "sable dev environment";
            inherit (baseShell) nativeBuildInputs buildInputs packages shellHook;

            LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath [
              pkgs.libayatana-appindicator
            ];
          };

          android = pkgs.mkShell {
            name = "sable dev environment (android)";
            inherit (baseShell) nativeBuildInputs buildInputs;  # <-- shellHook removed here

            packages = baseShell.packages ++ (with pkgs; [
              jdk
              androidSdk
            ]);

            shellHook = baseShell.shellHook + ''
              export NDK_HOME=${androidSdk}/share/android-sdk/ndk/26.1.10909125
              echo "Android SDK ready!";
            '';
          };
        };
      }
    );
}