next petsc attempt...moved to FindPETSc and create my own targets based

on if it is STATIC or not

Author: jacobmerson

CMakeLists.txt

@@ -76,18 +76,7 @@ if (PCMS_ENABLE_MESHFIELDS)
   message(STATUS "Found MeshFields: ${meshfields_DIR} (found version ${meshfields_VERSION})")
 endif()
 
-find_package(PkgConfig REQUIRED)
-if(DEFINED PETSC_DIR)
-  if(DEFINED PETSC_ARCH)
-    set(ENV{PKG_CONFIG_PATH} "${PETSC_DIR}/${PETSC_ARCH}/lib/pkgconfig:$ENV{PKG_CONFIG_PATH}")
-  else()
-    set(ENV{PKG_CONFIG_PATH} "${PETSC_DIR}/lib/pkgconfig:$ENV{PKG_CONFIG_PATH}")
-  endif()
-endif()
-pkg_check_modules(PETSC QUIET IMPORTED_TARGET PETSc)
-if(NOT PETSC_FOUND)
-  pkg_check_modules(PETSC REQUIRED IMPORTED_TARGET petsc)
-endif()
+find_package(PETSc REQUIRED)
 
 add_subdirectory(src)
 

cmake/FindPETSc.cmake

@@ -0,0 +1,70 @@
+find_package(PkgConfig REQUIRED)
+if(DEFINED PETSC_DIR)
+  if(DEFINED PETSC_ARCH)
+    set(ENV{PKG_CONFIG_PATH} "${PETSC_DIR}/${PETSC_ARCH}/lib/pkgconfig:$ENV{PKG_CONFIG_PATH}")
+  else()
+    set(ENV{PKG_CONFIG_PATH} "${PETSC_DIR}/lib/pkgconfig:$ENV{PKG_CONFIG_PATH}")
+  endif()
+endif()
+
+# we give an internal name _petsc
+# so we can fill up the PETSC_VARIABLE based
+# on static or not
+pkg_check_modules(_petsc PETSc)
+
+find_file(_petsc_PC_FILE petsc.pc                                                                                                 
+  PATHS ${_petsc_LIBRARY_DIRS}/../lib/pkgconfig                                                                                   
+        ${_petsc_STATIC_LIBRARY_DIRS}/../lib/pkgconfig                                                                            
+  ENV PKG_CONFIG_PATH                                                                                                             
+  NO_DEFAULT_PATH)                                                                                                                
+if(_petsc_PC_FILE)
+  file(READ "${_petsc_PC_FILE}" _petsc_PC_CONTENTS)
+  message(STATUS "PETSc .pc file: ${_petsc_PC_FILE}")
+  message(STATUS "PETSc .pc contents:\n${_petsc_PC_CONTENTS}")
+endif()
+
+if((_petsc_FOUND OR _petsc_STATIC_FOUND) AND _petsc_VERSION)
+  set(PETSC_VERSION ${_petsc_VERSION})
+endif()
+
+# note, there are a number of additional properties that
+# can be extracted / set on a target. We just do the basic
+# set for now. See: https://cmake.org/cmake/help/latest/module/FindPkgConfig.html
+if(_petsc_STATIC_FOUND)
+  message(STATUS "STATIC PETSC BUILD")
+  set(PETSC_LIBRARIES ${_petsc_STATIC_LINK_LIBRARIES})
+  set(PETSC_INCLUDE_DIRS ${_petsc_STATIC_INCLUDE_DIRS})
+  set(PETSC_LIBRARY_DIRS ${_petsc_STATIC_LIBRARY_DIRS})
+  set(PETSC_LDFLAGS ${_petsc_STATIC_LDFLAGS})
+  set(PETSC_LDFLAGS_OTHER ${_petsc_STATIC_LDFLAGS_OTHER})
+elseif(_petsc_FOUND)
+  message(STATUS "SHARED PETSC BUILD")
+  set(PETSC_LIBRARIES ${_petsc_LINK_LIBRARIES})
+  set(PETSC_INCLUDE_DIRS ${_petsc_INCLUDE_DIRS})
+  set(PETSC_LIBRARY_DIRS ${_petsc_LIBRARY_DIRS})
+  set(PETSC_LDFLAGS ${_petsc_LDFLAGS})
+  set(PETSC_LDFLAGS_OTHER ${_petsc_LDFLAGS_OTHER})
+endif()
+message(STATUS "PETSC_LIBRARIES ${PETSC_LIBRARIES}")
+message(STATUS "PETSC_INCLUDE_DIRS ${PETSC_INCLUDE_DIRS}")
+message(STATUS "PETSC_LIBRARY_DIRS ${PETSC_LIBRARY_DIRS}")
+message(STATUS "PETSC_LDFLAGS ${PETSC_LDFLAGS}")
+message(STATUS "PETSC_LDFLAGS_OTHER ${PETSC_LDFLAGS_OTHER}")
+
+
+if(NOT TARGET PETSc::PETSc)
+  add_library(PETSc::PETSc INTERFACE IMPORTED GLOBAL)
+  set_target_properties(PETSc::PETSc PROPERTIES INTERFACE_LINK_LIBRARIES "${PETSC_LIBRARIES}"
+                                     INTERFACE_INCLUDE_DIRECTORIES "${PETSC_INCLUDE_DIRS}"
+                                     INTERFACE_LINK_DIRECTORIES "${PETSC_LIBRARY_DIRS}"
+                                     INTERFACE_LINK_OPTIONS "${PETSC_LDFLAGS_OTHER}")
+endif()
+
+
+
+include(FindPackageHandleStandardArgs)
+# TODO consider adding version check logic
+find_package_handle_standard_args(PETSc
+  REQUIRED_VARS PETSC_LIBRARIES PETSC_INCLUDE_DIRS
+  VERSION_VAR PETSC_VERSION)
+

src/pcms/transfer/CMakeLists.txt

@@ -48,7 +48,7 @@ target_link_libraries(pcms_transfer PUBLIC
 
 target_link_libraries(pcms_transfer PUBLIC meshfields::meshfields)
 
-target_link_libraries(pcms_transfer PRIVATE PkgConfig::PETSC)
+target_link_libraries(pcms_transfer PRIVATE PETSc::PETSc)
 
 target_include_directories(pcms_transfer INTERFACE
     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>

test/CMakeLists.txt

@@ -415,7 +415,7 @@ if(Catch2_FOUND)
   #   target_link_libraries(unit_tests PUBLIC meshfields::meshfields)
   # endif()
 
-  target_link_libraries(unit_tests PRIVATE PkgConfig::PETSC)
+  target_link_libraries(unit_tests PRIVATE PETSc::PETSc)
 
   target_link_libraries(unit_tests PUBLIC 
     Catch2::Catch2